ustar2.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE ustar2
!                   *****************
!
     &( ustar, npoin2)
!
!***********************************************************************
! TOMAWAC   V6P1                                   29/06/2011
!***********************************************************************
!
!brief    COMPUTES THE FRICTION VELOCITY U*
!+                FOR ALL THE NODES IN THE 2D MESH.
!+
!+            USES A DRAG COEFFICIENT WHICH VARIES LINEARLY WITH
!+                WIND SPEED. THE FORMULATION IS IDENTICAL TO THAT
!+                USED IN WAM-CYCLE 3 (WAMDI GROUP, 1988).
!
!reference  WAMDI GROUP (1988) :
!+                     "A THIRD GENERATION OCEAN WAVE PREDICTION MODEL".
!+                      JPO, VOL 18, PP 1775-1810.
!
!history  M. BENOIT (EDF/DER/LNH)
!+        26/03/96
!+        V1P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        29/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| USTAR          |<--| FRICTION VELOCITY
!| UV             |-->| WIND VELOCITY ALONG X AT THE MESH POINTS
!| VV             |-->| WIND VELOCITY ALONG Y AT THE MESH POINTS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_tomawac, ONLY : uv, vv
      USE interface_tomawac, ex_ustar2 => ustar2
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""
      INTEGER, INTENT(IN)    ::  NPOIN2
      DOUBLE PRECISION, INTENT(INOUT) :: USTAR(npoin2)
!
!.....LOCAL VARIABLES
!     """""""""""""""""
      INTEGER  IP
      DOUBLE PRECISION UVENT , CDRAG
!
!
!.....MAIN LOOP ON THE NODES OF THE 2D MESH
!     """""""""""""""""""""""""""""""""""""""""""""""""""""
      DO ip=1,npoin2
!
!.......COMPUTES THE WIND SPEED 10 METERS ABOVE WATER
!       """""""""""""""""""""""""""""""""""""""""
        uvent=sqrt(uv(ip)**2+vv(ip)**2)
!
!.......COMPUTES THE DRAG COEFFICIENT
!       """""""""""""""""""""""""""""""""
        cdrag = 6.5d-5*uvent + 8.d-4
        IF (uvent.LT.7.5d0) cdrag = 1.2875d-3
!
!.......COMPUTES THE FRICTION VELOCITY
!       """""""""""""""""""""""""""""""""""
        ustar(ip)=sqrt(cdrag)*uvent
!
      ENDDO ! IP
!
      RETURN
      END