wpower.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE wpower
!                   *****************
!
     &( f     , cg    , nf    , ndire , npoin2)
!
!***********************************************************************
! TOMAWAC   V6P1                                   29/06/2011
!***********************************************************************
!
!brief    COMPUTES THE VARIANCE OF THE DIRECTIONAL SPECTRUM FOR
!+                ALL THE NODES IN THE 2D MESH. IT IS COMPUTED BY
!+                INTEGRATION OVER FREQUENCIES AND DIRECTIONS AND CAN
!+                TAKE THE HIGH FREQUENCY PART OF THE SPECTRUM INTO
!+                ACCOUNT.
!
!note     THE HIGH-FREQUENCY PART OF THE SPECTRUM IS ONLY CONSIDERED
!+         IF THE TAIL FACTOR (TAILF) IS STRICTLY GREATER THAN 1.
!
!history  M. BENOIT
!+        20/05/2003
!+        V5P3
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        29/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!history  G.MATTAROLO (EDF - LNHE)
!+        29/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| CG             |-->| DISCRETIZED GROUP VELOCITY
!| DFREQ          |-->| FREQUENCY STEPS BETWEEN DISCRETIZED FREQUENCIES
!| F              |-->| VARIANCE DENSITY DIRECTIONAL SPECTRUM
!| FREQ           |-->| DISCRETIZED FREQUENCIES
!| GRAVIT         |-->| GRAVITY ACCELERATION
!| NF             |-->| NUMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| POWER          |<--| WAVE POWER PER METER ALONG WAVE CREST
!| ROEAU          |-->| WATER DENSITY
!| TAILF          |-->| FACTEUR DE QUEUE DU SPECTRE
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_tomawac, ONLY : deupi, gravit, tailf , roeau,
     &    dfreq, power
!
      USE interface_tomawac, ex_wpower => wpower
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""
      INTEGER, INTENT(IN)    ::          NF    , NDIRE , NPOIN2
      DOUBLE PRECISION, INTENT(IN)    :: F(npoin2,ndire,nf)
      DOUBLE PRECISION, INTENT(IN)    :: CG(npoin2,nf)
!.....LOCAL VARIABLES
!     """""""""""""""""
      INTEGER          IP    , JP    , JF
      DOUBLE PRECISION AUX1  , DTETAR, ROGER
!
!
      dtetar=deupi/dble(ndire)
      roger=roeau*gravit/1000.d0
      DO ip=1,npoin2
        power(ip)=0.d0
      ENDDO
!
!-----C-------------------------------------------------------C
!-----C  SUMS UP THE DISCRETISED PART OF THE SPECTRUM         C
!-----C-------------------------------------------------------C
      DO jf=1,nf
        aux1=dfreq(jf)*dtetar
        DO jp=1,ndire
          DO ip=1,npoin2
            power(ip) = power(ip) + f(ip,jp,jf)*cg(ip,jf)*aux1
          ENDDO
        ENDDO
      ENDDO
!
!-----C-------------------------------------------------------------C
!-----C  TAKES THE HIGH FREQUENCY PART INTO ACCOUNT (OPTIONAL)      C
!-----C-------------------------------------------------------------C
!
      IF(tailf.GT.1.d0) THEN
        aux1=dtetar*gravit/(2.d0*deupi*tailf)
        DO jp=1,ndire
          DO ip=1,npoin2
            power(ip)=power(ip) + f(ip,jp,nf)*aux1
          ENDDO
        ENDDO
      ENDIF
!
!-----C-------------------------------------------------------------C
!-----C  CONVERTS TO KW/M  (MULTIPLIES BY RO.G/1000)                C
!-----C-------------------------------------------------------------C
!
      DO ip=1,npoin2
        power(ip)=power(ip)*roger
      ENDDO
!
      RETURN
      END