waitfor.f

Go to the documentation of this file.

!                   ******************
                    SUBROUTINE waitfor
!                   ******************
!
     & (dossier,fichier)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    'FICHIER' IS THE NAME OF A FILE EXPECTED IN THE DIRECTORY.
!+                THIS FILE EXISTS IF THERE IS AN EMPTY FILE CALLED
!+               'YAFICHIER' (NAME OF THE FILE PRECEDED WITH 'YA').
!+
!+            WHEN FILE 'YAFICHIER' EXISTS, IT IS DELETED AND WE EXIT
!+                THE SUBROUTINE.
!
!history  NATHALY BARBRY (UNIVERSITE DE CAEN); J-M HERVOUET (LNHE)
!+        08/02/2001
!+        V5P2
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| DOSSIER        |-->| DIRECTORY WHERE IS THE FILE TO BE READ
!| FICHIER        |-->| FILE TO BE READ
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
!
      USE declarations_special
      IMPLICIT NONE
!
      CHARACTER(LEN=PATH_LEN), INTENT(IN) :: DOSSIER
      CHARACTER(LEN=*)  , INTENT(IN) :: FICHIER
!
      CHARACTER(LEN=270) NOMFIC
      LOGICAL OUI
      INTEGER ERR1
!
!     PARAMETER: WAIT TIME
!
      INTEGER, PARAMETER :: LAPS = 3
      INTEGER :: ID
!
!-----------------------------------------------------------------------
!
      INTRINSIC trim
!
!-----------------------------------------------------------------------
!
10    CONTINUE
!
      nomfic=trim(dossier)//'YA'//fichier
      INQUIRE(file=nomfic,exist=oui,err=84,iostat=err1)
!
!-----------------------------------------------------------------------
!
      IF(oui) THEN
!
        CALL get_free_id(id)
        OPEN(id,file=nomfic,
     &          status='OLD',form='UNFORMATTED',err=85,iostat=err1)
        CLOSE(id,status='DELETE',err=86,iostat=err1)
!
        GO TO 1000
!
      ELSE
!
        INQUIRE(file=trim(dossier)//'STOP',exist=oui,err=84,iostat=err1)
        IF(oui) THEN
          WRITE(lu,*) 'WAITFOR : PROGRAM STOPPED, WAITING IS USELESS'
          WRITE(lu,*) '          BECAUSE A FILE STOP HAS BEEN CREATED'
          CALL plante(1)
          stop
        ELSE
          WRITE(lu,*) 'WAITING ',laps,' SECONDS'
          CALL attend(laps)
        ENDIF
!
        GO TO 10
!
      ENDIF
!
!-----------------------------------------------------------------------
!     ERROR MESSAGES
!-----------------------------------------------------------------------
!
84    CONTINUE
      WRITE(lu,*) 'WAITFOR : ERROR OF COMMAND INQUIRE ON FILE :'
      WRITE(lu,*) '         ',trim(dossier)//'YA'//fichier
      WRITE(lu,*) '          ERROR NUMBER : ',err1
      CALL plante(1)
      stop
85    CONTINUE
      WRITE(lu,*) 'WAITFOR : ERROR ',err1
      WRITE(lu,*) 'WHEN OPENING THE FILE ',nomfic
      CALL plante(1)
      stop
86    CONTINUE
      WRITE(lu,*) 'WAITFOR : ERROR ',err1
      WRITE(lu,*) 'WHEN CLOSING THE FILE ',nomfic
      CALL plante(1)
      stop
!
!-----------------------------------------------------------------------
!
1000  CONTINUE
!
!-----------------------------------------------------------------------
!
      RETURN
      END