vc00pp.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE vc00pp
!                   *****************
!
     &(xmul,z,surfac,ikle1,ikle2,ikle3,ikle4,ikle5,ikle6,nelem,nelmax,
     & w1,w2,w3,w4,w5,w6,formul)
!
!***********************************************************************
! BIEF   V6P2                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE FOLLOWING VECTOR IN FINITE ELEMENTS:
!code
!+                    /
!+    VEC(I) = XMUL  /    PSI(I)  D(OMEGA)
!+                  /OMEGA
!+
!+    PSI(I) IS A BASE OF TYPE P1 PRISM
!
!warning  THE JACOBIAN MUST BE POSITIVE
!warning  THE RESULT IS IN W IN NOT ASSEMBLED FORM
!
!history  J-M HERVOUET (LNH)    ; F LEPEINTRE (LNH)
!+        09/12/94
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FORMUL         |-->| STRING WITH THE FORMULA DESCRIBING THE VECTOR
!| IKLE1          |-->| FIRST POINT OF PRISMS
!| IKLE2          |-->| SECOND POINT OF PRISMS
!| IKLE3          |-->| THIRD POINT OF PRISMS
!| IKLE4          |-->| FOURTH POINT OF PRISMS
!| IKLE5          |-->| FIFTH POINT OF PRISMS
!| IKLE6          |-->| SIXTH POINT OF PRISMS
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| SURFAC         |-->| AREA OF TRIANGLES
!| W1             |<--| RESULT IN NON ASSEMBLED FORM
!| W2             |<--| RESULT IN NON ASSEMBLED FORM
!| W3             |<--| RESULT IN NON ASSEMBLED FORM
!| W4             |<--| RESULT IN NON ASSEMBLED FORM
!| W5             |<--| RESULT IN NON ASSEMBLED FORM
!| W6             |<--| RESULT IN NON ASSEMBLED FORM
!| XMUL           |-->| MULTIPLICATION COEFFICIENT
!| Z              |-->| ELEVATIONS OF POINTS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX
      INTEGER, INTENT(IN) :: IKLE1(nelmax),IKLE2(nelmax),IKLE3(nelmax)
      INTEGER, INTENT(IN) :: IKLE4(nelmax),IKLE5(nelmax),IKLE6(nelmax)
!
      DOUBLE PRECISION, INTENT(IN)    :: Z(*)
      DOUBLE PRECISION, INTENT(IN)    :: SURFAC(nelmax)
      DOUBLE PRECISION, INTENT(INOUT) :: W1(nelmax)
      DOUBLE PRECISION, INTENT(INOUT) :: W2(nelmax)
      DOUBLE PRECISION, INTENT(INOUT) :: W3(nelmax)
      DOUBLE PRECISION, INTENT(INOUT) :: W4(nelmax)
      DOUBLE PRECISION, INTENT(INOUT) :: W5(nelmax)
      DOUBLE PRECISION, INTENT(INOUT) :: W6(nelmax)
      DOUBLE PRECISION, INTENT(IN)    :: XMUL
!
      CHARACTER(LEN=16), INTENT(IN) :: FORMUL
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM
!
      DOUBLE PRECISION XSUR24,XSUR6,H1,H2,H3,SHT,COEF
!
!-----------------------------------------------------------------------
!
      xsur24 = xmul/24.d0
      xsur6  = xmul/6.d0
!
!-----------------------------------------------------------------------
!
      IF(formul(1:7).EQ.'MASBAS ') THEN
!
!     STANDARD FORMULA
!
!     LOOP ON THE ELEMENTS
!
      DO ielem = 1 , nelem
!
        h1 = z(ikle4(ielem)) - z(ikle1(ielem))
        h2 = z(ikle5(ielem)) - z(ikle2(ielem))
        h3 = z(ikle6(ielem)) - z(ikle3(ielem))
        sht = h1 + h2 + h3
!
        coef = xsur24 * surfac(ielem)
!
        w1(ielem) = coef * (sht+h1)
        w2(ielem) = coef * (sht+h2)
        w3(ielem) = coef * (sht+h3)
        w4(ielem) = w1(ielem)
        w5(ielem) = w2(ielem)
        w6(ielem) = w3(ielem)
!
      ENDDO
!
!-----------------------------------------------------------------------
!
      ELSEIF(formul(1:7).EQ.'MASBAS2') THEN
!
!     FORMULA WITH MASS-LUMPING
!
!     LOOP ON THE ELEMENTS
!
      DO ielem = 1 , nelem
!
        h1 = z(ikle4(ielem)) - z(ikle1(ielem))
        h2 = z(ikle5(ielem)) - z(ikle2(ielem))
        h3 = z(ikle6(ielem)) - z(ikle3(ielem))
!
        coef = xsur6 * surfac(ielem)
!
        w1(ielem) = coef * h1
        w2(ielem) = coef * h2
        w3(ielem) = coef * h3
        w4(ielem) = w1(ielem)
        w5(ielem) = w2(ielem)
        w6(ielem) = w3(ielem)
!
      ENDDO
!
!-----------------------------------------------------------------------
!
      ELSE
!
        WRITE(lu,*) ' '
        WRITE(lu,*) 'UNKNOWN FORMULA IN VC00PP:',formul
        CALL plante(1)
        stop
!
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END