vc09aa.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE vc09aa
!                   *****************
!
     &(xmul,sf,sg,su,sv,f,g,u,v,
     & xel,yel,ikle1,ikle2,ikle3,nelem,nelmax,w1,w2,w3 )
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE FOLLOWING VECTOR IN FINITE ELEMENTS:
!code
!+                    /                    DF        DF
!+      V  =  XMUL   /       PSII  * ( G U --  + G V -- )   D(OMEGA)
!+       I          /OMEGA                 DX        DY
!+
!+    PSI(I) IS A BASE OF TYPE P1 TRIANGLE
!
!warning  THE JACOBIAN MUST BE POSITIVE
!warning  THE RESULT IS IN W IN NOT ASSEMBLED FORM
!
!history  J-M HERVOUET (LNH)
!+        09/12/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| F              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| G              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| FORMUL         |-->| STRING WITH FORMULA OF VECTOR
!| IKLE           |-->| CONNECTIVITY TABLE
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SF             |-->| BIEF_OBJ STRUCTURE OF F
!| SG             |-->| BIEF_OBJ STRUCTURE OF G
!| SU             |-->| BIEF_OBJ STRUCTURE OF U
!| SV             |-->| BIEF_OBJ STRUCTURE OF V
!| U              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| V              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| W1             |<--| RESULT IN NON ASSEMBLED FORM
!| W2             |<--| RESULT IN NON ASSEMBLED FORM
!| W3             |<--| RESULT IN NON ASSEMBLED FORM
!| XEL            |-->| ABSCISSAE OF POINTS IN THE MESH, PER ELEMENT
!| XMUL           |-->| MULTIPLICATION COEFFICIENT
!| YEL            |-->| ORDINATES OF POINTS IN THE MESH, PER ELEMENT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_vc09aa => vc09aa
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX
      INTEGER, INTENT(IN) :: IKLE1(nelmax),IKLE2(nelmax),IKLE3(nelmax)
!
      DOUBLE PRECISION, INTENT(IN)    :: XEL(nelmax,*),YEL(nelmax,*)
      DOUBLE PRECISION, INTENT(INOUT) ::W1(nelmax),W2(nelmax),W3(nelmax)
      DOUBLE PRECISION, INTENT(IN)    :: XMUL
!
!     STRUCTURES OF F, G, U, V AND REAL DATA
!
      TYPE(bief_obj), INTENT(IN) :: SF,SG,SU,SV
      DOUBLE PRECISION, INTENT(IN) :: F(*),G(*),U(*),V(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IELMF,IELMU,IELMG,IELMV
!
      DOUBLE PRECISION X2,Y2,X3,Y3,F1,F2,F3,G1,G2,G3,U1,U2,U3,V1,V2,V3
      DOUBLE PRECISION XS120,T11,T12,T13,T22,T23,T33,FTX,FTY
      DOUBLE PRECISION U123,V123
!
!-----------------------------------------------------------------------
!
      xs120 = xmul / 120.d0
!
!-----------------------------------------------------------------------
!
      ielmf=sf%ELM
      ielmg=sg%ELM
      ielmu=su%ELM
      ielmv=sv%ELM
!
!-----------------------------------------------------------------------
!
!     FUNCTION F AND G AND VECTOR U ARE LINEAR
!
      IF(      ielmf.EQ.11.AND.ielmg.EQ.11
     &    .AND.ielmu.EQ.11.AND.ielmv.EQ.11  ) THEN
!
      DO ielem = 1 , nelem
!
        x2 = xel(ielem,2)
        x3 = xel(ielem,3)
        y2 = yel(ielem,2)
        y3 = yel(ielem,3)
!
        f1 = f(ikle1(ielem))
        f2 = f(ikle2(ielem))
        f3 = f(ikle3(ielem))
!
        g1 = g(ikle1(ielem))
        g2 = g(ikle2(ielem))
        g3 = g(ikle3(ielem))
!
        u1 = u(ikle1(ielem))
        u2 = u(ikle2(ielem))
        u3 = u(ikle3(ielem))
!
        v1 = v(ikle1(ielem))
        v2 = v(ikle2(ielem))
        v3 = v(ikle3(ielem))
!
        ftx = f1 * (x3-x2) - f2 * x3 + f3*x2
        fty = f1 * (y2-y3) + f2 * y3 - f3*y2
!
        u123 = u1 + u2 + u3
        v123 = v1 + v2 + v3
!
        t11 = ftx * ( v123 + v1 + v1 ) + fty * ( u123 + u1 + u1 )
        t22 = ftx * ( v123 + v2 + v2 ) + fty * ( u123 + u2 + u2 )
        t33 = ftx * ( v123 + v3 + v3 ) + fty * ( u123 + u3 + u3 )
!
        t12 = ftx * ( v123 + v123 - v3 ) + fty * ( u123 + u123 - u3 )
        t13 = ftx * ( v123 + v123 - v2 ) + fty * ( u123 + u123 - u2 )
        t23 = ftx * ( v123 + v123 - v1 ) + fty * ( u123 + u123 - u1 )
!
        w1(ielem) = ( 2 * g1*t11 +     g2*t12 +     g3*t13 ) * xs120
        w2(ielem) = (     g1*t12 + 2 * g2*t22 +     g3*t23 ) * xs120
        w3(ielem) = (     g1*t13 +     g2*t23 + 2 * g3*t33 ) * xs120
!
      ENDDO ! IELEM
!
!-----------------------------------------------------------------------
!
      ELSE
!
!-----------------------------------------------------------------------
!
        WRITE(lu,101) ielmf,sf%NAME
        WRITE(lu,111) ielmg,sg%NAME
        WRITE(lu,201) ielmu,su%NAME
        WRITE(lu,301)
101     FORMAT(1x,'VC09AA (BIEF) :',/,
     &         1x,'DISCRETIZATION OF F:',1i6,
     &         1x,'REAL NAME: ',a6)
111     FORMAT(1x,'DISCRETIZATION OF G:',1i6,
     &         1x,'REAL NAME: ',a6)
201     FORMAT(1x,'DISCRETIZATION OF U:',1i6,
     &         1x,'REAL NAME: ',a6)
301     FORMAT(1x,'CASE NOT IMPLEMENTED')
        CALL plante(0)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END