vc16aa.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE vc16aa
!                   *****************
!
     &( xmul,sf,sg,su,sv,f,g,u,v,
     &  xel,yel,surfac,
     &  ikle1,ikle2,ikle3,nelem,nelmax,
     &  w1,w2,w3 )
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE FOLLOWING VECTOR IN FINITE ELEMENTS:
!code
!+                    /  -> -->              ->
!+      V  =  XMUL   /   K GRAD(PSII) * DIV( U )  D(OMEGA)
!+       I          /OMEGA
!+
!+
!+    PSI(I) IS A BASE OF TYPE P1 TRIANGLE
!+    ->
!+    U IS A VECTOR WITH COORDINATES U AND V
!+    ->
!+    K IS A VECTOR WITH COMPONENTS F AND G
!
!warning  THE JACOBIAN MUST BE POSITIVE
!warning  THE RESULT IS IN W IN NOT ASSEMBLED FORM
!
!history  J-M HERVOUET (LNH)
!+        09/12/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| F              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| G              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| IKLE1          |-->| FIRST POINT OF TRIANGLES
!| IKLE2          |-->| SECOND POINT OF TRIANGLES
!| IKLE3          |-->| THIRD POINT OF TRIANGLES
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SF             |-->| BIEF_OBJ STRUCTURE OF F
!| SG             |-->| BIEF_OBJ STRUCTURE OF G
!| SU             |-->| BIEF_OBJ STRUCTURE OF U
!| SV             |-->| BIEF_OBJ STRUCTURE OF V
!| SURFAC         |-->| AREA OF TRIANGLES
!| U              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| V              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| W1             |<--| RESULT IN NON ASSEMBLED FORM
!| W2             |<--| RESULT IN NON ASSEMBLED FORM
!| W3             |<--| RESULT IN NON ASSEMBLED FORM
!| XEL            |-->| ABSCISSAE OF POINTS IN THE MESH, PER ELEMENT
!| XMUL           |-->| MULTIPLICATION COEFFICIENT
!| YEL            |-->| ORDINATES OF POINTS IN THE MESH, PER ELEMENT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_vc16aa => vc16aa
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX
      INTEGER, INTENT(IN) :: IKLE1(nelmax),IKLE2(nelmax),IKLE3(nelmax)
!
      DOUBLE PRECISION, INTENT(IN) :: XEL(nelmax,*),YEL(nelmax,*)
      DOUBLE PRECISION, INTENT(INOUT)::W1(nelmax),W2(nelmax),W3(nelmax)
      DOUBLE PRECISION, INTENT(IN) :: SURFAC(nelmax)
      DOUBLE PRECISION, INTENT(IN) :: XMUL
!
!     STRUCTURES OF F, G, H, U, V, W AND REAL DATA
!
      TYPE(bief_obj), INTENT(IN) :: SF,SG,SU,SV
      DOUBLE PRECISION, INTENT(IN) :: F(*),G(*),U(*),V(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IELMF,IELMU,IELMG,IELMV
      DOUBLE PRECISION X2,Y2,X3,Y3,U1,U2,U3,V1,V2,V3,FF,GG
      DOUBLE PRECISION XSUR04,COEF
!
!-----------------------------------------------------------------------
!
      xsur04 = xmul / 12.d0
!
!-----------------------------------------------------------------------
!
      ielmf=sf%ELM
      ielmu=su%ELM
      ielmg=sg%ELM
      ielmv=sv%ELM
!
!-----------------------------------------------------------------------
!
!     F AND G (NOT CHECKED) ARE P0; U AND V (NOT CHECKED) ARE LINEAR
!
      IF(     ielmf.EQ.10.AND.ielmg.EQ.11.
     &    and.ielmu.EQ.11.AND.ielmv.EQ.11  ) THEN
!
      DO ielem = 1 , nelem
!
      x2 = xel(ielem,2)
      x3 = xel(ielem,3)
      y2 = yel(ielem,2)
      y3 = yel(ielem,3)
!
      u1 = u(ikle1(ielem))
      u2 = u(ikle2(ielem)) - u1
      u3 = u(ikle3(ielem)) - u1
      v1 = v(ikle1(ielem))
      v2 = v(ikle2(ielem)) - v1
      v3 = v(ikle3(ielem)) - v1
!
!     U1 AND V1 NOW =0 (ONLY THE GRADIENT OF U IS USED)
!
      coef = (x2*v3-x3*v2-u3*y2+u2*y3) * xsur04 / surfac(ielem)
!
      ff = f(ielem)
      gg = g(ielem)
!
      w1(ielem) =-( (x2-x3)*gg+(y3-y2)*ff ) * coef
      w2(ielem) =           (-gg*x3+ff*y3)  * coef
      w3(ielem) =          -(ff*y2-gg*x2)   * coef
!
      ENDDO ! IELEM
!
!-----------------------------------------------------------------------
!
      ELSE
!
!-----------------------------------------------------------------------
!
        WRITE(lu,101) ielmf,sf%NAME
        WRITE(lu,201) ielmu,su%NAME
        WRITE(lu,301)
101     FORMAT(1x,'VC16AA (BIEF) :',/,
     &         1x,'DISCRETIZATION OF F:',1i6,
     &         1x,'REAL NAME: ',a6)
201     FORMAT(1x,'DISCRETIZATION OF U:',1i6,
     &         1x,'REAL NAME: ',a6)
301     FORMAT(1x,'CASE NOT IMPLEMENTED')
        CALL plante(0)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END