v8p2r0/html/vc04tt_8f_source.html

 !                   *****************
                     SUBROUTINE vc04tt
 !                   *****************
 !
      &(xmul,su,sv,sw,u,v,w,f,h,x,y,z,
      & ikle1,ikle2,ikle3,ikle4,nelem,nelmax,w1,w2,w3,w4,formul,specad,
      & npoin2,nelem2)
 !
 !***********************************************************************
 ! BIEF   V6P2                                   21/08/2010
 !***********************************************************************
 !
 !brief    COMPUTES THE FOLLOWING VECTOR IN FINITE ELEMENTS:
 !code
 !+                  /        D(PSII)       D(PSII)
 !+      V  = XMUL  /     U * ------- + V * -------   D(OMEGA)
 !+       I        /OMEGA       DX            DY
 !+
 !+                  /             D(PSII*)           D(PSII*)
 !+         = XMUL  /    DZ * U * -------- + DZ * V * --------   D(OMEGA*)
 !+                /OMEGA*           DX                 DY
 !+
 !+    PSII IS OF TYPE P1 TETRAHEDRON
 !+
 !+    REAL MESH HERE, CAN BE REGARDED AS A COMPUTATION
 !+    IN A TRANSFORMED MESH, BUT WITH H IN THE INTEGRAL.
 !
 !warning  THE JACOBIAN MUST BE POSITIVE
 !warning  THE RESULT IS IN W IN NOT ASSEMBLED FORM
 !warning  IF SPECAD=.TRUE., THE ADVECTING FIELD IS NOT ONLY
 !+        U AND V BUT U+DM1*GRAD(ZCONV). GRAD(ZCONV) IS HERE H, DM1 IS F
 !+
 !
 !history  J-M HERVOUET (LNH)
 !+        22/03/02
 !+        V5P3
 !+
 !
 !history  N.DURAND (HRW), S.E.BOURBAN (HRW)
 !+        13/07/2010
 !+        V6P0
 !+   Translation of French comments within the FORTRAN sources into
 !+   English comments
 !
 !history  N.DURAND (HRW), S.E.BOURBAN (HRW)
 !+        21/08/2010
 !+        V6P0
 !+   Creation of DOXYGEN tags for automated documentation and
 !+   cross-referencing of the FORTRAN sources
 !
 !history  J-M HERVOUET (LNHE)
 !+        07/09/2011
 !+        V6P2
 !+   Adaptation to case SPECAD=.TRUE.
 !
 !~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 !| FORMUL         |-->| STRING WITH FORMULA OF VECTOR
 !| IKLE1          |-->| FIRST POINT OF TETRAHEDRA
 !| IKLE2          |-->| SECOND POINT OF TETRAHEDRA
 !| IKLE3          |-->| THIRD POINT OF TETRAHEDRA
 !| IKLE4          |-->| FOURTH POINT OF TETRAHEDRA
 !| NELEM          |-->| NUMBER OF ELEMENTS
 !| NELEM2         |-->| NUMBER OF 2D ELEMENTS (CASE SPECAD)
 !| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
 !| SPECAD         |-->| IF YES, SPECIAL ADVECTION FIELD, SEE ABOVE
 !| SU             |-->| BIEF_OBJ STRUCTURE OF U
 !| SV             |-->| BIEF_OBJ STRUCTURE OF V
 !| SW             |-->| BIEF_OBJ STRUCTURE OF W
 !| U              |-->| FUNCTION USED IN THE VECTOR FORMULA
 !| V              |-->| FUNCTION USED IN THE VECTOR FORMULA
 !| W              |-->| FUNCTION USED IN THE VECTOR FORMULA
 !| W1             |<--| RESULT IN NON ASSEMBLED FORM
 !| W2             |<--| RESULT IN NON ASSEMBLED FORM
 !| W3             |<--| RESULT IN NON ASSEMBLED FORM
 !| W4             |<--| RESULT IN NON ASSEMBLED FORM
 !| X              |-->| ABSCISSAE OF POINTS IN THE MESH
 !| Y              |-->| ORDINATES OF POINTS IN THE MESH
 !| XMUL           |-->| MULTIPLICATION COEFFICIENT
 !| Z              |-->| ELEVATIONS OF POINTS
 !~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 !
       USE bief, ex_vc04tt => vc04tt
 !
       USE declarations_special
       IMPLICIT NONE
 !
 !+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 !
       INTEGER, INTENT(IN) :: NELEM,NELMAX,NELEM2,NPOIN2
       INTEGER, INTENT(IN) :: IKLE1(nelmax),IKLE2(nelmax)
       INTEGER, INTENT(IN) :: IKLE3(nelmax),IKLE4(nelmax)
 !
       DOUBLE PRECISION, INTENT(IN)    :: X(*),Y(*),Z(*)
       DOUBLE PRECISION, INTENT(INOUT) :: W1(nelmax),W2(nelmax)
       DOUBLE PRECISION, INTENT(INOUT) :: W3(nelmax),W4(nelmax)
       DOUBLE PRECISION, INTENT(IN)    :: XMUL
 !
       LOGICAL, INTENT(IN) :: SPECAD
 !
       CHARACTER(LEN=16), INTENT(IN) :: FORMUL
 !
 !     STRUCTURES AND THERE REAL DATA
 !
       TYPE(bief_obj),   INTENT(IN) :: SU,SV,SW
       DOUBLE PRECISION, INTENT(IN) :: U(*),V(*),W(*),F(*)
       DOUBLE PRECISION, INTENT(IN) :: H(*)
 !
 !+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 !
       DOUBLE PRECISION XSUR24,XSUR120,X2,X3,X4,Y2,Y3,Y4,Z1,Z2,Z3,Z4
       DOUBLE PRECISION F123,F134,F142,F243
       DOUBLE PRECISION U1,U2,U3,U4,V1,V2,V3,V4
       DOUBLE PRECISION UUUU,VVVV,WWWW,H1,H2,H3,H4
       INTEGER I1,I2,I3,I4,IELEM,IELEM2,IELMU,IELMV,IELMW
       INTEGER IP,I12D,I22D,I32D,I42D
 !
 !**********************************************************************
 !
       xsur24  = xmul /  24.d0
       xsur120 = xmul / 120.d0
 !
 !-----------------------------------------------------------------------
 !
       ielmu=su%ELM
       ielmv=sv%ELM
       ielmw=sw%ELM
 !
 !-----------------------------------------------------------------------
 !
 !   HORIZONTAL TERMS
 !
       IF(formul(14:16).EQ.'HOR') THEN
 !
 !   LOOP ON THE ELEMENTS
 !
         IF(ielmu.EQ.51.AND.ielmv.EQ.51) THEN
 !
 !-----------------------------------------------------------------------
 !
 !  U AND V DISCRETISED IN P1 PRISM:
 !
           IF(.NOT.specad) THEN
 !
 !     STANDARD CASE
 !
             DO ielem = 1 , nelem
 !
               i1 = ikle1(ielem)
               i2 = ikle2(ielem)
               i3 = ikle3(ielem)
               i4 = ikle4(ielem)
 !
               x2 = x(i2) - x(i1)
               x3 = x(i3) - x(i1)
               x4 = x(i4) - x(i1)
 !
               y2 = y(i2) - y(i1)
               y3 = y(i3) - y(i1)
               y4 = y(i4) - y(i1)
 !
 !             REAL MESH
 !
 !             Z2 = Z(I2) - Z(I1)
 !             Z3 = Z(I3) - Z(I1)
 !             Z4 = Z(I4) - Z(I1)
 !
               u1 = u(i1)
               u2 = u(i2)
               u3 = u(i3)
               u4 = u(i4)
               v1 = v(i1)
               v2 = v(i2)
               v3 = v(i3)
               v4 = v(i4)
 !
 !             RETRIEVING THE LOWER PLANE NUMBER
 !
               ip=(min(i1,i2,i3,i4)-1)/npoin2 +1
 !
 !             TRANSFORMED MESH, 0 FOR LOWER POINTS, 1 FOR UPPER POINTS
 !
               z1=dble((i1-1)/npoin2+1-ip)
               z2=dble((i2-1)/npoin2+1-ip)-z1
               z3=dble((i3-1)/npoin2+1-ip)-z1
               z4=dble((i4-1)/npoin2+1-ip)-z1
 !
 !             RETRIEVING THE 2D POINTS NUMBERS ON THE SAME VERTICAL
 !
               i12d=mod(i1-1,npoin2)+1
               i22d=mod(i2-1,npoin2)+1
               i32d=mod(i3-1,npoin2)+1
               i42d=mod(i4-1,npoin2)+1
 !
 !             RETRIEVING THE ORIGINAL PRISM HEIGHTS ON THE VERTICAL
 !             TWO OF THE FOUR HEIGHTS WILL BE EQUAL, THE TWO CORRESPONDING
 !             POINTS OF THE TETRAHEDRON BEING ON THE SAME VERTICAL
 !
               h1=z(ip*npoin2+i12d)-z((ip-1)*npoin2+i12d)
               h2=z(ip*npoin2+i22d)-z((ip-1)*npoin2+i22d)
               h3=z(ip*npoin2+i32d)-z((ip-1)*npoin2+i32d)
               h4=z(ip*npoin2+i42d)-z((ip-1)*npoin2+i42d)
 !
 !             EACH CONTRIBUTION IS THE EXITING FLUX THROUGH ADJACENT FACES / 3
 !             THE TOTAL FLUX IS ZERO, SO THE RESULT IS THE ENTERING FLUX
 !             THROUGH THE OPPOSITE FACE /3
 !             POINT 1 :   (FACE 123 + FACE 134 + FACE 142) /3 = - (FACE 243) /3
 !             POINT 2 : - (FACE 134) /3
 !             POINT 3 : - (FACE 142) /3
 !             POINT 4 : - (FACE 123) /3
 !
 !             FIJK IS IN FACT 8 TIMES THE REAL FLUX THROUGH FACE IJK
 !
 !             IN THE REAL MESH (WITH COEFFICIENT XSUR24)
 !
 !             UUUU=U1+U2+U3+U4
 !             VVVV=V1+V2+V3+V4
 !
 !             IN THE TRANSFORMED MESH (WITH COEFFICIENT XSUR120)
 !
               uuuu=(h1*u1+h2*u2+h3*u3+h4*u4+(h1+h2+h3+h4)*(u1+u2+u3+u4))
               vvvv=(h1*v1+h2*v2+h3*v3+h4*v4+(h1+h2+h3+h4)*(v1+v2+v3+v4))
 !
 !             FLUXES WITH OUTWARD NORMAL VECTOR
 !
               f123=(z2*y3-z3*y2)*uuuu+(x2*z3-z2*x3)*vvvv
               f134=(z3*y4-z4*y3)*uuuu+(x3*z4-z3*x4)*vvvv
               f142=(z4*y2-z2*y4)*uuuu+(x4*z2-z4*x2)*vvvv
               f243=-f123-f134-f142
 !
 !             REAL MESH
 !
 !             W1(IELEM) = -F243*XSUR24
 !             W2(IELEM) = -F134*XSUR24
 !             W3(IELEM) = -F142*XSUR24
 !             W4(IELEM) = -F123*XSUR24
 !
 !             TRANSFORMED MESH
 !
               w1(ielem) = -f243*xsur120
               w2(ielem) = -f134*xsur120
               w3(ielem) = -f142*xsur120
               w4(ielem) = -f123*xsur120
 !
             ENDDO
 !
           ELSE
 !
 !           CASE WITH SPECIFIC ADVECTING FIELD
 !
             DO ielem = 1 , nelem
 !
 !             CORRESPONDING 2D ELEMENT ON THE VERTICAL
 !             SEE NUMBERING OF ELEMENTS WHEN PRISMS ARE
 !             CUT INTO TETRAHEDRONS
 !
               ielem2 = mod(ielem-1,nelem2) + 1
 !
               i1 = ikle1(ielem)
               i2 = ikle2(ielem)
               i3 = ikle3(ielem)
               i4 = ikle4(ielem)
 !
               x2 = x(i2) - x(i1)
               x3 = x(i3) - x(i1)
               x4 = x(i4) - x(i1)
 !
               y2 = y(i2) - y(i1)
               y3 = y(i3) - y(i1)
               y4 = y(i4) - y(i1)
 !
 !             REAL MESH
 !
 !             Z2 = Z(I2) - Z(I1)
 !             Z3 = Z(I3) - Z(I1)
 !             Z4 = Z(I4) - Z(I1)
 !
 !
 !             RETRIEVING THE LOWER PLANE NUMBER
 !
               ip=(min(i1,i2,i3,i4)-1)/npoin2 +1
 !
 !             TRANSFORMED MESH, 0 FOR LOWER POINTS, 1 FOR UPPER POINTS
 !
               z1=dble((i1-1)/npoin2+1-ip)
               z2=dble((i2-1)/npoin2+1-ip)-z1
               z3=dble((i3-1)/npoin2+1-ip)-z1
               z4=dble((i4-1)/npoin2+1-ip)-z1
 !
 !             SPECIFIC ADVECTION FIELD
 !
               u1 = u(i1)+f(i1)*h(ielem2+(1-1)*nelem2)
               u2 = u(i2)+f(i2)*h(ielem2+(1-1)*nelem2)
               u3 = u(i3)+f(i3)*h(ielem2+(1-1)*nelem2)
               u4 = u(i4)+f(i4)*h(ielem2+(1-1)*nelem2)
               v1 = v(i1)+f(i1)*h(ielem2+(2-1)*nelem2)
               v2 = v(i2)+f(i2)*h(ielem2+(2-1)*nelem2)
               v3 = v(i3)+f(i3)*h(ielem2+(2-1)*nelem2)
               v4 = v(i4)+f(i4)*h(ielem2+(2-1)*nelem2)
 !
 !             RETRIEVING THE 2D POINTS NUMBERS ON THE SAME VERTICAL
 !
               i12d=mod(i1-1,npoin2)+1
               i22d=mod(i2-1,npoin2)+1
               i32d=mod(i3-1,npoin2)+1
               i42d=mod(i4-1,npoin2)+1
 !
 !             RETRIEVING THE ORIGINAL PRISM HEIGHTS ON THE VERTICAL
 !             TWO OF THE FOUR HEIGHTS WILL BE EQUAL, THE TWO CORRESPONDING
 !             POINTS OF THE TETRAHEDRON BEING ON THE SAME VERTICAL
 !
               h1=z(ip*npoin2+i12d)-z((ip-1)*npoin2+i12d)
               h2=z(ip*npoin2+i22d)-z((ip-1)*npoin2+i22d)
               h3=z(ip*npoin2+i32d)-z((ip-1)*npoin2+i32d)
               h4=z(ip*npoin2+i42d)-z((ip-1)*npoin2+i42d)
 !
 !             EACH CONTRIBUTION IS THE EXITING FLUX THROUGH ADJACENT FACES / 3
 !             THE TOTAL FLUX IS ZERO, SO THE RESULT IS THE ENTERING FLUX
 !             THROUGH THE OPPOSITE FACE /3
 !             POINT 1 :   (FACE 123 + FACE 134 + FACE 142) /3 = - (FACE 243) /3
 !             POINT 2 : - (FACE 134) /3
 !             POINT 3 : - (FACE 142) /3
 !             POINT 4 : - (FACE 123) /3
 !
 !             FIJK IS IN FACT 8 TIMES THE REAL FLUX THROUGH FACE IJK
 !
 !             IN THE REAL MESH (WITH COEFFICIENT XSUR24)
 !
 !             UUUU=U1+U2+U3+U4
 !             VVVV=V1+V2+V3+V4
 !
 !             IN THE TRANSFORMED MESH (WITH COEFFICIENT XSUR120)
 !             SIMPLIFYING BY TAKING AVERAGE DEPTH * AVERAGE VELOCITY
 !             WITH AVERAGE DEPTH = REAL VOLUME / TRANSFORMED VOLUME
 !             DOES NOT SEEM TO WORK VERY WELL (NON LINEAR WAVES, BUMPRES)
 !
               uuuu=(h1*u1+h2*u2+h3*u3+h4*u4+(h1+h2+h3+h4)
      &            *(u1+u2+u3+u4))
               vvvv=(h1*v1+h2*v2+h3*v3+h4*v4+(h1+h2+h3+h4)
      &            *(v1+v2+v3+v4))
 !
 !             FLUXES WITH OUTWARD NORMAL VECTOR
 !
               f123=(z2*y3-z3*y2)*uuuu+(x2*z3-z2*x3)*vvvv
               f134=(z3*y4-z4*y3)*uuuu+(x3*z4-z3*x4)*vvvv
               f142=(z4*y2-z2*y4)*uuuu+(x4*z2-z4*x2)*vvvv
               f243=-f123-f134-f142
 !
 !             REAL MESH
 !
 !             W1(IELEM) = -F243*XSUR24
 !             W2(IELEM) = -F134*XSUR24
 !             W3(IELEM) = -F142*XSUR24
 !             W4(IELEM) = -F123*XSUR24
 !
 !             TRANSFORMED MESH
 !
               w1(ielem) = -f243*xsur120
               w2(ielem) = -f134*xsur120
               w3(ielem) = -f142*xsur120
               w4(ielem) = -f123*xsur120
 !
             ENDDO
 !
           ENDIF
 !
 !-----------------------------------------------------------------------
 !
 !     ELSEIF(IELMU.EQ.  ) THEN
 !
 !-----------------------------------------------------------------------
 !
         ELSE
 !
 !-----------------------------------------------------------------------
 !
           WRITE(lu,102) ielmu,su%NAME
 102       FORMAT(1x,'VC04TT (BIEF) :',/,
      &        1x,'DISCRETISATION OF U ET V : ',1i6,' NOT IMPLEMENTED',/,
      &        1x,'REAL NAME OF U : ',a6)
           CALL plante(1)
           stop
 !
         ENDIF
 !
 !-----------------------------------------------------------------------
 !
       ELSEIF(formul(14:16).EQ.'TOT') THEN
 !
         IF(ielmw.NE.31.AND.ielmw.NE.51) THEN
           WRITE(lu,302)
 302       FORMAT(1x,'VC04TT (BIEF) :',/,
      &           1x,.NE..NE.'UNEXPECTED CASE (IELMW31 AND 51)')
           CALL plante(1)
           stop
         ENDIF
 !
         DO ielem = 1 , nelem
 !
           i1 = ikle1(ielem)
           i2 = ikle2(ielem)
           i3 = ikle3(ielem)
           i4 = ikle4(ielem)
 !
           x2 = x(i2) - x(i1)
           x3 = x(i3) - x(i1)
           x4 = x(i4) - x(i1)
 !
           y2 = y(i2) - y(i1)
           y3 = y(i3) - y(i1)
           y4 = y(i4) - y(i1)
 !
           z2 = z(i2) - z(i1)
           z3 = z(i3) - z(i1)
           z4 = z(i4) - z(i1)
 !
           uuuu=u(i1)+u(i2)+u(i3)+u(i4)
           vvvv=v(i1)+v(i2)+v(i3)+v(i4)
           wwww=w(i1)+w(i2)+w(i3)+w(i4)
 !
           f123=(z2*y3-z3*y2)*uuuu+(x2*z3-z2*x3)*vvvv+(x3*y2-x2*y3)*wwww
           f134=(z3*y4-z4*y3)*uuuu+(x3*z4-z3*x4)*vvvv+(x4*y3-x3*y4)*wwww
           f142=(z4*y2-z2*y4)*uuuu+(x4*z2-z4*x2)*vvvv+(x2*y4-x4*y2)*wwww
           f243=-f123-f134-f142
 !
           w1(ielem) = -f243*xsur24
           w2(ielem) = -f134*xsur24
           w3(ielem) = -f142*xsur24
           w4(ielem) = -f123*xsur24
 !
 !
 !              ORIGINAL MAPLE FORMULAS FOR HORIZONTAL PART
 !
 !              W1(IELEM) = XSUR24*(
 !          &U3*Z2*Y3+V4*X3*Z4-U4*Y3*Z4+U4*Z2*Y3+U4*Y4*Z3-U4*Z2*Y4-U4*
 !          &Y2*Z3+U1*Y4*Z3+V1*Z2*X4-V4*X2*Z4-U3*Z2*Y4-U2*Y2*Z3+V4*X2*Z3+V4*Z2*
 !          &X4-V4*X4*Z3+V2*Z2*X4-U2*Z2*Y4+U2*Y2*Z4+U2*Y4*Z3+U2*Z2*Y3-V1*Z2*X3+
 !          &V1*X2*Z3-V1*X4*Z3+V1*X3*Z4+U3*Y2*Z4+U3*Y4*Z3-V3*X2*Z4-V3*X4*Z3+V3*
 !          &X3*Z4-V3*Z2*X3+V3*X2*Z3+V3*Z2*X4+U1*Z2*Y3-U1*Y2*Z3+U1*Y2*Z4-V2*X2*
 !          &Z4-V2*X4*Z3-V2*Z2*X3+V2*X2*Z3-U3*Y2*Z3+V2*X3*Z4-V4*Z2*X3-U1*Y3*Z4+
 !          &U4*Y2*Z4-U3*Y3*Z4-V1*X2*Z4-U1*Z2*Y4-U2*Y3*Z4)
 !
 !              W2(IELEM) = XSUR24*(
 !          &-U4*Y4*Z3+U4*Y3*Z4-V4*X3*Z4+V4*X4*Z3+U1*Y3*Z4-U1*Y4*Z3-V3
 !          &*X3*Z4+V3*X4*Z3+U3*Y3*Z4-U3*Y4*Z3-V1*X3*Z4+V1*X4*Z3+U2*Y3*Z4-U2*Y4
 !          &*Z3-V2*X3*Z4+V2*X4*Z3)
 !
 !              W3(IELEM) = XSUR24*(
 !          &U4*Z2*Y4-U4*Y2*Z4-V4*Z2*X4+U3*Z2*Y4+V4*X2*Z4-V1*Z2*X4-U1*
 !          &Y2*Z4-V3*Z2*X4+V3*X2*Z4-U3*Y2*Z4+V1*X2*Z4-U2*Y2*Z4+U2*Z2*Y4-V2*Z2*
 !          &X4+V2*X2*Z4+U1*Z2*Y4)
 !
 !              W4(IELEM) = XSUR24*(
 !          &U4*Y2*Z3-U4*Z2*Y3+V4*Z2*X3-V4*X2*Z3+U1*Y2*Z3-U1*Z2*Y3+U3*
 !          &Y2*Z3-U3*Z2*Y3-V3*X2*Z3+V3*Z2*X3-V1*X2*Z3+V1*Z2*X3-U2*Z2*Y3+U2*Y2*
 !          &Z3-V2*X2*Z3+V2*Z2*X3)
 !
 !              ORIGINAL MAPLE FORMULAS FOR VERTICAl PART
 !
 !              Q1 = W(I1)
 !              Q2 = W(I2)
 !              Q3 = W(I3)
 !              Q4 = W(I4)
 !
 !              W1(IELEM) = (
 !          &         X4*Y3*Q4-Y2*X4*Q4+X2*Y4*Q4-X2*Y3*Q4-X3*Y4*Q4+Y2*X3*Q4-X2*
 !          &Y3*Q3-Y2*X4*Q3+X2*Y4*Q1-X3*Y4*Q3+X2*Y4*Q3+Y2*X3*Q3-X3*Y4*Q2+X4*Y3*
 !          &Q2+X2*Y4*Q2-Y2*X4*Q2-X2*Y3*Q2+Y2*X3*Q2+Y2*X3*Q1-Y2*X4*Q1-X2*Y3*Q1+
 !          &X4*Y3*Q3+X4*Y3*Q1-X3*Y4*Q1 )*XSUR24
 !
 !              W2(IELEM) = (
 !          &         -X4*Y3*Q4+X3*Y4*Q4+X3*Y4*Q3+X3*Y4*Q2-X4*Y3*Q2-X4*Y3*Q3-X4
 !          &*Y3*Q1+X3*Y4*Q1 )*XSUR24
 !
 !              W3(IELEM) = (
 !          &         Y2*X4*Q4-X2*Y4*Q4+Y2*X4*Q3-X2*Y4*Q1-X2*Y4*Q3-X2*Y4*Q2+Y2*
 !          &X4*Q2+Y2*X4*Q1 )*XSUR24
 !
 !              W4(IELEM) = (
 !          &         X2*Y3*Q4-Y2*X3*Q4+X2*Y3*Q3-Y2*X3*Q3+X2*Y3*Q2-Y2*X3*Q2-Y2*
 !          &X3*Q1+X2*Y3*Q1 )*XSUR24
 !
         ENDDO
 !
       ELSE
 !
 !-----------------------------------------------------------------------
 !
         WRITE(lu,202) formul
 202     FORMAT(1x,'VC04TT (BIEF):',/,
      &         1x,'HOR OR VER LACKING AT THE END OF THE FORMULA : ',a16)
         CALL plante(1)
         stop
 !
 !-----------------------------------------------------------------------
 !
       ENDIF
 !
 !-----------------------------------------------------------------------
 !
       RETURN
       END
declarations_special
Definition: declarations_special.F:3

declarations_special::lu
integer lu
Definition: declarations_special.F:45

vc04tt
subroutine vc04tt(XMUL, SU, SV, SW, U, V, W, F, H, X, Y, Z, IKLE1, IKLE2, IKLE3, IKLE4, NELEM, NELMAX, W1, W2, W3, W4, FORMUL, SPECAD, NPOIN2, NELEM2)
Definition: vc04tt.f:9

bief
Definition: bief.f:3