vector.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE vector
!                   *****************
!
     &(vec,op,formul,ielm1,xmul,f,g,h,u,v,w,mesh,msk,maskel,lego,asspar)
!
!***********************************************************************
! BIEF   V7P0                                   08/01/2014
!***********************************************************************
!
!brief    COMPUTES VECTORS.
!+
!+            THE VECTOR IS IDENTIFIED BY THE FORMULATION IN
!+                THE CHARACTER STRING 'FORMUL'.
!+
!+            'OP' IS = OR +.
!code
!+  MEANING OF IELM1
!+
!+  TYPE OF ELEMENT      NUMBER OF POINTS
!+
!+   0 : P0 SEGMENT             1
!+   1 : P1 SEGMENT             2
!+
!+  10 : P0 TRIANGLE            1
!+  11 : P1 TRIANGLE            3
!+  12 : QUASI-BUBBLE TRIANGLE  4
!+
!+  20 : Q0 QUADRILATERAL       1
!+  21 : Q1 QUADRILATERAL       4
!+
!+  40 : TELEMAC-3D P0 PRISMS   1
!+  41 : TELEMAC-3D P1 PRISMS   6
!
!
!history  JM HERVOUET (LNHE)
!+        25/06/2008
!+        V5P9
!+   NO CALL TO VECTOS IF THE NUMBER OF ELEMENTS IS 0
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (EDF R&D, LNHE)
!+        11/01/2013
!+        V6P3
!+   Arguments added to VECTOS
!
!history  J-M HERVOUET (EDF R&D, LNHE)
!+        03/05/2013
!+        V6P3
!+   Checking size of vector, and status=0 allowed if OP='='.
!
!history  J-M HERVOUET (EDF R&D, LNHE)
!+        08/01/2014
!+        V7P0
!+   New optional argument ASSPAR, to assemble the vector in parallel.
!+   This will avoid a lot of CALL PARCOM everywhere.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ASSPAR         |-->| IF YES, RARALLEL ASSEMBLY OF THE VECTOR IS DONE
!| F              |-->| FUNCTION USED IN THE VECTOR FORMULA (BIEF_OBJ)
!| FORMUL         |-->| STRING WITH THE FORMULA DESCRIBING THE VECTOR
!| G              |-->| FUNCTION USED IN THE VECTOR FORMULA (BIEF_OBJ)
!| H              |-->| FUNCTION USED IN THE VECTOR FORMULA (BIEF_OBJ)
!| IELM1          |-->| TYPE OF ELEMENT
!| MASKEL         |-->| MASKING OF ELEMENTS
!|                |   | =1. : NORMAL   =0. : MASKED ELEMENT
!| MESH           |-->| MESH STRUCTURE
!| MSK            |-->| IF YES, THERE IS MASKED ELEMENTS
!| OP             |-->| '=' : WE DO VEC= THE VECTOR
!|                |   | '+' : WE DO VEC=VEC+ THE VECTOR
!| U              |-->| FUNCTION USED IN THE VECTOR FORMULA (BIEF_OBJ)
!| V              |-->| FUNCTION USED IN THE VECTOR FORMULA (BIEF_OBJ)
!| W              |-->| FUNCTION USED IN THE VECTOR FORMULA (BIEF_OBJ)
!| VEC            |<->| RESULTING VECTOR
!| XMUL           |-->| MULTIPLICATION COEFFICIENT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_vector => vector
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      TYPE(bief_obj),    INTENT(INOUT) :: VEC
      DOUBLE PRECISION,  INTENT(IN)    :: XMUL
      INTEGER,           INTENT(IN)    :: IELM1
      LOGICAL,           INTENT(IN)    :: MSK
      CHARACTER(LEN=16), INTENT(IN)    :: FORMUL
      CHARACTER(LEN=1),  INTENT(IN)    :: OP
      TYPE(bief_obj),    INTENT(IN)    :: F,G,H,U,V,W,MASKEL
      TYPE(bief_mesh),   INTENT(INOUT) :: MESH
      LOGICAL, OPTIONAL, INTENT(IN)    :: LEGO,ASSPAR
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER  :: NPT                  ! NUMBER OF POINTS PER ELEMENT
      INTEGER  :: DIM1T                ! FIRST DIMENSION OF T IN VECTOS
      LOGICAL  :: LLEGO,AASSPAR        ! ASSEMBLY OR NOT
      INTEGER  :: IELM0                ! P0 DISCRETISATION
!
      IF(PRESENT(lego)) THEN
        llego=lego
      ELSE
        llego=.true.
      ENDIF
!
!-----------------------------------------------------------------------
!  POSSIBLE CHANGE OF DISCRETISATION
!-----------------------------------------------------------------------
! IF A VECTOR HAS BEEN ALLOCATED WITH STATUS 1, I.E ITS DISCRETISATION
! CANNOT CHANGE, IT IS NECESSARY TO TEST THE COHERENCE BETWEEN THE
! DISCRETISATION OF THE VECTOR AND THAT PROPOSED IN ARGUMENT.
! MIGHT HAVE SURPRISES OTHERWISE !!!!
!
      IF(vec%STATUS.EQ.1.AND.vec%ELM.NE.ielm1) THEN
        WRITE(lu,1002) vec%NAME,vec%ELM,ielm1
1002    FORMAT(1x,'VECTOR: CHANGING DISCRETIZATION FORBIDDEN',
     &  ' FOR THE VECTOR ',a6,' : ',1i6,' <=> ',1i6)
        CALL plante(1)
        stop
      ELSEIF(vec%STATUS.EQ.2.OR.vec%STATUS.EQ.1.OR.
     &      (vec%STATUS.EQ.0.AND.op.EQ.'=')) THEN
        npt = bief_nbpts(ielm1,mesh)
        vec%ELM = ielm1
        IF(npt.GT.vec%MAXDIM1) THEN
          WRITE(lu,*) 'VECTOR ',vec%NAME
          WRITE(lu,*) 'HAS A FIRST DIMENSION OF: ',vec%MAXDIM1
          WRITE(lu,*) 'IT CANNOT BE USED IN VECTOR'
          WRITE(lu,*) 'FOR A SIZE OF ',npt
          CALL plante(1)
          stop
        ELSE
          vec%DIM1= npt
          IF(vec%STATUS.EQ.0) vec%STATUS=2
        ENDIF
      ELSE
        WRITE(lu,*) 'VECTOR ',vec%NAME,' HAS A STATUS ',vec%STATUS,
     &              ' IT CANNOT BE USED IN SUBROUTINE VECTOR'
        CALL plante(1)
        stop
      ENDIF
!
! ASSEMBLY: NOT PERFORMED FOR VECTORS
! RESULT OF P0 DISCRETISATION
! LLEGO IS SET TO TRUE IF THE RESULTANT VECTOR DISCRETISATION
! IS P1, FALSE OTHERWISE.
!
      ielm0 = 10*(ielm1/10)
      IF(ielm0.EQ.ielm1) llego=.false.
!
!-----------------------------------------------------------------------
!  CALLS THE SUBROUTINE THAT SHUNTS AND ASSEMBLES
!-----------------------------------------------------------------------
!
      IF(dimens(ielm1).EQ.mesh%DIM1) THEN
        dim1t=mesh%NELMAX
      ELSE
        dim1t=mesh%NELEBX
      ENDIF
!
!-----------------------------------------------------------------------
!  OPTIONAL ASSEMBLY: VALUES OF VEC SUMMED AT INTERFACE POINTS
!-----------------------------------------------------------------------
!
      aasspar=.false.
      IF(ncsize.GT.1) THEN
        IF(PRESENT(asspar).AND.dimens(ielm1).EQ.mesh%DIM1) THEN
          aasspar=asspar
        ENDIF
      ENDIF
!
      IF(dimens(ielm1).EQ.mesh%DIM1.OR.mesh%NELEB.GT.0) THEN
!
        CALL vectos(vec,vec%R,op,formul,xmul,
     &              f%R,g%R,h%R,u%R,v%R,w%R,
     &              f,g,h,u,v,w,mesh%W%R,llego,
     &              mesh%XEL%R   , mesh%YEL%R   ,
     &              mesh%X%R     , mesh%Y%R     , mesh%Z%R    ,
     &              mesh%SURFAC%R, mesh%LGSEG%R ,
     &              mesh%IKLE%I  , mesh%IKLBOR%I, mesh%NBOR%I ,
     &              mesh%XSGBOR%R, mesh%YSGBOR%R,
     &              npt,mesh%NELEM,mesh%NELEB,
     &              mesh%NELMAX,mesh%NELEBX,
     &              ielm1,mesh%LV,msk,maskel%R,mesh,dim1t,
     &              mesh%NELBOR%I,mesh%NULONE%I,aasspar)
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END