tautot.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE tautot
!                   *****************
!
     &( taut  , uvent , tauw  , seuil ,
     &  itr   , itrmin, itrmax)
!
!***********************************************************************
! TOMAWAC   V6P1                                   28/06/2011
!***********************************************************************
!
!brief    COMPUTES THE TOTAL STRESS FROM THE WIND VELOCITY
!+                UVENT AT THE ELEVATION ZVENT (IN PRINCIPLE ZVENT=10 M)
!+                AND FROM THE WAVE STRESS TAUW.
!+
!+            THEORY DEVELOPED BY JANSSEN (1989 AND 1991) AND USED
!+                IN WAM-CYCLE 4 (SUBROUTINE STRESS OF PREPROC).
!
!note     TAUT IS COMPUTED FROM UVENT AND TAUW (SOLVES THE EQUATION
!+          IMPLICITLY USING AN ITERATIVE METHOD - NEWTON).
!
!reference  JANSSEN P.A.E.M (1989) :
!+                     "WIND-INDUCED STRESS AND THE DRAG OF AIR FLOW
!+                      OVER SEA WAVES". JPO, VOL 19, PP 745-754.
!reference JANSSEN P.A.E.M (1991) :
!+                     "QUASI-LINEAR THEORY OF WIND-WAVE GENERATION
!+                      APPLIED TO WAVE FORECASTING". JPO, VOL 21, PP 1631-1642.
!
!history  M. BENOIT (EDF/DER/LNH)
!+        25/04/95
!+        V1P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        28/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ITR            |<--| NOMBRE D'ITERATIONS EFFECTUES
!| ITRMAX         |-->| MAXIMUM NUMBER OF ITERATIONS
!| ITRMIN         |-->| MINIMUM NUMBER OF ITERATIONS
!| SEUIL          |-->| CONVERGENCY THRESHOLD - NEWTON METHOD
!| TAUT           |<--| TOTAL STRESS
!| TAUW           |-->| STRESS DUE TO THE WAVES
!| UVENT          |-->| WIND SPEED AT HEIGHT ZVENT
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_tomawac, ONLY : gravit, xkappa, alpha, cdrag,
     &                zvent
      USE interface_tomawac, ex_tautot => tautot
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""
      INTEGER, INTENT(IN)    ::  ITRMIN, ITRMAX
      INTEGER, INTENT(INOUT) ::  ITR
      DOUBLE PRECISION, INTENT(IN)    :: UVENT , TAUW
      DOUBLE PRECISION, INTENT(IN)    :: SEUIL
      DOUBLE PRECISION, INTENT(INOUT) :: TAUT
! Variables in TOMAWAC MODULE
!   XKAPPA          VON KARMAN CONSTANT
!   ALPHA           CHARNOCK CONSTANT
!   ZVENT    ELEVATION FOR WIND MEASUREMENTS
!
!.....LOCAL VARIABLES
!     """""""""""""""""
      DOUBLE PRECISION TAUMIN, XNUAIR, AUX   , USTO  , TAUO   , TAUN
      DOUBLE PRECISION USTN  , X     , ZE    , DIFF  , FOLD   , DFOLD
!
      itr   =0
      taumin=1.d-5
      xnuair=1.d-5
!
!.....INITIAL VALUES
!     """"""""""""""""""
      usto  =uvent*sqrt(cdrag)
      tauo  =max(usto**2,tauw+taumin)
  190 CONTINUE
      itr   = itr+1
!
!.....ITERATION BY THE METHOD OF NEWTON
!     """""""""""""""""""""""""""""""""""
      usto  = sqrt(tauo)
      x     = tauw/tauo
      IF(abs(1.d0-x).LT.1.d-30) THEN
        WRITE(lu,*) 'IN ROUTINE TAUTOT I DIVIDE BY 1-X'
        WRITE(lu,*) 'AND X=',x,' WIND MODELE =1 ?'
        WRITE(lu,*) 'MAY BE YOU CAN TRY WITH MODELE=2 ?'
        CALL plante(3)
        stop
      ENDIF
      ze    = max(0.1d0*xnuair/usto,alpha*tauo/(gravit*sqrt(1.d0-x)))
      aux   = log(zvent/ze)
      fold  = usto-xkappa*uvent/aux
      dfold = 1.d0-2.d0*xkappa*uvent*(1.d0-1.5d0*x)/aux**2/usto/(1.d0-x)
      ustn  = usto-fold/dfold
      taun  = max(ustn**2,tauw+taumin)
!
!.....CONVERGENCE CRITERIA
!     """"""""""""""""""""""""
      diff=abs(taun-tauo)/tauo
      tauo=taun
      IF (itr.LT.itrmin) GOTO 190
      IF ((diff.GT.seuil).AND.(itr.LT.itrmax)) GOTO 190
!
!.....APPLIES THE SOLUTION
!     """""""""""""""""""""""""""""""""""
      taut=taun
!
      RETURN
      END