ustar1.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE ustar1
!                   *****************
!
     &( ustar , z0    , tauwav,  npoin2)
!
!***********************************************************************
! TOMAWAC   V6P1                                   29/06/2011
!***********************************************************************
!
!brief    COMPUTES THE FRICTION VELOCITY AND ROUGHNESS LENGTH
!+                FOR ALL THE NODES IN THE 2D MESH.
!+                BASED ON JANSSEN (1989, 1991).
!
!note     COMPUTES TAUT FROM UVENT AND TAUW IN SUBROUTINE 'TAUTOT'.
!
!reference  JANSSEN P.A.E.M (1989) :
!+                     "WIND-INDUCED STRESS AND THE DRAG OF AIR
!+                      FLOW OVER SEA WAVES". JPO, VOL 19, PP 745-754.
!reference JANSSEN P.A.E.M (1991) :
!+                     "QUASI-LINEAR THEORY OF WIND-WAVE GENERATION
!+                      APPLIED TO WAVE FORECASTING". JPO, VOL 21, PP 1631-1642.
!
!history  M. BENOIT (EDF/DER/LNH)
!+        25/04/95
!+        V1P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        29/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| TAUWAV         |-->| STRESS DUE TO WAVES
!| USTAR          |<--| FRICTION VELOCITY
!| Z0             |<--| SURFACE ROUGHNESS LENGTH
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_tomawac, ex_ustar1 => ustar1
      USE declarations_tomawac, ONLY : gravit, alpha, uv, vv
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""
      INTEGER, INTENT(IN)    ::  NPOIN2
      DOUBLE PRECISION, INTENT(IN)    :: TAUWAV(npoin2)
      DOUBLE PRECISION, INTENT(INOUT) :: USTAR(npoin2), Z0(npoin2)
!
!.....LOCAL VARIABLES
!     """""""""""""""""
      INTEGER  ITRMIN, ITRMAX, ITR   , IP
      DOUBLE PRECISION TAUT  , UVENT , TAUW  , USMIN , SEUIL , X
      DOUBLE PRECISION USTEMP
!
!
      usmin =1.d-6
      seuil =1.d-7
      itrmin=1
      itrmax=15
!
!.....MAIN LOOP ON THE NODES OF THE 2D MESH
!     """""""""""""""""""""""""""""""""""""""""""""""""""""
      DO ip=1,npoin2
!
!.......COMPUTES THE TOTAL STRESS
!     """""""""""""""""""""""""""""""
        uvent=sqrt(uv(ip)**2+vv(ip)**2)
        tauw =tauwav(ip)
        CALL tautot
     &( taut  , uvent , tauw  , seuil ,
     &  itr   , itrmin, itrmax)
!
!.......COMPUTES THE FRICTION VELOCITY
!       """""""""""""""""""""""""""""""""""
        ustar(ip)=sqrt(taut)
!
!.......COMPUTES TEH ROUGHNESS LENGTH
!       """"""""""""""""""""""""""""""""""
        ustemp=max(ustar(ip),usmin)
        x     =min(tauwav(ip)/ustemp**2,0.999d0)
        z0(ip)=alpha*ustemp**2/(gravit*sqrt(1.d0-x))
!
      ENDDO
!
      RETURN
      END