wnscou.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE wnscou
!                   *****************
!
     &( ck2   , freq  , depth )
!
!***********************************************************************
! TOMAWAC   V6P1                                   29/06/2011
!***********************************************************************
!
!brief    COMPUTES THE WAVE NUMBER.
!+                SOLVES THE DISPERSION EQUATION WITHOUT CURRENT.
!code
!+     3 METHODS ARE USED DEPENDING ON THE VALUE OF K0*D
!+     (K0: WAVE NUMBER IN INFINITE DEPTH)
!+
!+                      3.2                  5.6
!+      -----------------!--------------------!-----------------> K0*D
!+                       !                    !
!+   EXPLICIT METHODE    ! ITERATIVE METHODE  !     K=K0
!+   (HUNT 9TH ORDER)    !                    ! (INFINITE DEPTH)
!
!history  M. BENOIT (EDF/DER/LNH)
!+        07/02/95
!+        V1P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        29/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| CK2            |<--| WAVE NUMBER
!| DEPTH          |-->| WATER DEPTH
!| FREQ           |-->| DISCRETIZED FREQUENCY
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_tomawac, ONLY : deupi,gravit
!
      USE interface_tomawac, ex_wnscou => wnscou
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""
      DOUBLE PRECISION, INTENT(IN)    :: FREQ  , DEPTH
      DOUBLE PRECISION, INTENT(INOUT) :: CK2
!
!.....LOCAL VARIABLES
!     """""""""""""""""
      INTEGER  I
      DOUBLE PRECISION :: P(9)  , XK0   , XK0D
      DOUBLE PRECISION :: AUX   , A     , Y     , YI    , OM
!
      DOUBLE PRECISION, PARAMETER :: EPS = 0.0001d0
      parameter( p   = (/
     &       0.66667d0,0.35550d0,0.16084d0,0.06320d0,0.02174d0,
     &       0.00654d0,0.00171d0,0.00039d0,0.00011d0 /) )
!
!.....COMPUTES THE ANGULAR FREQUENCY (OM), K0 AND K0D
      om=freq*deupi
      xk0=om**2/gravit
      xk0d=xk0*depth
!
!.....DETERMINES THE METHOD OF RESOLUTION DEPENDING ON THE VALUE OF XK0D
!     ================================================================
!
      IF(xk0d.LE.3.2d0) THEN
!
!.......EXPLICIT METHOD (HUNT 9TH ORDER)
!
        y=xk0*depth
        aux=1.d0
        yi=1.d0
        DO i=1,9
          yi=yi*y
          aux=aux+p(i)*yi
        ENDDO ! I
        aux=y+1.d0/aux
        ck2=om/sqrt(gravit*depth/aux)
!
      ELSEIF(xk0d.LE.5.6d0) THEN
!
!.......ITERATIVE METHOD (FROM HUNT 9TH ORDER)
!
        y=xk0*depth
        aux=1.d0
        yi=1.d0
        DO i=1,9
          yi=yi*y
          aux=aux+p(i)*yi
        ENDDO ! I
        aux=y+1.d0/aux
        ck2=om/sqrt(gravit*depth/aux)
        DO
        a=ck2
        ck2=xk0/tanh(a*depth)
        IF (abs(ck2-a)/ck2.LT.eps) EXIT
        ENDDO
!
      ELSE
!
!.......APPROXIMATION OF INFINITE DEPTH
!
        ck2=xk0
!
      ENDIF
!
      RETURN
      END