vc01bb.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE vc01bb
!                   *****************
!
     &(xmul,sf,f,surfac,ikle1,ikle2,ikle3,ikle4,nelem,nelmax,
     & w1,w2,w3,w4)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE FOLLOWING VECTOR IN FINITE ELEMENTS:
!code
!+                    /
!+    VEC(I) = XMUL  /    PSI(I) * F  D(OMEGA)
!+                  /OMEGA
!+
!+    PSI(I) IS A BASE OF QUASI-BUBBLE TYPE
!
!warning  THE JACOBIAN MUST BE POSITIVE
!warning  THE RESULT IS IN W IN NOT ASSEMBLED FORM
!
!history  J-M HERVOUET (LNH)    ; C MOULIN (LNH)
!+        10/01/95
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| F              |-->| FUNCTION USED IN THE VECTOR FORMULA
!| IKLE1          |-->| FIRST POINT OF TRIANGLES
!| IKLE2          |-->| SECOND POINT OF TRIANGLES
!| IKLE3          |-->| THIRD POINT OF TRIANGLES
!| IKLE4          |-->| QUASI-BUBBLE POINT OF TRIANGLES
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SF             |-->| BIEF_OBJ STRUCTURE OF F
!| SURFAC         |-->| AREA OF TRIANGLES
!| W1             |<--| RESULT IN NON ASSEMBLED FORM
!| W2             |<--| RESULT IN NON ASSEMBLED FORM
!| W3             |<--| RESULT IN NON ASSEMBLED FORM
!| W4             |<--| RESULT IN NON ASSEMBLED FORM
!| XMUL           |-->| MULTIPLICATION COEFFICIENT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_vc01bb => vc01bb
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX
      INTEGER, INTENT(IN) :: IKLE1(nelmax),IKLE2(nelmax)
      INTEGER, INTENT(IN) :: IKLE3(nelmax),IKLE4(nelmax)
!
      DOUBLE PRECISION, INTENT(INOUT) :: W1(nelmax),W2(nelmax)
      DOUBLE PRECISION, INTENT(INOUT) :: W3(nelmax),W4(nelmax)
      DOUBLE PRECISION, INTENT(IN)    :: SURFAC(nelmax)
      DOUBLE PRECISION, INTENT(IN)    :: XMUL
!
!     STRUCTURE OF F AND REAL DATA
!
      TYPE(bief_obj),   INTENT(IN) :: SF
      DOUBLE PRECISION, INTENT(IN) :: F(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM,IELMF
      DOUBLE PRECISION F1,F2,F3,F4,XSU108,XSUR09,XSUR36,XSUR18
!
!-----------------------------------------------------------------------
!
      ielmf=sf%ELM
!
!-----------------------------------------------------------------------
!     F OF TYPE P1
!-----------------------------------------------------------------------
!
      IF(ielmf.EQ.11) THEN
!
      xsu108 = xmul / 108.d0
      xsur09 = xmul / 9.d0
!
      DO ielem = 1 , nelem
!
        f1  = f(ikle1(ielem))
        f2  = f(ikle2(ielem))
        f3  = f(ikle3(ielem))
!
        w1(ielem) = surfac(ielem)*(5*f3+5*f2+14*f1)*xsu108
!
        w2(ielem) = surfac(ielem)*(5*f3+14*f2+5*f1)*xsu108
!
        w3(ielem) = surfac(ielem)*(14*f3+5*f2+5*f1)*xsu108
!
        w4(ielem) = surfac(ielem)*(f3+f2+f1)*xsur09
!
      ENDDO ! IELEM
!
!-----------------------------------------------------------------------
!     F QUASI-BUBBLE
!-----------------------------------------------------------------------
!
      ELSEIF(ielmf.EQ.12) THEN
!
      xsur36 = xmul / 36.d0
      xsur18 = xmul / 18.d0
!
      DO ielem = 1 , nelem
!
        f1  = f(ikle1(ielem))
        f2  = f(ikle2(ielem))
        f3  = f(ikle3(ielem))
        f4  = f(ikle4(ielem))
!
        w1(ielem) = surfac(ielem)*(2*f4+  f3+  f2+4*f1)*xsur36
        w2(ielem) = surfac(ielem)*(2*f4+  f3+4*f2+  f1)*xsur36
        w3(ielem) = surfac(ielem)*(2*f4+4*f3+  f2+  f1)*xsur36
        w4(ielem) = surfac(ielem)*(3*f4+  f3+  f2+  f1)*xsur18
!
      ENDDO ! IELEM
!
!-----------------------------------------------------------------------
!      OTHER
!      ELSEIF
!-----------------------------------------------------------------------
!
      ELSE
!
        WRITE(lu,101) ielmf,sf%NAME
101     FORMAT(1x,'VC01BB (BIEF) :',/,
     &         1x,'DISCRETIZATION OF F NOT AVAILABLE:',1i6,
     &         1x,'REAL NAME: ',a6)
        CALL plante(0)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END