tobw_sisyphe.f

Go to the documentation of this file.

!                   ***********************
                    SUBROUTINE tobw_sisyphe
!                   ***********************
!
     &(tobw ,cf, fw, uw,tw,hn,npoin,xmve)
!
!***********************************************************************
! SISYPHE   V6P1                                   21/07/2011
!***********************************************************************
!
!brief    COMPUTES THE WAVE FRICTION STRESS. THE FRICTION
!+                COEFFICIENT IS COMPUTED USING SWART FORMULATION (1976).
!
!history  C. VILLARET (LNHE)
!+        01/10/2003
!+        V5P4
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C.VILLARET (EDF-LNHE), P.TASSI (EDF-LNHE)
!+        19/07/2011
!+        V6P1
!+   Name of variables
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| CF             |-->| QUADRATIC FRICTION COEFFICIENT
!| FW             |-->| QUADRATIC FRICTION COEFFICIENT (WAVE)
!| HN             |-->| WATER DEPTH AT TIME N
!| NPOIN          |-->| NUMBER OF POINTS
!| TOBW           |-->| TOTAL BED SHEAR STRESS
!| TW             |-->| WAVE PERIOD
!| UW             |-->| ORBITAL VELOCITY (WAVE)
!| XMVE           |-->| FLUID DENSITY
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NPOIN
!
      DOUBLE PRECISION, INTENT(IN)    :: CF(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: UW(npoin),TW(npoin),HN(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: XMVE
      DOUBLE PRECISION, INTENT(INOUT) :: TOBW(npoin),FW(npoin)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I
      DOUBLE PRECISION KS,AUX
      DOUBLE PRECISION PI,AW
      DOUBLE PRECISION, PARAMETER :: KARMAN = 0.4d0
!
!-----------------------------------------------------------------------
!
      pi = 4.d0 * atan( 1.d0 )
!
!-----------------------------------------------------------------------
!
      DO  i=1,npoin
!       KS : NIKURADSE COEFFICIENT (TOTAL FRICTION)
        aux=1.d0+karman*sqrt(2.d0/max(cf(i),1.d-10))
        ks=30.d0*max(hn(i),1.d-8)*exp(-aux)
        aw= uw(i)*tw(i) / (2.d0*pi)
        IF(aw/ks.GT.1.59d0) THEN
          fw(i)=exp( -6.d0 + 5.2d0 * (aw/ks)**(-0.19d0) )
        ELSE
          fw(i)=0.3d0
        ENDIF
        tobw(i)=0.5d0 * xmve * fw(i) * uw(i)*uw(i)
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE tobw_sisyphe