vc01oo.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE vc01oo
!                   *****************
!
     &(xmul,sf,f,lgseg,ikle1,ikle2,nbor,nelem,nelmax,w1,w2)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE FOLLOWING VECTOR IN FINITE ELEMENTS:
!code
!+                    /
!+    VEC(I) = XMUL  /    PSI(I) * F  D(OMEGA)
!+                  /OMEGA
!+
!+    PSI(I) IS A BASE OF TYPE P1 SEGMENT
!+
!+    F IS A VECTOR OF TYPE IELMF
!
!warning  THE JACOBIAN MUST BE POSITIVE
!warning  THE RESULT IS IN W IN NOT ASSEMBLED FORM
!
!history  J-M HERVOUET (LNH)    ; F LEPEINTRE (LNH)
!+        20/03/08
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| F              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| IKLE1          |-->| FIRST POINT OF SEGMENTS
!| IKLE2          |-->| SECOND POINT OF SEGMENTS
!| LGSEG          |-->| LENGTH OF SEGMENTS
!| NBOR           |-->| GLOBAL NUMBER OF BOUNDARY POINTS
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SF             |-->| BIEF_OBJ STRUCTURE OF F
!| W1             |<--| RESULT IN NON ASSEMBLED FORM
!| W2             |<--| RESULT IN NON ASSEMBLED FORM
!| XMUL           |-->| MULTIPLICATION COEFFICIENT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_vc01oo => vc01oo
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX
      INTEGER, INTENT(IN) :: IKLE1(nelmax),IKLE2(nelmax)
      INTEGER, INTENT(IN) :: NBOR(*)
!
      DOUBLE PRECISION, INTENT(INOUT) :: W1(nelmax),W2(nelmax)
      DOUBLE PRECISION, INTENT(IN)    :: LGSEG(*)
      DOUBLE PRECISION, INTENT(IN)    :: XMUL
!
!     STRUCTURE OF F AND REAL DATA
!
      TYPE(bief_obj), INTENT(IN) :: SF
      DOUBLE PRECISION, INTENT(IN) :: F(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IELMF
      DOUBLE PRECISION XSUR3,XSUR6,F1,F2,V1,V2
!
!-----------------------------------------------------------------------
!
      ielmf=sf%ELM
!
!-----------------------------------------------------------------------
!
!     F IS CONSTANT BY SEGMENTS
!
      IF(ielmf.EQ.0) THEN
!
      DO ielem = 1,nelem
        w1(ielem) = 0.5d0*xmul*f(ielem)*lgseg(ielem)
        w2(ielem) = w1(ielem)
      ENDDO
!
!-----------------------------------------------------------------------
!
!     F IS LINEAR BY SEGMENTS
!
      ELSEIF(ielmf.EQ.1) THEN
!
      xsur3 = xmul/3.d0
      xsur6 = xmul/6.d0
!
      DO ielem = 1,nelem
        f1 = f(ikle1(ielem))
        f2 = f(ikle2(ielem))
        v1 = ( f1*xsur3 + f2*xsur6 )
        v2 = ( f2*xsur3 + f1*xsur6 )
        w1(ielem) = v1 * lgseg(ielem)
        w2(ielem) = v2 * lgseg(ielem)
      ENDDO
!
!-----------------------------------------------------------------------
!
!     F IS LINEAR BY TRIANGLES OR QUADRILATERALS OR QUASI-BUBBLE
!
      ELSEIF(ielmf.EQ.11.OR.ielmf.EQ.12.OR.ielmf.EQ.21) THEN
!
      xsur3 = xmul/3.d0
      xsur6 = xmul/6.d0
!
      DO ielem = 1,nelem
        f1 = f(nbor(ikle1(ielem)))
        f2 = f(nbor(ikle2(ielem)))
        v1 = ( f1*xsur3 + f2*xsur6 )
        v2 = ( f2*xsur3 + f1*xsur6 )
        w1(ielem) = v1 * lgseg(ielem)
        w2(ielem) = v2 * lgseg(ielem)
      ENDDO
!
!-----------------------------------------------------------------------
!
      ELSE
!
!-----------------------------------------------------------------------
!
        WRITE(lu,101) ielmf,sf%NAME
101     FORMAT(1x,'VC01OO (BIEF) :',/,
     &         1x,'DISCRETIZATION OF F NOT AVAILABLE:',1i6,
     &         1x,'REAL NAME: ',a6)
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END