vecle3.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE vecle3
!                   *****************
!
     & (lv,ikle,nelem,nelmax,npoin,v)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    DETERMINES THE LENGTH OF A VECTOR WITHOUT BACK
!+                DEPENDENCIES FOR LOOPS ON THE ELEMENTS.
!+
!+            ONLY LOOKS FOR VALUES :
!+                1 , 64 , 128 , 256 , 512 , 1024.
!+
!+            THE PRINCIPLE IS TO PERFORM, IN SCALAR AND VECTOR
!+                MODE, AN ALGORITHM WHICH COMPUTES THE NUMBER OF
!+                ADJACENT ELEMENTS AT EACH POINT.
!+
!+            ELEMENT CONSIDERED: TRIANGLE.
!
!warning  IN VECTOR MODE WITH DEPENDENCIES, THE RESULT IS WRONG
!
!history  J-M HERVOUET (LNH)
!+        19/08/94
!+        V5P1
!+   ORIGINAL IDEA FROM J.-P. GREGOIRE
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IKLE           |-->| CONNECTIVITY TABLE.
!| LV             |-->| VECTOR LENGTH OF THE MACHINE
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| NPOIN          |-->| NUMBER OF POINTS
!| V              |-->| ARRAY OF SIZE NPOIN
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_vecle3 => vecle3
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(INOUT)          :: LV
      INTEGER, INTENT(IN)             :: NELEM,NELMAX,NPOIN
      INTEGER, INTENT(IN)             :: IKLE(nelmax,3)
      DOUBLE PRECISION, INTENT(INOUT) :: V(npoin)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IB
!
!-----------------------------------------------------------------------
!
      lv = 1024
!
5     CONTINUE
!
!  INITIALISES V AT 0
!
      CALL ov('X=C     ', x=v, c=0.d0, dim1=npoin)
!
!  SCALAR MODE
!
      DO ielem = 1 , nelem
        v(ikle(ielem,1)) = v(ikle(ielem,1)) + 1.d0
        v(ikle(ielem,2)) = v(ikle(ielem,2)) + 1.d0
        v(ikle(ielem,3)) = v(ikle(ielem,3)) + 1.d0
      ENDDO ! IELEM
!
!  VECTOR MODE WITH FORCED VECTORISATION
! (FUJITSU COMMANDS, THEN CRAY COMMANDS)
!
      DO ib = 1,(nelem+lv-1)/lv
!VOCL LOOP,NOVREC
!DIR$ IVDEP
      DO ielem = 1+(ib-1)*lv , min(nelem,ib*lv)
        v(ikle(ielem,1)) = v(ikle(ielem,1)) - 1.d0
        v(ikle(ielem,2)) = v(ikle(ielem,2)) - 1.d0
        v(ikle(ielem,3)) = v(ikle(ielem,3)) - 1.d0
      ENDDO ! IELEM
      ENDDO ! IB
!
!-----------------------------------------------------------------------
!
      IF(dot(npoin,v,v).GT.0.5d0.AND.lv.NE.1) THEN
        lv = lv/2
        IF(lv.LT.64) THEN
          lv = 1
          GO TO 1000
        ENDIF
        GO TO 5
      ENDIF
!
1000  CONTINUE
!
!-----------------------------------------------------------------------
!
      RETURN
      END