wipj.f

Go to the documentation of this file.

!#######################################################################
      SUBROUTINE wipj (  WIP, FS, NPOIN2, XK, WIPDX, WIPDY,NDIRE,NF)
!     Calculating the wave induced pressure and gradients
!     WIP = Wave Induced Pressure      
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FS             |-->| VARIANCE DENSITY DIRECTIONAL SPECTRUM
!| NF             |-->| NUMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| WIP            |<--| WAVE INDUCED PRESSURE 
!| WIPDX          |<--| DERIVATIVE OF WIP ALONG X 
!| WIPDY          |<--| DERIVATIVE OF WIP ALONG Y 
!| XK             |-->| DISCRETIZED WAVE NUMBER
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      USE bief
      USE declarations_tomawac, ONLY : st1,st3,st4, mesh, gravit, dfreq
     &     ,ielm2,t1,t3,t4, depth, deupi
      USE interface_tomawac, ex_wipj => wipj

      IMPLICIT NONE
      
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""

      INTEGER, INTENT(IN)    :: NPOIN2,NDIRE,NF
      DOUBLE PRECISION, INTENT(IN)    :: FS(npoin2,ndire,nf)
      DOUBLE PRECISION, INTENT(IN)    :: XK(npoin2,nf)
      DOUBLE PRECISION, INTENT(INOUT) :: WIP(npoin2)
      DOUBLE PRECISION, INTENT(INOUT) :: WIPDX(npoin2)
      DOUBLE PRECISION, INTENT(INOUT) :: WIPDY(npoin2)
!.....LOCAL VARIABLES
!     """""""""""""""""
      INTEGER  JP    , JF    , IP
      DOUBLE PRECISION DTETAR, COEF, C
      
      dtetar=deupi/dble(ndire)
      DO ip=1,npoin2
        wip(ip) = 0.d0
      ENDDO
         
      DO jf=1,nf
        coef=gravit*dfreq(jf)*dtetar
        DO jp=1,ndire  
          DO ip=1,npoin2
            wip(ip)=wip(ip)+((xk(ip,jf)*fs(ip,jp,jf))
     &  /(sinh(2.d0*(xk(ip,jf)*depth(ip)))))*coef
          ENDDO
        ENDDO
      ENDDO

!.....DERIVATIVE IN X
      CALL ov('X=Y     ',t4,wip,t3,c,npoin2)
    
      CALL vector
     & (st1,'=','GRADF          X',ielm2,1.d0,st4,
     &  st3,st3,st3,st3,st3,mesh,.false.,st3,asspar=.true.)
            
      CALL vector
     & (st3,'=','GRADF          X',ielm2,1.d0,mesh%X,
     &  st1,st1,st1,st1,st1,mesh,.false.,st1,asspar=.true.)

!      IF(NCSIZE.GE.1) THEN
!        CALL PARCOM(ST1,2,MESH)
!        CALL PARCOM(ST3,2,MESH)
!      ENDIF
      CALL ov('X=Y/Z   ',wipdx,t1,t3,c,npoin2)
     
!.....DERIVATIVE IN Y
      CALL ov('X=Y     ',t4,wip,t3,c,npoin2)
      CALL vector
     & (st1,'=','GRADF          Y',ielm2,1.d0,st4,
     &  st3,st3,st3,st3,st3,mesh,.false.,st3,asspar=.true.)
!
      CALL vector
     & (st3,'=','GRADF          Y',ielm2,1.d0,mesh%Y,
     &  st1,st1,st1,st1,st1,mesh,.false.,st1,asspar=.true.)

!AQUI FAZEMOS A MÉDIA dos grads no volume.

      CALL ov('X=Y/Z   ',wipdy,t1,t3,c,npoin2)
      
!AQUI TEMOS AS DERIVADAS EM X E Y DO WAVE INDUCED PRESSURE

      RETURN
      END