vc11tt0.f

Go to the documentation of this file.

!                   ******************
                    SUBROUTINE vc11tt0
!                   ******************
!
     &( xmul,sf,sg,f,g,x,y,z,ikle1,ikle2,ikle3,ikle4,nelem,npoin,
     &  w,icoord)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE FOLLOWING VECTOR IN FINITE ELEMENTS:
!code
!+   (EXAMPLE OF THE X COMPONENT, WHICH CORRESPONDS TO ICOORD=1)
!+
!+                       /            DF
!+    VEC(I)  =  XMUL   /  ( G  P  *( --  )) D(OMEGA)
!+                     /OMEGA    I    DX
!+
!+
!+    P   IS A LINEAR BASE
!+     I
!+
!+    F IS A VECTOR OF TYPE P1
!+    W IS A VECTOR OF TYPE P0
!+    G IS ALSO A VECTOR OF TYPE P0
!+    IT IS THEREFORE NOT REQUIRED TO ASSEMBLE THE RESULT VECTOR
!+    THE RESULT IS DIRECTLY IN W
!
!warning  THE JACOBIAN MUST BE POSITIVE
!
!history  J-M HERVOUET (LNH)
!+        **/06/04
!+        V5P5
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| F              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| G              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| ICOORD         |-->| 1: DERIVATIVE ALONG X, 2: ALONG Y
!| IKLE1          |-->| FIRST POINT OF TETRAHEDRA
!| IKLE2          |-->| SECOND POINT OF TETRAHEDRA
!| IKLE3          |-->| THIRD POINT OF TETRAHEDRA
!| IKLE4          |-->| FOURTH POINT OF TETRAHEDRA
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SF             |-->| BIEF_OBJ STRUCTURE OF F
!| SG             |-->| BIEF_OBJ STRUCTURE OF G
!| SURFAC         |-->| AREA OF TRIANGLES
!| W              |<--| RESULT IN NON ASSEMBLED FORM
!| XEL            |-->| ABSCISSAE OF POINTS IN THE MESH, PER ELEMENT
!| XMUL           |-->| MULTIPLICATION COEFFICIENT
!| YEL            |-->| ORDINATES OF POINTS IN THE MESH, PER ELEMENT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM          ! NUMBER OF ELEMENTS
      INTEGER, INTENT(IN) :: NPOIN          ! NUMBER OF POINTS
      INTEGER, INTENT(IN) :: ICOORD         ! DIRECTION OF GRAD :
                                            ! 1 - X
                                            ! 2 - Y
                                            ! 3 - Z
!
      INTEGER, INTENT(IN) :: IKLE1(nelem)  ! NODE NUMBER 1 OF ELEMENTS
      INTEGER, INTENT(IN) :: IKLE2(nelem)  ! NODE NUMBER 2 OF ELEMENTS
      INTEGER, INTENT(IN) :: IKLE3(nelem)  ! NODE NUMBER 3 OF ELEMENTS
      INTEGER, INTENT(IN) :: IKLE4(nelem)  ! NODE NUMBER 4 OF ELEMENTS
!
      DOUBLE PRECISION, DIMENSION(NPOIN), TARGET, INTENT(IN) :: X,Y,Z
      DOUBLE PRECISION, INTENT(IN)         :: XMUL        ! CONSTANT FACTOR
      DOUBLE PRECISION, INTENT(OUT)        :: W(nelem)   ! RESULT
!
!     STRUCTURES OF F, G, H, U, V, W AND REAL DATA
!
      TYPE(bief_obj)  , INTENT(IN)   :: SF,SG !
      DOUBLE PRECISION, INTENT(IN)   :: G(*)  ! VECTOR TO MULTIPLY BY
      DOUBLE PRECISION, INTENT(IN)   :: F(*)  ! VECTOR WE COMPUTE THE
                                              ! GRAD OF
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
! LOCAL VARIABLES
!
      INTEGER          :: IELEM,IELMF,IELMG ! ELEMENT TYPES
      DOUBLE PRECISION :: F1,F2,F3,F4       ! THE 4 VALUES OF F AT THE
                                            ! NODES OF AN ELEMENT
      DOUBLE PRECISION :: X2,X3,X4,Y2,Y3,Y4 ! DELTA_X, DELTA_Y
      DOUBLE PRECISION :: X1, Y1            ! COORD OF THE FIRST NODE
      INTEGER          :: I1,I2,I3,I4       ! THE NUMBERS OF THE NODES
                                            ! OF AN ELEMENT
!
      DOUBLE PRECISION, DIMENSION(:), POINTER :: PX, PY ! POINTER TO
                                                        ! THE COORD
      DOUBLE PRECISION          :: XSUR24
      DOUBLE PRECISION          :: F2MF1,F3MF1,F4MF1
      DOUBLE PRECISION          :: DET               ! JACOBIAN
!
!-----------------------------------------------------------------------
! INITIALISES
!
      xsur24 = xmul/24.d0
!
      ielmf = sf%ELM
      ielmg = sg%ELM
!
!-----------------------------------------------------------------------
! TEST ON THE COMPONENT TO DIFFERENTIATE :
! 1 FOR X, 2 FOR Y, 3 FOR Z. OTHER VALUES ARE NOT ALLOWED.
! THE POINTER POINTS TO THE ARRAYS OF THE COORDINATES THAT
! WILL BE USED.
      SELECT CASE (icoord )
        CASE ( 1 )
          px => y
          py => z
        CASE ( 2 )
          px => z
          py => x
        CASE ( 3 )
          px => x
          py => y
        CASE DEFAULT
          WRITE(lu,203) icoord
 203      FORMAT(1x,'VC11TT0 (BIEF) : IMPOSSIBLE COMPONENT ',
     &         1i6,' CHECK ICOORD')
          CALL plante(1)
      END SELECT
!
      IF(ielmf.EQ.31.AND.ielmg.EQ.30) THEN
!
! LOOP ON THE ELEMENTS
      DO  ielem = 1 , nelem
! GETS THE ID OF THE FOUR NODES OF THE ELEMENT
        i1 = ikle1(ielem)
        i2 = ikle2(ielem)
        i3 = ikle3(ielem)
        i4 = ikle4(ielem)
! GETS THE FOUR NODAL VALUES OF THE VECTOR TO DIFFERENTIATE
        f1 = f(i1)
        f2 = f(i2)
        f3 = f(i3)
        f4 = f(i4)
! DIFFERENCES OF THE NODAL VALUES OF F
        f2mf1 = f2-f1
        f3mf1 = f3-f1
        f4mf1 = f4-f1
!
!  REAL COORDINATES OF THE POINTS OF THE ELEMENT (ORIGIN IN 1)
!
        x1  =  px(i1)
        x2  =  px(i2) - x1
        x3  =  px(i3) - x1
        x4  =  px(i4) - x1
        y1  =  py(i1)
        y2  =  py(i2) - y1
        y3  =  py(i3) - y1
        y4  =  py(i4) - y1
        det =  (x3*y4-x4*y3)*f2mf1 + (y2*x4-x2*y4)*f3mf1+
     &          (x2*y3-y2*x3)*f4mf1
! RESULT
        w(ielem) = det* g(ielem) * xsur24
      ENDDO
!
!
!=======================================================================
!     ERROR ON THE ELEMENT TYPES
!
      ELSE
!-----------------------------------------------------------------------
!
        WRITE(lu,1101) ielmf,sf%NAME
        WRITE(lu,1201) ielmg,sg%NAME
        WRITE(lu,1301)
        CALL plante(1)
        stop
 1101   FORMAT(1x,'VC11TT0 (BIEF) :',/,
     &         1x,'DISCRETIZATION OF F:',1i6,
     &         1x,'REAL NAME: ',a6)
 1201   FORMAT(1x,'DISCRETIZATION OF G:',1i6,
     &         1x,'REAL NAME: ',a6)
 1301   FORMAT(1x,'CASE NOT IMPLEMENTED')
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE vc11tt0