windiss3.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE windiss3
!                   *****************
     &  (fwx, fwy, npoin2, xk, ndire, fs,nf)
!  SURFACE STRESS DUE TO WIND INPUT ENERGY AND WHITECAPPING
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FS             |-->| VARIANCE DENSITY DIRECTIONAL SPECTRUM
!| FWX            |<--| SURFACE STRESS DUE TO WIND ALONG X
!| FWY            |<--| SURFACE STRESS DUE TO WIND ALONG Y
!| NF             |-->| NUMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| XK             |-->| DISCRETIZED WAVE NUMBER
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

      USE declarations_tomawac, ONLY : freq, dfreq, sintet, costet,
     &   teta, deupi, twold, usold,   coefwd, coefwe, coefwf, coefwh
!
      IMPLICIT NONE
!
      INTEGER, INTENT(IN) :: NPOIN2, NDIRE,NF
      DOUBLE PRECISION, INTENT(IN) :: FS(npoin2,ndire,nf)
      DOUBLE PRECISION, INTENT(IN) :: XK(npoin2,nf)
      DOUBLE PRECISION, INTENT(INOUT) :: FWX(npoin2), FWY(npoin2)
!
      DOUBLE PRECISION DTETAR,  AUX1, CPHAS, SIGMA
      DOUBLE PRECISION BETAWIN, DIREC, INTER, DIR
      INTEGER IP, JF, JP
      dtetar=deupi/dble(ndire)
      DO ip=1,npoin2
        fwx(ip) = 0.d0
        fwy(ip) = 0.d0
      ENDDO

!.....LOOP ON THE DISCRETISED FREQUENCIES
!     """"""""""""""""""""""""""""""""""""""""""""
      DO jf=1,nf

        sigma=deupi*freq(jf)
        aux1=dfreq(jf)*dtetar
!
!.......LOOP ON THE DISCRETISED DIRECTIONS
!       """"""""""""""""""""""""""""""""""""""""""""
        DO jp=1,ndire
          direc=teta(jp)
          DO ip=1,npoin2
!.......COMPUTES THE FREQUENCIES (OMEGA AND UETOILE/CPHASE)
            cphas = sigma / xk(ip,jf)
            inter=usold(ip)/cphas
            dir=cos(direc-twold(ip))
            betawin = (coefwd*inter**2*dir+coefwe*inter*dir
     &      +coefwf*dir+coefwh)*sigma

            fwx(ip)=fwx(ip)+((xk(ip,jf)/sigma)*sintet(jp)
     &           *betawin*fs(ip,jp,jf))*aux1
            fwy(ip)=fwy(ip)+((xk(ip,jf)/sigma)*costet(jp)
     &           *betawin*fs(ip,jp,jf))*aux1
          ENDDO
        ENDDO
      ENDDO
      RETURN
      END