v8p2r0/html/vc04pp_8f_source.html

 !                   *****************
                     SUBROUTINE vc04pp
 !                   *****************
 !
      &( xmul,su,sv,sw,u,v,w,f,h,x,y,z,
      &  ikle1,ikle2,ikle3,ikle4,ikle5,ikle6,nelem,nelmax,
      &  w1,w2,w3,w4,w5,w6,specad,formul,nelem2)
 !
 !***********************************************************************
 ! BIEF   V6P3                                   21/08/2010
 !***********************************************************************
 !
 !brief    COMPUTES THE FOLLOWING VECTOR IN FINITE ELEMENTS:
 !code
 !+     IF FORMUL ENDS WITH 'HOR'
 !+     IN THE TRANSFORMED MESH
 !+
 !+                 /            D(PSII*)           D(PSII*)
 !+     V  = XMUL  /    H * U * -------- +  H * V * --------   D(OMEGA*)
 !+      I        /OMEGA*          DX                 DY
 !+
 !+     BEWARE : TRANSFORMED MESH HERE !!!!
 !+
 !+
 !+     IF FORMUL ENDS WITH 'TOT'
 !+     IN THE REAL MESH
 !+
 !+                 /     ->  --->
 !+     V  = XMUL  /      U * GRAD(PSI)   D(OMEGA*)
 !+      I        /OMEGA
 !+
 !+     BEWARE : REAL MESH HERE !!!!
 !+
 !+     PSII IS OF TYPE P1 PRISM
 !
 !warning  THE JACOBIAN MUST BE POSITIVE
 !warning  THE RESULT IS IN W IN NOT ASSEMBLED FORM
 !warning  IF SPECAD=.TRUE., THE ADVECTING FIELD IS NOT ONLY
 !+        U AND V BUT U+DM1*GRAD(ZCONV). ZCONV IS HERE G, DM1 IS F
 !+        GRAD(ZCONV) IS HERE H, DM1 IS F
 !+
 !warning  VERSION 6.1: WITH MASS-LUMPING ON THE VERTICAL
 !
 !history  J-M HERVOUET (LNHE)
 !+        21/06/06
 !+        V6P0
 !+
 !
 !history  N.DURAND (HRW), S.E.BOURBAN (HRW)
 !+        13/07/2010
 !+        V6P0
 !+   Translation of French comments within the FORTRAN sources into
 !+   English comments
 !
 !history  N.DURAND (HRW), S.E.BOURBAN (HRW)
 !+        21/08/2010
 !+        V6P0
 !+   Creation of DOXYGEN tags for automated documentation and
 !+   cross-referencing of the FORTRAN sources
 !
 !history  J-M HERVOUET (LNHE)
 !+        07/09/2011
 !+        V6P2
 !+   Case SPECAD=.TRUE. differently treated, with gradient of ZCONV
 !+   now given as argument.
 !
 !history  J-M HERVOUET (EDF R&D LNHE)
 !+        07/01/2013
 !+        V6P3
 !+   X and Y are now given per element.
 !
 !~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 !| F              |-->| FUNCTION USED IN THE VECTOR FORMULA
 !| H              |-->| FUNCTION USED IN THE VECTOR FORMULA
 !| FORMUL         |-->| STRING WITH FORMULA OF VECTOR
 !| IKLE1          |-->| FIRST POINT OF PRISMS
 !| IKLE2          |-->| SECOND POINT OF PRISMS
 !| IKLE3          |-->| THIRD POINT OF PRISMS
 !| IKLE4          |-->| FOURTH POINT OF PRISMS
 !| IKLE5          |-->| FIFTH POINT OF PRISMS
 !| IKLE6          |-->| SIXTH POINT OF PRISMS
 !| NELEM          |-->| NUMBER OF ELEMENTS
 !| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
 !| NPLAN          |-->| NUMBER OF PLANES IN THE MESH OF PRISMS
 !| SPECAD         |-->| IF YES, SPECIAL ADVECTION FIELD, SEE ABOVE
 !| SU             |-->| BIEF_OBJ STRUCTURE OF U
 !| SV             |-->| BIEF_OBJ STRUCTURE OF V
 !| SW             |-->| BIEF_OBJ STRUCTURE OF W
 !| U              |-->| FUNCTION USED IN THE VECTOR FORMULA
 !| V              |-->| FUNCTION USED IN THE VECTOR FORMULA
 !| W              |-->| FUNCTION USED IN THE VECTOR FORMULA
 !| W1             |<--| RESULT IN NON ASSEMBLED FORM
 !| W2             |<--| RESULT IN NON ASSEMBLED FORM
 !| W3             |<--| RESULT IN NON ASSEMBLED FORM
 !| W4             |<--| RESULT IN NON ASSEMBLED FORM
 !| W5             |<--| RESULT IN NON ASSEMBLED FORM
 !| W6             |<--| RESULT IN NON ASSEMBLED FORM
 !| X              |-->| ABSCISSAE OF POINTS IN THE MESH, PER ELEMENT
 !| Y              |-->| ORDINATES OF POINTS IN THE MESH, PER ELEMENT
 !| XMUL           |-->| MULTIPLICATION COEFFICIENT
 !| Z              |-->| ELEVATIONS OF POINTS IN THE MESH, PER POINT !!!
 !~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 !
       USE bief, ex_vc04pp => vc04pp
 !
       USE declarations_special
       IMPLICIT NONE
 !
 !+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 !
       INTEGER, INTENT(IN) :: NELEM,NELMAX,NELEM2
       INTEGER, INTENT(IN) :: IKLE1(nelmax),IKLE2(nelmax),IKLE3(nelmax)
       INTEGER, INTENT(IN) :: IKLE4(nelmax),IKLE5(nelmax),IKLE6(nelmax)
 !
       DOUBLE PRECISION, INTENT(IN)   ::X(nelmax,6),Y(nelmax,6),Z(*)
       DOUBLE PRECISION, INTENT(INOUT)::W1(nelmax),W2(nelmax),W3(nelmax)
       DOUBLE PRECISION, INTENT(INOUT)::W4(nelmax),W5(nelmax),W6(nelmax)
       DOUBLE PRECISION, INTENT(IN)   ::XMUL
 !
       LOGICAL, INTENT(IN) :: SPECAD
       CHARACTER(LEN=16), INTENT(IN) :: FORMUL
 !
 !     STRUCTURES AND THEIR REAL DATA
 !
       TYPE(bief_obj),   INTENT(IN) :: SU,SV,SW
       DOUBLE PRECISION, INTENT(IN) :: U(*),V(*),W(*),F(*)
       DOUBLE PRECISION, INTENT(IN) :: H(nelem2,2)
 !
 !+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
 !
       DOUBLE PRECISION SUR144,X1,X2,X3,Y1,Y2,Y3,H1,H2,H3,SHT
       DOUBLE PRECISION HU1,HU2,HUINF,HUSUP,HV1,HV2,HVINF,HVSUP
       DOUBLE PRECISION U1,U2,U3,U4,U5,U6,V1,V2,V3,V4,V5,V6
       DOUBLE PRECISION Q1,Q2,Q3,Q4,Q5,Q6,Z2,Z3,Z4,Z5,Z6
 !     DOUBLE PRECISION GRADGX,GRADGY,DET
       INTEGER I1,I2,I3,I4,I5,I6,IELEM2
       INTEGER IELEM,IELMU,IELMV,IELMW
 !
 !**********************************************************************
 !
       sur144 = xmul / 144.d0
 !
 !-----------------------------------------------------------------------
 !
       ielmu=su%ELM
       ielmv=sv%ELM
       ielmw=sw%ELM
 !
 !-----------------------------------------------------------------------
 !
 !   TERMES HORIZONTAUX
 !
       IF(formul(14:16).EQ.'HOR') THEN
 !
 !   BOUCLE SUR LES ELEMENTS
 !
         IF(ielmu.EQ.41.AND.ielmv.EQ.41) THEN
 !
 !-----------------------------------------------------------------------
 !
 !  U ET V DISCRETISEES EN PRISME P1 :
 !
           IF(.NOT.specad) THEN
 !
 !     STANDARD CASE
 !
             DO ielem = 1 , nelem
 !
               i1 = ikle1(ielem)
               i2 = ikle2(ielem)
               i3 = ikle3(ielem)
               i4 = ikle4(ielem)
               i5 = ikle5(ielem)
               i6 = ikle6(ielem)
 !
               h1 = z(i4) - z(i1)
               h2 = z(i5) - z(i2)
               h3 = z(i6) - z(i3)
               sht = h1 + h2 + h3
 !
               hu1 = (u(i1)+u(i2)+u(i3))*sht + h1*u(i1) + h2*u(i2)
      &            + h3*u(i3)
               hu2 = (u(i4)+u(i5)+u(i6))*sht + h1*u(i4) + h2*u(i5)
      &            + h3*u(i6)
               huinf = (hu1+hu1+hu2) * sur144
               husup = (hu1+hu2+hu2) * sur144
 !
               hv1 = (v(i1)+v(i2)+v(i3))*sht + h1*v(i1) + h2*v(i2)
      &            + h3*v(i3)
               hv2 = (v(i4)+v(i5)+v(i6))*sht + h1*v(i4) + h2*v(i5)
      &            + h3*v(i6)
               hvinf = (hv1+hv1+hv2) * sur144
               hvsup = (hv1+hv2+hv2) * sur144
 !
 !             Y1 = Y(I2) - Y(I3)
 !             Y2 = Y(I3) - Y(I1)
 !             Y3 = Y(I1) - Y(I2)
               y1 = y(ielem,2) - y(ielem,3)
               y2 = y(ielem,3)
               y3 =            - y(ielem,2)
 !
 !             X1 = X(I3) - X(I2)
 !             X2 = X(I1) - X(I3)
 !             X3 = X(I2) - X(I1)
               x1 = x(ielem,3) - x(ielem,2)
               x2 =            - x(ielem,3)
               x3 = x(ielem,2)
 !
               w1(ielem) = y1*huinf + x1*hvinf
               w2(ielem) = y2*huinf + x2*hvinf
               w3(ielem) = y3*huinf + x3*hvinf
               w4(ielem) = y1*husup + x1*hvsup
               w5(ielem) = y2*husup + x2*hvsup
               w6(ielem) = y3*husup + x3*hvsup
 !
             ENDDO
 !
           ELSE
 !
 !       CASE WITH SPECIFIC ADVECTING FIELD
 !
             DO ielem = 1 , nelem
 !
 !             CORRESPONDING 2D ELEMENT ON THE VERTICAL
 !             SEE NUMBERING OF PRISMS
 !
               ielem2 = mod(ielem-1,nelem2) + 1
 !
               i1 = ikle1(ielem)
               i2 = ikle2(ielem)
               i3 = ikle3(ielem)
               i4 = ikle4(ielem)
               i5 = ikle5(ielem)
               i6 = ikle6(ielem)
 !
               h1 = z(i4) - z(i1)
               h2 = z(i5) - z(i2)
               h3 = z(i6) - z(i3)
               sht = h1 + h2 + h3
 !
               u1=u(i1)+f(i1)*h(ielem2,1)
               u2=u(i2)+f(i2)*h(ielem2,1)
               u3=u(i3)+f(i3)*h(ielem2,1)
               u4=u(i4)+f(i4)*h(ielem2,1)
               u5=u(i5)+f(i5)*h(ielem2,1)
               u6=u(i6)+f(i6)*h(ielem2,1)
               v1=v(i1)+f(i1)*h(ielem2,2)
               v2=v(i2)+f(i2)*h(ielem2,2)
               v3=v(i3)+f(i3)*h(ielem2,2)
               v4=v(i4)+f(i4)*h(ielem2,2)
               v5=v(i5)+f(i5)*h(ielem2,2)
               v6=v(i6)+f(i6)*h(ielem2,2)
 !
               hu1 = (u1+u2+u3)*sht + h1*u1 + h2*u2 + h3*u3
               hu2 = (u4+u5+u6)*sht + h1*u4 + h2*u5 + h3*u6
               huinf = (hu1+hu1+hu2) * sur144
               husup = (hu1+hu2+hu2) * sur144
 !
               hv1 = (v1+v2+v3)*sht + h1*v1 + h2*v2 + h3*v3
               hv2 = (v4+v5+v6)*sht + h1*v4 + h2*v5 + h3*v6
               hvinf = (hv1+hv1+hv2) * sur144
               hvsup = (hv1+hv2+hv2) * sur144
 !
 !
 !             Y1 = Y(I2) - Y(I3)
 !             Y2 = Y(I3) - Y(I1)
 !             Y3 = Y(I1) - Y(I2)
               y1 = y(ielem,2) - y(ielem,3)
               y2 = y(ielem,3)
               y3 =            - y(ielem,2)
 !
 !             X1 = X(I3) - X(I2)
 !             X2 = X(I1) - X(I3)
 !             X3 = X(I2) - X(I1)
               x1 = x(ielem,3) - x(ielem,2)
               x2 =            - x(ielem,3)
               x3 = x(ielem,2)
 !
               w1(ielem) = y1*huinf + x1*hvinf
               w2(ielem) = y2*huinf + x2*hvinf
               w3(ielem) = y3*huinf + x3*hvinf
               w4(ielem) = y1*husup + x1*hvsup
               w5(ielem) = y2*husup + x2*hvsup
               w6(ielem) = y3*husup + x3*hvsup
 !
             ENDDO
 !
           ENDIF
 !
 !     ELSEIF(IELMU.EQ.  ) THEN
 !
 !-----------------------------------------------------------------------
 !
         ELSE
 !
 !-----------------------------------------------------------------------
 !
           WRITE(lu,102) ielmu,su%NAME
 102       FORMAT(1x,'VC04PP (BIEF) :',/,
      &        1x,'DISCRETISATION OF U ET V : ',1i6,' NOT IMPLEMENTED',/,
      &        1x,'REAL NAME OF U : ',a6)
           CALL plante(1)
           stop
 !
         ENDIF
 !
 !-----------------------------------------------------------------------
 !
       ELSEIF(formul(14:16).EQ.'TOT') THEN
 !
 !     TERMES HORIZONTAUX
 !
 !     BOUCLE SUR LES ELEMENTS
 !
 !     HERE SIGMAG NOT TAKEN INTO ACCOUNT (IT WOULD BE TO IMPLEMENT IF A
 !     COMPATIBILITY WITH 2D CONTINUITY EQUATION REQUIRED)
 !
         IF(ielmu.EQ.41.AND.
      &     ielmv.EQ.41.AND.
      &     ielmw.EQ.41) THEN
 !
 !-----------------------------------------------------------------------
 !
 !     VITESSE DISCRETISEE EN PRISME P1 :
 !
           DO ielem = 1 , nelem
 !
             i1 = ikle1(ielem)
             i2 = ikle2(ielem)
             i3 = ikle3(ielem)
             i4 = ikle4(ielem)
             i5 = ikle5(ielem)
             i6 = ikle6(ielem)
 !
 !           X2=X(I2)-X(I1)
 !           X3=X(I3)-X(I1)
 !           Y2=Y(I2)-Y(I1)
 !           Y3=Y(I3)-Y(I1)
 !
             x2=x(ielem,2)
             x3=x(ielem,3)
             y2=y(ielem,2)
             y3=y(ielem,3)
 !
             z2=z(i2)-z(i1)
             z3=z(i3)-z(i1)
             z4=z(i4)-z(i1)
             z5=z(i5)-z(i1)
             z6=z(i6)-z(i1)
 !
             u1=u(i1)
             u2=u(i2)
             u3=u(i3)
             u4=u(i4)
             u5=u(i5)
             u6=u(i6)
 !
             v1=v(i1)
             v2=v(i2)
             v3=v(i3)
             v4=v(i4)
             v5=v(i5)
             v6=v(i6)
 !
             q1=w(i1)
             q2=w(i2)
             q3=w(i3)
             q4=w(i4)
             q5=w(i5)
             q6=w(i6)
 !
 !           DERIVATIVE IN Z
 !
             w1(ielem) = (-3*q6-3*q5-3*q2-3*q3-6*q4-6*q1)*(y3*x2-x3*y2)
             w2(ielem) = (-3*q6-6*q5-6*q2-3*q3-3*q4-3*q1)*(y3*x2-x3*y2)
             w3(ielem) = (-6*q6-3*q1-3*q4-6*q3-3*q2-3*q5)*(y3*x2-x3*y2)
             w4(ielem) = - w1(ielem)
             w5(ielem) = - w2(ielem)
             w6(ielem) = - w3(ielem)
 !
 !           DERIVATIVE IN X
 !
             w1(ielem) = w1(ielem) +
      &         (-2*z2*u1+3*z6*u3+z6*u2-4*z2*u2-z6*u5+z5*u4+3*z4*u5+4*z5*
      &u2-2*z2*u5-2*z3*u5+6*z4*u4-3*z6*u4-3*z3*u6-6*z3*u1-3*z3*u4+2*z5*u3
      &+2*z5*u5+6*z4*u1+3*z4*u2+z5*u6-2*z2*u3-4*z3*u2-z2*u4-z2*u6+3*z4*u3
      &+3*z4*u6+2*z5*u1-6*z3*u3)*y2+(6*z2*u1-4*z6*u3-2*z6*u6-2*z6*u2+6*z2
      &*u2-z6*u5+3*z5*u4-3*z4*u5-3*z5*u2+3*z2*u5+z3*u5-6*z4*u4-z6*u4+2*z3
      &*u6+2*z3*u1+z3*u4-z5*u3-6*z4*u1-3*z4*u2+z5*u6+4*z2*u3+2*z3*u2+3*z2
      &*u4+2*z2*u6-3*z4*u3-3*z4*u6+4*z3*u3-2*z6*u1)*y3
             w2(ielem) = w2(ielem) +
      &         (z4*u3-4*z3*u2+2*z4*u2-2*z6*u4+2*z4*u6-2*z3*u3-z6*u3-2*z6
      &*u6-2*z3*u5+2*z4*u4-2*z3*u1+z4*u1-z3*u6-z6*u1-2*z6*u2-4*z6*u5+4*z4
      &*u5-z3*u4)*y2+(z4*u3-z4*u6-2*z3*u2+6*z5*u5+4*z6*u3+2*z6*u2-2*z3*u6
      &+3*z5*u3+3*z5*u4-z3*u4+6*z5*u2+3*z4*u1+z6*u4-z3*u5+2*z6*u6-4*z3*u3
      &+2*z6*u1+3*z5*u1+3*z5*u6+z6*u5-2*z3*u1-3*z4*u5)*y3
             w3(ielem) = w3(ielem) +
      &         (-6*z6*u6-2*z5*u1-3*z6*u1-z5*u6+2*z2*u5+4*z2*u2+z2*u4-2*z
      &5*u5+2*z2*u1-2*z5*u3-3*z6*u2+3*z4*u6+z2*u6-6*z6*u3-4*z5*u2+2*z2*u3
      &-z5*u4+z4*u5-z4*u2-3*z4*u1-3*z6*u5-3*z6*u4)*y2+(-2*z4*u3-z4*u2-4*z
      &4*u6+2*z2*u2+2*z5*u3+4*z2*u3-2*z4*u4+2*z5*u4+2*z2*u6+z5*u1+2*z2*u1
      &-z4*u1+z5*u2+z2*u4+z2*u5+2*z5*u5+4*z5*u6-2*z4*u5)*y3
             w4(ielem) = w4(ielem) +
      &         (z3*u2-2*z2*u6+4*z5*u5-2*z2*u2+6*z6*u6+3*z6*u1+2*z6*u2-z3
      &*u5+2*z5*u6-2*z2*u4+2*z5*u2-3*z3*u6-z2*u3+3*z6*u3-z2*u1+2*z5*u4+6*
      &z6*u4+3*z3*u1+z5*u3+4*z6*u5-4*z2*u5+z5*u1)*y2+(z3*u2-4*z5*u6-2*z6*
      &u3-2*z5*u3-6*z5*u5-6*z5*u4-z6*u1+4*z3*u6-z2*u3+2*z3*u3-2*z6*u4+2*z
      &3*u4-4*z6*u6+2*z3*u5+3*z2*u5-2*z6*u5+z2*u6-3*z5*u2-z6*u2-3*z2*u1+z
      &3*u1-3*z5*u1)*y3
             w5(ielem) = w5(ielem) +
      &         (2*z6*u6+z6*u1-z4*u1-2*z4*u6-2*z4*u4+z3*u4+2*z3*u3+2*z3*u
      &5+4*z3*u2+z3*u6-2*z4*u2+z6*u3+2*z6*u4-4*z4*u5+2*z6*u2+2*z3*u1+4*z6
      &*u5-z4*u3)*y2+(2*z4*u3-z3*u1-z3*u2-6*z2*u2+2*z6*u3+4*z4*u6+z6*u1+3
      &*z4*u2+6*z4*u4-4*z3*u6-3*z2*u3+3*z4*u1+2*z6*u4-2*z3*u4+6*z4*u5-2*z
      &3*u3+z6*u2-3*z2*u4-6*z2*u5+2*z6*u5-2*z3*u5+4*z6*u6-3*z2*u6-3*z2*u1
      &)*y3
             w6(ielem) = w6(ielem) +
      &         (3*z3*u5+2*z2*u4-2*z5*u2+3*z3*u2-z5*u1-2*z5*u6+z2*u1-2*z4
      &*u2+2*z2*u2+4*z2*u5-z5*u3-6*z4*u6+2*z2*u6+3*z3*u4+6*z3*u3+6*z3*u6+
      &z2*u3-6*z4*u4+3*z3*u1-2*z5*u4-4*z4*u5-3*z4*u1-4*z5*u5-3*z4*u3)*y2+
      &(2*z4*u3-z5*u1+4*z4*u6-2*z2*u2-2*z5*u3+z4*u2+z4*u1-2*z5*u4-4*z2*u3
      &-z5*u2-4*z5*u6-2*z5*u5-2*z2*u6-2*z2*u1-z2*u5-z2*u4+2*z4*u5+2*z4*u4
      &)*y3
 !
 !            DERIVATIVE IN Y
 !
             w1(ielem) = w1(ielem) +
      &         (-4*z5*v2-3*z4*v5-z5*v6+z6*v5+2*z3*v5+4*z2*v2+3*z3*v6+z2*
      &v4+4*z3*v2-2*z5*v3-z6*v2+z2*v6+6*z3*v1-6*z4*v1-2*z5*v5+6*z3*v3+2*z
      &2*v3-3*z4*v3-2*z5*v1+3*z3*v4-6*z4*v4-3*z4*v6+3*z6*v4-3*z6*v3-z5*v4
      &+2*z2*v1+2*z2*v5-3*z4*v2)*x2+(3*z5*v2+3*z4*v5-z5*v6+z6*v5-z3*v5-6*
      &z2*v2-2*z3*v6-3*z2*v4-2*z3*v2+z5*v3+2*z6*v2-2*z2*v6-2*z3*v1+6*z4*v
      &1-4*z3*v3-4*z2*v3+3*z4*v3+2*z6*v6-z3*v4+6*z4*v4+3*z4*v6+z6*v4+4*z6
      &*v3-3*z5*v4-6*z2*v1+2*z6*v1-3*z2*v5+3*z4*v2)*x3
             w2(ielem) = w2(ielem) +
      &         (-2*z4*v6+2*z6*v6+z6*v3+2*z6*v4-z4*v3-z4*v1+2*z3*v1+z3*v4
      &-4*z4*v5+4*z6*v5+2*z6*v2+2*z3*v3+z3*v6+4*z3*v2-2*z4*v4+2*z3*v5-2*z
      &4*v2+z6*v1)*x2+(-3*z5*v1-6*z5*v2+2*z3*v1-3*z5*v4+2*z3*v6+4*z3*v3+z
      &3*v4+z3*v5-6*z5*v5-3*z4*v1+3*z4*v5-2*z6*v2-z6*v5-z4*v3-2*z6*v1-4*z
      &6*v3-3*z5*v6-z6*v4+z4*v6+2*z3*v2-3*z5*v3-2*z6*v6)*x3
             w3(ielem) = w3(ielem) +
      &         (-2*z2*v5+z5*v4+6*z6*v3+6*z6*v6+3*z6*v5-2*z2*v1+3*z6*v4+2
      &*z5*v5+z5*v6+3*z4*v1-2*z2*v3-z4*v5+3*z6*v1-z2*v6-3*z4*v6+2*z5*v3-4
      &*z2*v2-z2*v4+3*z6*v2+4*z5*v2+z4*v2+2*z5*v1)*x2+(-4*z5*v6-2*z2*v2-2
      &*z2*v1-z2*v4-z5*v1+z4*v1+z4*v2+2*z4*v4-2*z5*v5+4*z4*v6-z2*v5-2*z2*
      &v6+2*z4*v5-2*z5*v4-4*z2*v3-z5*v2+2*z4*v3-2*z5*v3)*x3
             w4(ielem) = w4(ielem) +
      &         (-2*z5*v4-6*z6*v6-2*z5*v6+4*z2*v5-4*z5*v5-4*z6*v5+2*z2*v2
      &+z2*v3-6*z6*v4+2*z2*v6+3*z3*v6-z5*v1-2*z6*v2-z5*v3-3*z6*v3+z2*v1+2
      &*z2*v4-3*z6*v1-z3*v2-2*z5*v2-3*z3*v1+z3*v5)*x2+(3*z5*v1+2*z6*v5+3*
      &z2*v1-z3*v2-z3*v1+2*z6*v4-4*z3*v6-2*z3*v3+z6*v2-2*z3*v4+2*z6*v3+6*
      &z5*v5+z2*v3-z2*v6+2*z5*v3+z6*v1+4*z5*v6+6*z5*v4-2*z3*v5+3*z5*v2+4*
      &z6*v6-3*z2*v5)*x3
             w5(ielem) = w5(ielem) +
      &         (z4*v3-z6*v1-2*z6*v6+4*z4*v5-2*z3*v3-z6*v3+2*z4*v4-z3*v4+
      &2*z4*v6-2*z6*v4-4*z6*v5-2*z3*v1-z3*v6-4*z3*v2-2*z6*v2-2*z3*v5+2*z4
      &*v2+z4*v1)*x2+(-2*z6*v5+3*z2*v1-4*z4*v6+z3*v1-2*z4*v3+4*z3*v6+2*z3
      &*v3+2*z3*v4-6*z4*v5-3*z4*v1-3*z4*v2-6*z4*v4+3*z2*v4-2*z6*v3+6*z2*v
      &2+3*z2*v3-4*z6*v6+3*z2*v6-z6*v1-z6*v2+6*z2*v5-2*z6*v4+2*z3*v5+z3*v
      &2)*x3
             w6(ielem) = w6(ielem) +
      &         (6*z4*v6-2*z2*v2+2*z5*v4-4*z2*v5-6*z3*v3+2*z5*v6-z2*v1+6*
      &z4*v4+3*z4*v1+3*z4*v3+z5*v1-3*z3*v1-3*z3*v4-2*z2*v6-6*z3*v6+z5*v3-
      &z2*v3-2*z2*v4+4*z5*v5-3*z3*v2+2*z5*v2-3*z3*v5+2*z4*v2+4*z4*v5)*x2+
      &(2*z5*v4+2*z2*v1+z5*v1-z4*v2-2*z4*v4+2*z5*v5-z4*v1+4*z5*v6+2*z2*v2
      &-2*z4*v5+2*z5*v3+z5*v2+4*z2*v3+z2*v5+z2*v4+2*z2*v6-4*z4*v6-2*z4*v3
      &)*x3
 !
             w1(ielem) = w1(ielem)*sur144
             w2(ielem) = w2(ielem)*sur144
             w3(ielem) = w3(ielem)*sur144
             w4(ielem) = w4(ielem)*sur144
             w5(ielem) = w5(ielem)*sur144
             w6(ielem) = w6(ielem)*sur144
 !
           ENDDO
 !
 !-----------------------------------------------------------------------
 !
 !     ELSEIF(IELMU.EQ.  ) THEN
 !
 !-----------------------------------------------------------------------
 !
         ELSE
 !
 !-----------------------------------------------------------------------
 !
           WRITE(lu,302) ielmu,su%NAME
 302       FORMAT(1x,'VC04PP (BIEF) :',/,
      &         1x,'DISCRETISATION OF U,V,W : ',1i6,' NOT IMPLEMENTED',/,
      &         1x,'REAL NAME OF U : ',a6)
           CALL plante(1)
           stop
 !
         ENDIF
 !
 !-----------------------------------------------------------------------
 !
       ELSE
 !
 !-----------------------------------------------------------------------
 !
         WRITE(lu,202) formul
 202     FORMAT(1x,'VC04PP (BIEF) :',/,
      &         1x,'HOR OR TOT LACKING AT THE END OF THE FORMULA : ',a16)
         CALL plante(1)
         stop
 !
 !-----------------------------------------------------------------------
 !
       ENDIF
 !
 !-----------------------------------------------------------------------
 !
       RETURN
       END
declarations_special
Definition: declarations_special.F:3

declarations_special::lu
integer lu
Definition: declarations_special.F:45

vc04pp
subroutine vc04pp(XMUL, SU, SV, SW, U, V, W, F, H, X, Y, Z, IKLE1, IKLE2, IKLE3, IKLE4, IKLE5, IKLE6, NELEM, NELMAX, W1, W2, W3, W4, W5, W6, SPECAD, FORMUL, NELEM2)
Definition: vc04pp.f:9

bief
Definition: bief.f:3