uvstokes.f

Go to the documentation of this file.

!#######################################################################
                        SUBROUTINE uvstokes
     &  (ust, vst, wst, fs, npoin2, xk, zfj, ndire, ztel, nz, nf)
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!  calculation of the three components of the stokes drift
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FS             |-->| VARIANCE DENSITY DIRECTIONAL SPECTRUM
!| NF             |-->| NUMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| NZ             |-->| NUMBER OF PLAN IN TELEMAC3D
!| XK             |-->| DISCRETIZED WAVE NUMBER
!| UST            |<--| STOKES COMPONENT ALONG X
!| VST            |<--| STOKES COMPONENT ALONG Y
!| WST            |<--| STOKES COMPONENT ALONG Z
!| ZFJ            |-->| BOTTOM ELEVATION
!| ZTEL           |-->| ELEVATION IN TELEMAC3D
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      USE bief
      USE declarations_tomawac, ONLY : freq,costet,dfreq,dzx,dzy,sintet,
     &                                 depth, deupi
      USE interface_tomawac, ex_uvstokes => uvstokes
      
!NDIRE - number of direction discretization      
      IMPLICIT NONE
      
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""
      INTEGER, INTENT(IN)  :: NZ,NF
      INTEGER, INTENT(IN) :: NPOIN2, NDIRE
      DOUBLE PRECISION, INTENT(IN) :: FS(npoin2,ndire,nf)
      DOUBLE PRECISION, INTENT(IN) :: ZFJ(npoin2)
      DOUBLE PRECISION, INTENT(IN) :: XK(npoin2,nf)
      DOUBLE PRECISION, INTENT(INOUT) :: UST(npoin2,nz)
      DOUBLE PRECISION, INTENT(INOUT) :: VST(npoin2,nz)
      DOUBLE PRECISION, INTENT(INOUT) :: WST(npoin2)
      DOUBLE PRECISION, INTENT(IN) :: ZTEL(npoin2,nz)
!.....LOCAL VARIABLES
!     """""""""""""""""
      INTEGER  JP    , JF    , IP, INZ
      DOUBLE PRECISION SIGMA, DTETAR, AUX1
!
      dtetar=deupi/dble(ndire)

!begin mjt- initialize variables      
      DO ip=1,npoin2
        DO inz=1,nz
          ust(ip,inz) = 0.d0
          vst(ip,inz) = 0.d0
        ENDDO      
      ENDDO
      DO jp=1,ndire
        DO jf=1,nf
          sigma=deupi*freq(jf)
          aux1=dfreq(jf)*dtetar
          DO ip=1,npoin2
            DO inz=1, nz
              ust(ip,inz)=ust(ip,inz)+(sigma*xk(ip,jf)*sintet(jp)
     & *fs(ip,jp,jf)*(cosh(2.d0*xk(ip,jf)*ztel(ip,inz)
     & +2.d0*xk(ip,jf)*(-zfj(ip)))
     & /sinh(xk(ip,jf)*depth(ip))**2.d0))*aux1

              vst(ip,inz)=vst(ip,inz)+(sigma*xk(ip,jf)
     & *costet(jp)*fs(ip,jp,jf)*(cosh(2.d0*xk(ip,jf)*ztel(ip,inz)
     & +2.d0*xk(ip,jf)*(-zfj(ip))) 
     & /sinh(xk(ip,jf)*depth(ip))**2.d0))*aux1
            ENDDO
          ENDDO
        ENDDO
      ENDDO
      DO ip=1,npoin2
        wst(ip)=-ust(ip,1)*dzx(ip)-vst(ip,1)*dzy(ip)
      ENDDO
      
      RETURN
      END