tetmoy.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE tetmoy
!                   *****************
!
     &( tetam , f     , ndire , nf    , npoin2)
!
!***********************************************************************
! TOMAWAC   V6P1                                   28/06/2011
!***********************************************************************
!
!brief    COMPUTES THE MEAN DIRECTION OF A DIRECTIONAL SPECTRUM
!+               (BY COMPUTING THE ARC TANGENT OF THE MEAN SINE AND
!+                COSINE). THE RESULT IS IN RADIANS.
!
!history  P. THELIIER; M. BENOIT
!+        01/02/95
!+        V1P0
!+
!
!history  M. BENOIT
!+        05/07/96
!+        V1P2
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        28/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| COSMOY         |<->| WORK TABLE
!| COSTET         |-->| COSINE OF TETA ANGLE
!| DFREQ          |-->| FREQUENCY STEPS BETWEEN DISCRETIZED FREQUENCIES
!| F              |-->| VARIANCE DENSITY DIRECTIONAL SPECTRUM
!| FREQ           |-->| DISCRETIZED FREQUENCIES
!| NF             |-->| NUMBER OF FREQUENCIES
!| NDIRE          |-->| NUMBER OF DIRECTIONS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D MESH
!| SINMOY         |<->| WORK TABLE
!| SINTET         |-->| SINE OF TETA ANGLE
!| TAILF          |-->| FACTEUR DE QUEUE DU SPECTRE
!| TAUXC          |<->| WORK TABLE
!| TAUXS          |<->| WORK TABLE
!| TETAM          |<--| DIRECTIONAL SPECTRUM MEAN DIRECTION
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_tomawac, ONLY : deupi, freq, dfreq, tailf,
     &                                 costet, sintet
!
      USE interface_tomawac, ex_tetmoy => tetmoy
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)    ::  NF    , NDIRE , NPOIN2
      DOUBLE PRECISION, INTENT(IN)    :: F(npoin2,ndire,nf)
      DOUBLE PRECISION, INTENT(INOUT) :: TETAM(npoin2)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER  IP    , JP    , JF
      DOUBLE PRECISION AUXC  , AUXS  ,SEUIL , COEFT, DFDTET
      DOUBLE PRECISION DTETAR, COSMOY,SINMOY, TAUXC, TAUXS
!
!-----------------------------------------------------------------------
!
      dtetar=deupi/dble(ndire)
      seuil =1.d-10
!
      DO ip=1,npoin2
        cosmoy=0.d0
        sinmoy=0.d0
!
!-----C-------------------------------------------------------C
!-----C  SUMS UP THE DISCRETISED PART OF THE SPECTRUM         C
!-----C-------------------------------------------------------C
!
        DO jf=1,nf
!
          dfdtet=dfreq(jf)*dtetar
!
          tauxc=0.d0
          tauxs=0.d0
!
          DO jp=1,ndire
            auxc=costet(jp)*dfdtet
            auxs=sintet(jp)*dfdtet
            tauxc=tauxc+f(ip,jp,jf)*auxc
            tauxs=tauxs+f(ip,jp,jf)*auxs
          ENDDO
!
          cosmoy=cosmoy+tauxc
          sinmoy=sinmoy+tauxs
!
        ENDDO                   ! JF
!
!-----C-------------------------------------------------------------C
!-----C  TAKES THE HIGH FREQUENCY PART INTO ACCOUNT (OPTIONAL)      C
!-----C-------------------------------------------------------------C
!
        IF(tailf.GT.1.d0) THEN
          coeft=freq(nf)/((tailf-1.d0)*dfreq(nf))
          cosmoy=cosmoy+tauxc*coeft
          sinmoy=sinmoy+tauxs*coeft
        ENDIF
!
!-----C-------------------------------------------------------------C
!-----C  COMPUTES THE MEAN DIRECTION                                C
!-----C  (IN RADIANS BETWEEN 0 AND 2.PI)                            C
!-----C-------------------------------------------------------------C
!
        IF(abs(sinmoy).LT.seuil.AND.
     &       abs(cosmoy).LT.seuil) THEN
          tetam(ip) = 0.d0
        ELSE
          tetam(ip)=atan2(sinmoy,cosmoy)
          IF(tetam(ip).LT.0.d0) tetam(ip)=tetam(ip)+deupi
        ENDIF
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END