tvf_2.f

Go to the documentation of this file.

!                   ****************
                    SUBROUTINE tvf_2
!                   ****************
!
     &(f,fstar,fc,volu2d,unsv2d,dt,fxbor,fxborpar,fbor,smh,yasmh,fscexp,
     & npoin,nptfr,nbor,limtra,kdir,kddl,optsou,hlin,
     & iopt2,flbortra,surnit,rain,pluie,train,phi_i,tetafcor,
     & mass_bal,massou)
!
!***********************************************************************
! BIEF   V7P1
!***********************************************************************
!
!brief    As TVF, computes the new value of tracer in a sub-iteration,
!+        but here based on contributions per point, not on fluxes.
!
!history  S. PAVAN & J-M HERVOUET (EDF LAB, LNHE)
!+        22/04/2014
!+        V7P0
!+   First version, derived from TVF.
!
!history  S. PAVAN & J-M HERVOUET (EDF LAB, LNHE)
!+        28/05/2015
!+        V7P0
!+   Second version, with 3 new arguments after PHI_I.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| MASS_BAL       |-->| IF YES, FLBORTRA WILL BE UPDATED FOR THE
!|                |   | MASS BALANCE.
!| DT             |-->| TIME-STEP
!| F              |<--| VALUES OF F AT TIME N+1 OF SUB-ITERATION
!| FBOR           |-->| VALUES OF F AT THE PRESCRIBED BOUNDARIES
!| FC             |-->| VALUES OF F AT TIME N OF SUB-ITERATION
!| FLBORTRA       |<->| FLUX OF TRACER AT THE BOUNDARIES
!| FSTAR          |-->| VALUE OF THE PREDICTOR
!| FSCEXP         |-->| EXPLICIT SOURCE TERM FOR F
!| FXBOR          |-->| FLUXES ON BOUNDARIES
!| FXBORPAR       |-->| FLUXES ON BOUNDARIES (DEFINED ON ALL DOMAIN
!|                |   | AND ASSEMBLED IN PARALLEL)
!| HLIN           |-->| WATER DEPTH AT TIME N+1
!|                |   | (WITH LINEAR INTERPOLATION IN TIME BETWEEN
!|                |   | HN AND H)
!| IOPT2          |-->| 0: CONSERVATIVE ADVECTION FIELD
!|                |   | 1: NON CONSERVATIVE ADVECTION FIELD
!| KDDL           |-->| CONVENTION FOR DEGREE OF FREEDOM
!| KDIR           |-->| CONVENTION FOR DIRICHLET POINT
!| LIMTRA         |-->| TECHNICAL BOUNDARY CONDITIONS FOR TRACERS
!| MASS_BAL       |-->| IF YES, ALL TERMS FOR MASS BALANCE
!|                |   | WILL BE COMPUTED
!| MASSOU         |<->| ADDED MASS BY SOURCE TERMS
!| NBOR           |-->| GLOBAL NUMBER OF BOUNDARY POINTS
!| NPOIN          |-->| NUMBER OF POINTS
!| NPTFR          |-->| NUMBER OF BOUNDARY POINTS
!| OPTSOU         |-->| TYPE OF SOURCES
!|                |   | 1: NORMAL
!|                |   | 2: DIRAC
!| PHI_I          |-->| CONTRIBUTIONS PER POINT
!| PLUIE          |-->| RAIN OR EVAPORATION, IN M/S
!| RAIN           |-->| IF YES: RAIN OR EVAPORATION
!| SMH            |-->| SOURCE TERM IN CONTINUITY EQUATION
!| SURNIT         |-->| SURNIT=1/NIT
!| TETAFCOR       |-->| SEMI_IMPLICITATION COEFFICIENT
!|                |   | (CASE OF PREDICTOR CORRECTOR)
!| TRAIN          |-->| VALUE OF TRACER IN RAIN
!| UNSV2D         |-->| INVERSE OF INTEGRALS OF TEST FUNCTIONS
!| YASMH          |-->| IF YES, SMH MUST BE TAKEN INTO ACCOUNT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_tvf_2 => tvf_2
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)             :: NPOIN,NPTFR,KDIR,KDDL
      INTEGER, INTENT(IN)             :: OPTSOU,IOPT2
      INTEGER, INTENT(IN)             :: NBOR(nptfr),LIMTRA(nptfr)
      DOUBLE PRECISION, INTENT(IN)    :: DT,SURNIT,TRAIN,TETAFCOR
      DOUBLE PRECISION, INTENT(INOUT) :: FLBORTRA(nptfr),MASSOU
      DOUBLE PRECISION, INTENT(INOUT) :: F(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: FXBOR(nptfr)
      DOUBLE PRECISION, INTENT(IN)    :: FC(npoin),HLIN(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: SMH(npoin),UNSV2D(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: VOLU2D(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: PLUIE(*)
      DOUBLE PRECISION, INTENT(IN)    :: FSCEXP(npoin),FSTAR(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: FBOR(nptfr),FXBORPAR(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: PHI_I(npoin)
      LOGICAL, INTENT(IN)             :: YASMH,RAIN,MASS_BAL
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,N
!
!-----------------------------------------------------------------------
!
      IF(iopt2.NE.0) THEN
        WRITE(lu,*) 'TVF_2: UNKNOWN IOPT2 OPTION'
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
!     INTERNAL FLUXES
!
!-----------------------------------------------------------------------
!
      DO i=1,npoin
        f(i)=f(i)-(dt/hlin(i))*unsv2d(i)*phi_i(i)
      ENDDO
!
!-----------------------------------------------------------------------
!
!     SOURCE TERMS
!
!-----------------------------------------------------------------------
!
      IF(yasmh) THEN
        IF(optsou.EQ.1) THEN
          DO i=1,npoin
            f(i)=f(i)+dt/hlin(i)*smh(i)
     &          *(fscexp(i)-tetafcor*fstar(i)-(1.d0-tetafcor)*fc(i))
          ENDDO
        ELSEIF(optsou.EQ.2) THEN
          DO i=1,npoin
            f(i)=f(i)+dt/hlin(i)*unsv2d(i)*smh(i)
     &          *(fscexp(i)-tetafcor*fstar(i)-(1.d0-tetafcor)*fc(i))
          ENDDO
        ENDIF
        IF(mass_bal) THEN
          IF(optsou.EQ.1) THEN
            DO i=1,npoin
              IF(smh(i).GT.0.d0) THEN
                massou=massou+dt*volu2d(i)*smh(i)*fscexp(i)
              ELSE
                massou=massou+dt*volu2d(i)*smh(i)
     &                *(tetafcor*fstar(i)+(1.d0-tetafcor)*fc(i))
              ENDIF
            ENDDO
          ELSEIF(optsou.EQ.2) THEN
            DO i=1,npoin
              IF(smh(i).GT.0.d0) THEN
                massou=massou+dt*smh(i)*fscexp(i)
              ELSE
                massou=massou+dt*smh(i)
     &                *(tetafcor*fstar(i)+(1.d0-tetafcor)*fc(i))
              ENDIF
            ENDDO
          ENDIF
        ENDIF
      ENDIF
!
!-----------------------------------------------------------------------
!
!     RAIN-EVAPORATION
!
!-----------------------------------------------------------------------
!
      IF(rain) THEN
        DO i=1,npoin
          IF(pluie(i).GT.0.d0) THEN
!           REAL RAIN, VALUE IN RAIN CONSIDERED...
            f(i)=f(i)+dt/hlin(i)*pluie(i)
     &          *(train-tetafcor*fstar(i)-(1.d0-tetafcor)*fc(i))
          ELSE
!           EVAPORATION, VALUE IN RAIN NOT CONSIDERED...
            f(i)=f(i)+dt/hlin(i)*pluie(i)
     &          *(     -tetafcor*fstar(i)-(1.d0-tetafcor)*fc(i))
          ENDIF
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
!     BOUNDARIES
!
!-----------------------------------------------------------------------
!
!     ON THE DIRICHLET BOUNDARIES, FLUX TERMS TAKEN INTO ACCOUNT
!     ON OTHERS, FBOR IS TAKEN AS FN, SO NO CONTRIBUTION
!     FC : FN AT THE PREDICTOR STEP
!
      DO i=1,nptfr
        IF(limtra(i).EQ.kdir) THEN
          n=nbor(i)
          f(n)=f(n)-dt/hlin(n)*unsv2d(n)*fxborpar(n)*
     &                 (fbor(i)-(1.d0-tetafcor)*fc(n)-tetafcor*fstar(n))
        ENDIF
      ENDDO
      IF(mass_bal) THEN
        DO i=1,nptfr
          IF(limtra(i).EQ.kdir) THEN
            flbortra(i)=flbortra(i)+fxbor(i)*fbor(i)*surnit
          ELSEIF(limtra(i).EQ.kddl) THEN
            n=nbor(i)
            flbortra(i)=flbortra(i)
     &        +fxbor(i)*((1.d0-tetafcor)*fc(n)+tetafcor*fstar(n))*surnit
          ENDIF
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END