vc05ft.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE vc05ft
!                   *****************
!
     &(xmul,su,sv,u,v,x,y,z,
     & ikle1,ikle2,ikle3,nbor,nelem,nelmax,w1,w2,w3)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE FOLLOWING VECTOR IN FINITE ELEMENTS:
!code
!+                    /         ->
!+    VEC(I) = XMUL  /    (U,V).N  PSI(I) D(GAMMA)
!+                  /GAMMA
!+
!+    PSI(I) IS A BASE OF TYPE P1 TRIANGLE ON A LATERAL VERTICAL
!+    MESH (PRISMS MESH SPLIT IN TETRAHEDRONS)
!
!warning  THE JACOBIAN MUST BE POSITIVE
!warning  THE RESULT IS IN W1,2,3 IN NOT ASSEMBLED FORM
!
!history  J-M HERVOUET (LNH)    ; F LEPEINTRE (LNH)
!+        05/02/91
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IKLE1          |-->| FIRST POINT OF TRIANGLES
!| IKLE2          |-->| SECOND POINT OF TRIANGLES
!| IKLE3          |-->| THIRD POINT OF TRIANGLES
!| NBOR           |-->| GLOBAL NUMBER OF BOUNDARY POINTS
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SU             |-->| BIEF_OBJ STRUCTURE OF U
!| SV             |-->| BIEF_OBJ STRUCTURE OF V
!| U              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| V              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| W1             |<--| RESULT IN NON ASSEMBLED FORM
!| W2             |<--| RESULT IN NON ASSEMBLED FORM
!| W3             |<--| RESULT IN NON ASSEMBLED FORM
!| X              |-->| ABSCISSAE OF POINTS IN THE MESH
!| XMUL           |-->| MULTIPLICATION COEFFICIENT
!| Y              |-->| ORDINATES OF POINTS IN THE MESH
!| Z              |-->| ELEVATIONS OF POINTS IN THE MESH
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_vc05ft => vc05ft
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NBOR(*),NELEM,NELMAX
      INTEGER, INTENT(IN) :: IKLE1(nelmax),IKLE2(nelmax),IKLE3(nelmax)
!
      DOUBLE PRECISION, INTENT(IN)   :: X(*),Y(*),Z(*)
      DOUBLE PRECISION, INTENT(INOUT):: W1(nelmax),W2(nelmax),W3(nelmax)
      DOUBLE PRECISION, INTENT(IN)   :: XMUL
!
!-----------------------------------------------------------------------
!
!     STRUCTURES OF U, V AND REAL DATA
!
      TYPE(bief_obj), INTENT(IN)   :: SU,SV
      DOUBLE PRECISION, INTENT(IN) :: U(*),V(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      DOUBLE PRECISION U1,U2,U3,V1,V2,V3,X1,X2,X3,Y1,Y2,Y3,Z1,Z2,Z3
      DOUBLE PRECISION XSUR24
      INTEGER IELMU,IELMV,IELEM,N1,N2,N3,I1,I2,I3
!
!-----------------------------------------------------------------------
!
      ielmu=su%ELM
      ielmv=sv%ELM
!
!-----------------------------------------------------------------------
!
      xsur24 = xmul/24.d0
!
!     U LINEAR BY TETRAHEDRONS
!
!-----------------------------------------------------------------------
!
      IF(ielmu.EQ.61.AND.ielmv.EQ.61) THEN
!
!-----------------------------------------------------------------------
!
!   LOOP ON THE BOUNDARY SIDES
!
        DO ielem = 1,nelem
!
!         LOCAL NUMBERING OF THE SIDE NODES
!
          i1 = ikle1(ielem)
          i2 = ikle2(ielem)
          i3 = ikle3(ielem)
!
!         GLOBAL NUMBERING OF THE SIDE NODES
!
          n1 = nbor(i1)
          n2 = nbor(i2)
          n3 = nbor(i3)
!
          u1 = u(i1)
          u2 = u(i2)
          u3 = u(i3)
          v1 = v(i1)
          v2 = v(i2)
          v3 = v(i3)
!
          x1 = x(n1)
          x2 = x(n2)-x1
          x3 = x(n3)-x1
          y1 = y(n1)
          y2 = y(n2)-y1
          y3 = y(n3)-y1
          z1 = z(n1)
          z2 = z(n2)-z1
          z3 = z(n3)-z1
!
!         COMPUTES THE AREA OF THE TRIANGLE (BY VECTOR PRODUCT)
!
!         NOTE: VECTOR NORMAL TO THE TRIANGLE,
!               WHICH NORM IS THE SURFACE:
!
!                    0.5  (Y2*Z3-Y3*Z2)
!                    0.5  (X3*Z2-X2*Z3)
!                    0.5  (X2*Y3-X3*Y2)  : THIS TERM =0
!
!         INSPIRED FROM MASVEC ON TRIANGLES :
!
!
          w1(ielem) = xsur24* (  (y2*z3-y3*z2)*(2*u1+  u2+  u3)
     &                          +(x3*z2-x2*z3)*(2*v1+  v2+  v3) )
          w2(ielem) = xsur24* (  (y2*z3-y3*z2)*(  u1+2*u2+  u3)
     &                          +(x3*z2-x2*z3)*(  v1+2*v2+  v3) )
          w3(ielem) = xsur24* (  (y2*z3-y3*z2)*(  u1+  u2+2*u3)
     &                          +(x3*z2-x2*z3)*(  v1+  v2+2*v3) )
!
        ENDDO
!
!-----------------------------------------------------------------------
!
      ELSEIF(ielmu.EQ.51.AND.ielmv.EQ.51) THEN
!
!-----------------------------------------------------------------------
!
!   LOOP ON THE BOUNDARY SIDES
!
        DO ielem = 1,nelem
!
!         GLOBAL NUMBERING OF THE SIDE NODES
!
          n1 = nbor(ikle1(ielem))
          n2 = nbor(ikle2(ielem))
          n3 = nbor(ikle3(ielem))
!
          u1 = u(n1)
          u2 = u(n2)
          u3 = u(n3)
          v1 = v(n1)
          v2 = v(n2)
          v3 = v(n3)
          x1 = x(n1)
          x2 = x(n2)-x1
          x3 = x(n3)-x1
          y1 = y(n1)
          y2 = y(n2)-y1
          y3 = y(n3)-y1
          z1 = z(n1)
          z2 = z(n2)-z1
          z3 = z(n3)-z1
!
!         COMPUTES THE AREA OF THE TRIANGLE (BY VECTOR PRODUCT)
!
!         NOTE: VECTOR NORMAL TO THE TRIANGLE,
!               WHICH NORM IS THE SURFACE:
!
!                    0.5  (Y2*Z3-Y3*Z2)
!                    0.5  (X3*Z2-X2*Z3)
!                    0.5  (X2*Y3-X3*Y2)  : THIS TERM =0
!
!         INSPIRED FROM MASVEC ON TRIANGLES :
!
!
          w1(ielem) = xsur24* (  (y2*z3-y3*z2)*(2*u1+  u2+  u3)
     &                          +(x3*z2-x2*z3)*(2*v1+  v2+  v3) )
          w2(ielem) = xsur24* (  (y2*z3-y3*z2)*(  u1+2*u2+  u3)
     &                          +(x3*z2-x2*z3)*(  v1+2*v2+  v3) )
          w3(ielem) = xsur24* (  (y2*z3-y3*z2)*(  u1+  u2+2*u3)
     &                          +(x3*z2-x2*z3)*(  v1+  v2+2*v3) )
!
        ENDDO
!
!-----------------------------------------------------------------------
!
      ELSE
!
!-----------------------------------------------------------------------
!
        WRITE(lu,101) ielmu,su%NAME
101     FORMAT(1x,'VC05FT (BIEF) :',/,
     &         1x,'DISCRETIZATION OF U NOT AVAILABLE:',1i6,
     &         1x,'REAL NAME: ',a6)
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END