tsloc.f

Go to the documentation of this file.

!                   *******************************
                    DOUBLE PRECISION FUNCTION tsloc
!                   *******************************
!
     & (year,month,day,hour,minu,sec,at)
!
!***********************************************************************
! BIEF   V6P2                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE LOCAL SIDEREAL TIME IN RADIAN FOR
!+                THE GIVEN DATE IN UNIVERSAL TIME.
!code
!+     IN THIS FUNCTION, THE COMPUTATION TIME MUST BE SPLIT IN:
!+
!+     - TIME UNTIL 0:00 OF THE SAME DAY,
!+     - TIME LEFT UNTIL THE PRECISE DATE IN SECONDS.
!+
!+     THIS REQUIRES A COMBINATION BETWEEN THE STARTING DATE
!+     AND THE COMPUTING TIME AT:
!+
!+     COMPUTES THE TIME IN JULIAN CENTURY AT 0:00 OF THE SAME DAY
!+
!+     AT1 : NUMBER OF DAYS IN SECONDS TO ADD TO THE REFERENCE
!+           DATE (YEAR, MONTH, DAY) TO GET TO THE COMPUTATION
!+           DATE AT TIME (0H, 0MIN, 0SEC).
!+     ATR : NUMBER OF SECONDS BETWEEN THE DATE REPRESENTED BY AT1
!+           AND THE EXACT COMPUTATION DATE. ATR ACTUALLY CORRESPONDS
!+           TO TU EXPRESSED IN SECONDS.
!
!history  E. DAVID (LHF)
!+        02/06/08
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  U.H.MERKEL
!+        21/08/2010
!+        V6P2
!+   Min renamed minute due to NAG COMPILER issues
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AT             |-->| TIME IN SECONDS
!| DAY            |-->| DAY
!| HOUR           |-->| HOUR IN UNIVERSAL TIME
!| MINUTE         |-->| MINUTE IN UNIVERSAL TIME
!| MONTH          |-->| MONTH
!| SEC            |-->| SECOND IN UNIVERSAL TIME
!| YEAR           |-->| YEAR
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_tsloc => tsloc
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)          :: MONTH,DAY,HOUR,MINU,SEC
      INTEGER, INTENT(INOUT)       :: YEAR
      DOUBLE PRECISION, INTENT(IN) :: AT
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      DOUBLE PRECISION T,TETA,TETA0,UT
      DOUBLE PRECISION AT1,ATR
!
      INTRINSIC acos,int
!
!-----------------------------------------------------------------------
!
      atr = at + ( hour * 60.d0 + minu ) * 60.d0 + sec
      at1 = int( atr / ( 24.d0 * 3600.d0 ) ) * ( 24.d0 * 3600.d0 )
      atr = atr - at1
      t = jultim(year,month,day,0,0,0,at1)
!
! COMPUTES THE SIDEREAL TIME WRT GREENWICH AT 0:00 (IN HOURS)
!
      teta0 = 6.6460656d0 + 2400.051262d0 * t + 0.00002581d0 * t**2
!
! COMPUTES THE SIDEREAL TIME WRT GREENWICH AT TU
!
      ut = atr / 3600.d0
      teta = teta0 + ut*1.002737908d0
!
! COMPUTES THE LOCAL SIDEREAL TIME IN RADIANS WITHOUT TAKING LONGITUDE
! INTO ACCOUNT
!
      tsloc = teta * acos(-1.d0) / 12.d0
!
!-----------------------------------------------------------------------
!
      RETURN
      END