vc05oo.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE vc05oo
!                   *****************
!
     &(xmul,su,sv,u,v,xnor,ynor,lgseg,ikle,nbor,nelem,nelmax,w1,w2 )
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE FOLLOWING VECTOR IN FINITE ELEMENTS:
!code
!+                    /             ->   ->
!+    VEC(I) = XMUL  /    PSI(I) *  U  . N  D(OMEGA)
!+                  /OMEGA
!+
!+    PSI(I) IS A BASE OF TYPE P1 SEGMENT
!+    ->
!+    U IS A VECTOR WITH COMPONENTS U AND V
!+    ->
!+    N IS THE OUTGOING NORMAL VECTOR TO THE ELEMENT
!
!warning  THE JACOBIAN MUST BE POSITIVE
!warning  THE RESULT IS IN W IN NOT ASSEMBLED FORM
!
!history  J-M HERVOUET (LNH)
!+        29/05/08
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IKLE           |-->| CONNECTIVITY TABLE
!| LGSEG          |-->| LENGTH OF SEGMENTS
!| NBOR           |-->| GLOBAL NUMBER OF BOUNDARY POINTS
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SU             |-->| BIEF_OBJ STRUCTURE OF U
!| SV             |-->| BIEF_OBJ STRUCTURE OF V
!| U              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| V              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| W1             |<--| RESULT IN NON ASSEMBLED FORM
!| W2             |<--| RESULT IN NON ASSEMBLED FORM
!| XMUL           |-->| MULTIPLICATION COEFFICIENT
!| XNOR           |-->| FIRST COMPONENT OF NORMAL TO ELEMENT
!| YNOR           |-->| SECOND COMPONENT OF NORMAL TO ELEMENT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_vc05oo => vc05oo
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX
      INTEGER, INTENT(IN) :: IKLE(nelmax,*)
      INTEGER, INTENT(IN) :: NBOR(*)
!
      DOUBLE PRECISION, INTENT(IN)    :: XNOR(nelmax),YNOR(nelmax)
      DOUBLE PRECISION, INTENT(INOUT) :: W1(nelmax),W2(nelmax)
      DOUBLE PRECISION, INTENT(IN)    :: LGSEG(*)
      DOUBLE PRECISION, INTENT(IN)    :: XMUL
!
!     STRUCTURES OF U, V AND REAL DATA
!
      TYPE(bief_obj)  , INTENT(IN) :: SU,SV
      DOUBLE PRECISION, INTENT(IN) :: U(*),V(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER N1,N2,NG1,NG2,IELEM,IELMU,IELMV
      DOUBLE PRECISION XSUR06,U1,U2,V1,V2,VX1,VY1,VX2,VY2
!
!-----------------------------------------------------------------------
!
      xsur06 = xmul/6.d0
!
!-----------------------------------------------------------------------
!
      ielmu=su%ELM
      ielmv=sv%ELM
!
!-----------------------------------------------------------------------
!         ->
!   F AND U LINEAR FUNCTIONS ON TRIANGLES OR QUADRILATERALS
!
      IF( (ielmu.EQ.11.OR.ielmu.EQ.12.OR.ielmu.EQ.21) .AND.
     &    (ielmv.EQ.11.OR.ielmv.EQ.12.OR.ielmv.EQ.21)       ) THEN
!
      DO ielem =1,nelem
!
!     NUMBERING OF THE BOUNDARY NODES
!
!     GLOBAL NUMBERING
!
      ng1= nbor(ikle(ielem,1))
      ng2= nbor(ikle(ielem,2))
!
      u1 = u(ng1)
      u2 = u(ng2)
      v1 = v(ng1)
      v2 = v(ng2)
!
!   DETERMINES THE BASE FUNCTIONS AT THE BOUNDARY:
!
      vx1 = xsur06 * ( u2 + u1 + u1 )
      vy1 = xsur06 * ( v2 + v1 + v1 )
      vx2 = xsur06 * ( u1 + u2 + u2 )
      vy2 = xsur06 * ( v1 + v2 + v2 )
!
      w1(ielem) = lgseg(ielem) * ( vx1*xnor(ielem) + vy1*ynor(ielem) )
      w2(ielem) = lgseg(ielem) * ( vx2*xnor(ielem) + vy2*ynor(ielem) )
!
      ENDDO
!
!-----------------------------------------------------------------------
!   ->
!   U LINEAR FUNCTIONS ON SEGMENTS
!
      ELSEIF(ielmu.EQ.1.AND.ielmv.EQ.1) THEN
!
      DO ielem =1,nelem
!
!     NUMBERING OF THE BOUNDARY NODES
!
      n1 = ikle(ielem,1)
      n2 = ikle(ielem,2)
!
!     GLOBAL NUMBERING
!
      ng1= nbor(n1)
      ng2= nbor(n2)
!
      u1 = u(n1)
      u2 = u(n2)
      v1 = v(n1)
      v2 = v(n2)
!
!   DETERMINES THE BASE FUNCTIONS AT THE BOUNDARY:
!
      vx1 = xsur06 * ( u2 + u1 + u1 )
      vy1 = xsur06 * ( v2 + v1 + v1 )
      vx2 = xsur06 * ( u1 + u2 + u2 )
      vy2 = xsur06 * ( v1 + v2 + v2 )
!
      w1(ielem) = lgseg(ielem) * ( vx1*xnor(ielem) + vy1*ynor(ielem) )
      w2(ielem) = lgseg(ielem) * ( vx2*xnor(ielem) + vy2*ynor(ielem) )
!
      ENDDO
!
!-----------------------------------------------------------------------
!
      ELSE
!
!-----------------------------------------------------------------------
!
        WRITE(lu,110)
        WRITE(lu,112) ielmu,su%NAME
        WRITE(lu,113) ielmv,sv%NAME
        WRITE(lu,114)
110     FORMAT(1x,'VC05OO (BIEF):')
112     FORMAT(1x,'DISCRETIZATION OF U:',1i6,
     &         1x,'REAL NAME: ',a6)
113     FORMAT(1x,'DISCRETIZATION OF V:',1i6,
     &         1x,'REAL NAME: ',a6)
114     FORMAT(1x,'CASE NOT IMPLEMENTED')
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END