vc14aa.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE vc14aa
!                   *****************
!
     &( xmul,su,sv,u,v,xel,yel,surfac,ikle1,ikle2,ikle3,nelem,nelmax,
     &  w1,w2,w3)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE TURBULENT PRODUCTION TERM
!+               (TO ACCURACY NUT):
!code
!+                   /
!+  VEC(I) = XMUL   /     PSI(I) *
!+                 /OMEGA
!+
!+              DU           DV          DU   DV
!+     *  (  2*(--)^2  +  2*(--)^2  +  ( -- + -- )^2  )  D(OMEGA)
!+              DX           DY          DY   DX
!+
!+
!+    U AND V ARE VECTORS
!+
!+    PSI(I) IS A BASE OF TYPE IELM
!
!warning  THE JACOBIAN MUST BE POSITIVE
!
!history  C. MOULIN (LNH); L VAN HAREN (LNH); A FROEHLY (MATMECA)
!+        09/07/2008
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IKLE1          |-->| FIRST POINT OF TRIANGLES
!| IKLE2          |-->| SECOND POINT OF TRIANGLES
!| IKLE3          |-->| THIRD POINT OF TRIANGLES
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SU             |-->| BIEF_OBJ STRUCTURE OF U
!| SV             |-->| BIEF_OBJ STRUCTURE OF V
!| SURFAC         |-->| AREA OF TRIANGLES
!| U              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| V              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| W1             |<--| RESULT IN NON ASSEMBLED FORM
!| W2             |<--| RESULT IN NON ASSEMBLED FORM
!| W3             |<--| RESULT IN NON ASSEMBLED FORM
!| XEL            |-->| ABSCISSAE OF POINTS IN THE MESH, PER ELEMENT
!| XMUL           |-->| MULTIPLICATION COEFFICIENT
!| YEL            |-->| ORDINATES OF POINTS IN THE MESH, PER ELEMENT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_vc14aa => vc14aa
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX
      INTEGER, INTENT(IN) :: IKLE1(nelmax),IKLE2(nelmax),IKLE3(nelmax)
!
      DOUBLE PRECISION, INTENT(IN) :: XEL(nelmax,*),YEL(nelmax,*)
      DOUBLE PRECISION, INTENT(INOUT) ::W1(nelmax),W2(nelmax),W3(nelmax)
      DOUBLE PRECISION, INTENT(IN) :: SURFAC(nelmax)
      DOUBLE PRECISION, INTENT(IN) :: XMUL
!
!     STRUCTURES OF U, V AND REAL DATA
!
      TYPE(bief_obj), INTENT(IN) :: SU,SV
      DOUBLE PRECISION, INTENT(IN) :: U(*),V(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IELMU,IELMV
      DOUBLE PRECISION FACT,XSUR12,U21,U31,V21,V31,X2,X3,Y2,Y3
!
!-----------------------------------------------------------------------
!
      xsur12 = xmul / 12.d0
!
!-----------------------------------------------------------------------
!
!     BEWARE: U IS QUASI-BUBBLE AND U IS P2; ARE TREATED AS IF LINEAR HERE
!
!-----------------------------------------------------------------------
!
      ielmu=su%ELM
      ielmv=sv%ELM
!
      IF(      (ielmu.EQ.11.AND.ielmv.EQ.11)
     &     .OR.(ielmu.EQ.12.AND.ielmv.EQ.12)
     &     .OR.(ielmu.EQ.13.AND.ielmv.EQ.13)) THEN
!
      DO ielem = 1 , nelem
!
        x2  = xel(ielem,2)
        x3  = xel(ielem,3)
        y2  = yel(ielem,2)
        y3  = yel(ielem,3)
!
        u21 = u(ikle2(ielem)) - u(ikle1(ielem))
        u31 = u(ikle3(ielem)) - u(ikle1(ielem))
        v21 = v(ikle2(ielem)) - v(ikle1(ielem))
        v31 = v(ikle3(ielem)) - v(ikle1(ielem))
!
        fact = (       ( x2*u31-x3*u21-y2*v31+y3*v21)**2
     &           + 2 *(( x2*v31-x3*v21 )**2+( y3*u21-y2*u31 )**2 )
     &         )  * xsur12 / surfac(ielem)
!
        w1(ielem) = fact
        w2(ielem) = fact
        w3(ielem) = fact
!
      ENDDO ! IELEM
!
!-----------------------------------------------------------------------
!
      ELSE
!
!-----------------------------------------------------------------------
!
        WRITE(lu,101) ielmu,su%NAME
        WRITE(lu,201) ielmv,sv%NAME
        WRITE(lu,301)
101     FORMAT(1x,'VC14AA (BIEF) :',/,
     &         1x,'DISCRETIZATION OF U:',1i6,
     &         1x,'REAL NAME: ',a6)
201     FORMAT(1x,'DISCRETIZATION OF V:',1i6,
     &         1x,'REAL NAME: ',a6)
301     FORMAT(1x,'CASE NOT IMPLEMENTED')
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END