write_data.f

Go to the documentation of this file.

!                   *********************
                    SUBROUTINE write_data
!                   *********************
!
     &(fformat,fileres,nvars,time,timestep,outvar,nomvar,bvarsor,n,mesh)
!
!***********************************************************************
! BIEF   V7P1
!***********************************************************************
!
!brief    WRITES DATA VALUES ON A MESH INTO THE DATA FILE OF THE
!+                GIVEN FILE FORMAT.
!+
!+            DATA VALUES ARE STORED IN A BIEF_OBJ BLOCK (BVARSOR),
!+                AND THE LOGICAL OUTVAR INDICATES FOR EACH VARIABLE IF
!+                WE SHOULD PRINT IT OUT OR NOT.
!
!history  R NEBAUER (LNHE)
!+        25/11/08
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  Y. AUDOUIN (EDF), V.STOBIAC (EDF)
!+        10/12/2014
!+        V7P0
!+
!+   Use of Hermes interface to write data and mesh update option
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FFORMAT         |-->| FILE FORMAT
!| FILERES         |-->| LOGICAL UNIT OF FILE
!| NVARS           |-->| NUMBER OF VARIABLES
!| TIME            |-->| TIME
!| TIMESTEP        |-->| TIME STEP (INTEGER), NOT DT.
!| OUTVAR          |-->| VARIABLES TO BE PUT IN THE FILE
!| NOMVAR          |-->| NAME OF VARIABLES
!| BVARSOR         |-->| BIEF BLOCK CONTAINING THE VARIABLES VARIABLES
!| N               |-->| NUMBER OF VALUES (MAY BE DIFFERENT FROM
!|                 |   | THE NUMBER OF DEGREES OF FREEDOM, E.G. FOR
!|                 |   | QUADRATIC ELEMENTS ONLY THE LINEAR VALUES
!|                 |   | ARE EXITED)
!| MESH (OPTIONAL) |-->| MESH STRUCTURE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_write_data => write_data
      USE interface_hermes
!
      USE declarations_special
      IMPLICIT NONE
!
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      CHARACTER(LEN=8), INTENT(IN)           :: FFORMAT
      INTEGER,          INTENT(IN)           :: FILERES,N
      INTEGER,          INTENT(IN)           :: NVARS
      DOUBLE PRECISION, INTENT(IN)           :: TIME
      INTEGER,          INTENT(IN)           :: TIMESTEP
      CHARACTER(LEN=32),DIMENSION(NVARS), INTENT(IN) :: NOMVAR
      LOGICAL, DIMENSION(NVARS), INTENT(IN)  :: OUTVAR
      TYPE(bief_obj),   INTENT(IN)           :: BVARSOR
      TYPE(bief_mesh),  INTENT(IN), OPTIONAL :: MESH
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      LOGICAL :: FIRST_VAR
      INTEGER :: I,IERR, NPT, NB_DIM
      DOUBLE PRECISION, DIMENSION(:), ALLOCATABLE :: COORD
      CHARACTER(LEN=32) :: VAR_NAME
!
!-----------------------------------------------------------------------
!
      ! CONSTRUCT COORDINATES TABLE
      IF(PRESENT(mesh)) THEN
        ! SET VARIABLES
        npt    = mesh%NPOIN
        nb_dim = mesh%DIM1
        ! SET COORDINATES
        ALLOCATE(coord(nb_dim*npt))
        DO i=1,npt
          coord(i)     = mesh%X%R(i)
          coord(i+npt) = mesh%Y%R(i)
          IF(nb_dim.EQ.3) coord(i+2*npt) = mesh%Z%R(i)
        ENDDO
        ! UPDATE COORDINATES IN 3D RES FILES
        CALL update_data_mesh(fformat,fileres,time,timestep,
     &                        nb_dim,npt,coord,ierr)
        DEALLOCATE(coord)
      ENDIF
!
      ! LOOP ON ALL THE VARIABLES
      first_var = .true.
      DO i=1,nvars
        ! IF THE VARIABLE MUST BE WRITTEN
        IF(outvar(i)) THEN
          IF(ASSOCIATED(bvarsor%ADR(i)%P%R)) THEN
            var_name = nomvar(i)
            CALL add_data(fformat,fileres,var_name,time,timestep,
     &                    first_var,bvarsor%ADR(i)%P%R,n,ierr)
            CALL check_call(ierr,'WRITE_DATASET:ADD_DATA')
            first_var = .false.
          ELSE
            WRITE(lu,*) 'WRITE_DATA: VARIABLE NO: ',i
            WRITE(lu,*) '        NOT OR NOT WELL ALLOCATED'
            WRITE(lu,*) '        OR POINTER NOT ASSOCIATED '
          ENDIF
        ENDIF
      ENDDO

!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE