tassement_2.f

Go to the documentation of this file.

!                     **********************
                      SUBROUTINE tassement_2
!                     **********************
!
     &(npoin,dts,elay,dzf_tass,t2,lt,xmvs,xmve,nomblay,
     & es,conc_vase,ms_vase,xwc,coef_n,conc_gel,conc_max)
!
!***********************************************************************
! SISYPHE   V6P2                                   13/01/2012
!***********************************************************************
!
!BRIEF    COMPUTES THE CONSOLIDATION BASED ON GIBSON THEORY
!+
!
!history LAN ANH VAN (LHSV)
!+        10/01/2011
!+        V6P2
!+   FIRST VERSION IN TEST (NOT YET CALLED IN CURRENT VERSION 6.2)
!+
!history  PABLO SANTORO (IMFIA) AND PABLO TASSI (EDF R&D - LHSV)
!+        01/08/2015
!+        V7P1
!+   INFLUENCE OF THE DIFFUSION EFFECT IN COMPUTATION OF
!+   THE EFFECTIVE STRESS, SEE VAN (2012)
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| COEF_N         |-->| PERMEABILITY COEFFICIENT
!| CONC_GEL       |-->| GEL CONCENTRATION
!| CONC_MAX       |-->| MAXIMUM CONCENTRATION
!| CONC_VASE      |<->| MUD CONCENTRATION FOR EACH LAYER
!| DTS            |-->| TIME STEP FOR SUSPENSION
!| DZF_TASS       |-->| BED EVOLUTION DUE TO CONSOLIDATION
!| ELAY           |<->| THICKNESS OF EACH LAYER
!| ES             |<->| LAYER THICKNESSES AS DOUBLE PRECISION
!| GRAV           |-->| GRAVITY ACCELERATION
!| LT             |-->| ITERATION
!| MS_VASE        |<->| MASS OF MUD PER LAYER (KG/M2)
!| NOMBLAY        |-->| NUMBER OF LAYERS FOR CONSOLIDATION
!| NPOIN          |-->| NUMBER OF POINTS
!| T2             |<->| WORK BIEF_OBJ STRUCTURE
!| XMVE           |-->| WATER DENSITY
!| XMVS           |-->| SEDIMENT DENSITY
!| XWC            |-->| SETTLING VELOCITY
!| ZF             |-->| ELEVATION OF BOTTOM
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_sisyphe, ONLY : nlaymax
      USE interface_sisyphe, ex_tassement_2 => tassement_2
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER,INTENT(IN)              :: NPOIN
      INTEGER, INTENT(IN)             :: LT,NOMBLAY
      DOUBLE PRECISION, INTENT(IN)    :: DTS
      DOUBLE PRECISION, INTENT(IN)    :: XMVS,XMVE
      type(bief_obj),  INTENT(INOUT) :: dzf_tass,elay,t2
      DOUBLE PRECISION, INTENT(INOUT) :: MS_VASE(npoin,nomblay)
      DOUBLE PRECISION, INTENT(INOUT) :: ES(npoin,nomblay)
      DOUBLE PRECISION, INTENT(IN)    :: CONC_VASE(nomblay)
      DOUBLE PRECISION, INTENT(IN)    :: XWC
      DOUBLE PRECISION, INTENT(IN)    :: COEF_N,CONC_GEL,CONC_MAX
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,J
!     FALLING VELOCITY OF EACH LAYER
      DOUBLE PRECISION V_S(nlaymax)
!     EFFECTIVE STRESS OF EACH LAYER
      DOUBLE PRECISION SIG_EFF(nlaymax)
!     PERMEABILITY
      DOUBLE PRECISION KSED(nlaymax),KCONSO(nlaymax)
!     SEDIMENT FLUX BETWEEN TWO CONSECUTIVE LAYERS
      DOUBLE PRECISION FLUX(nlaymax)
!     DIFFUSION TERM
      DOUBLE PRECISION DIFFU(nlaymax)
!
!     ******************************************************************
!     * PROGRAM SIMULATING THE SEDIMENTATION-CONSOLIDATION             *
!     ******************************************************************
!
      DO i =1,npoin
        t2%R(i)=0.d0
        DO j=1,nomblay
          t2%R(i)=t2%R(i)+es(i,j)
        ENDDO

!       FROM VAN (2012)
!       DEPENDING ON THE CLOSURE EQUATIONS,
!       THE INPUT CAN BE EFFECTIVE STRESS OF DIFFUSION TERM (=
!       KC*DSIGMA/DC/(G*RHO_F))
!
!        EFFECTIVE STRESS: DIFFUSION TERM
!       ----------------------------------
        DO j = 1,nomblay
          diffu(j)=11.55d0*(conc_vase(j)/(xmvs*0.0296d0))**12.d0*
     & (lt*dts)**(-3.4d0)
        ENDDO

!       EFFECTIVE STRESS
!       ------------------------
        DO j = 1,nomblay
          sig_eff(j)=119033.d0*(conc_vase(j)/xmvs)**14.d0
        ENDDO

!       PERMEABILITY
!       --------------
        DO j=1,nomblay-1
!       SEDIMENTATION
          ksed(j)=xwc*(1.d0-conc_vase(j)/xmvs)*
     &            (1.d0-(conc_vase(j)/conc_gel))**coef_n/
     &            ((xmvs-xmve)*(conc_vase(j)/xmvs)/xmve)
!       CONSOLIDATION
          kconso(j)=xwc*(1.d0-conc_vase(j)/xmvs)*
     &            (1.d0-(conc_vase(j)/conc_max))**coef_n/
     &            ((xmvs-xmve)*(conc_vase(j)/xmvs)/xmve)
!
        IF (conc_vase(j).GT.conc_gel) THEN
!
!     SEDIMENTATION AND CONSOLIDATION :
!     --------------------------------
        IF ((es(i,j+1) + es(i,j)).GT.1.d-8) THEN
            v_s(j) =
     & kconso(j) * conc_vase(j) * (1.d0/xmvs - 1.d0/xmve)
     & + diffu(j)/conc_vase(j)*
     & (conc_vase(j+1)-conc_vase(j))/
     & (0.5d0 * (es(i,j+1) + es(i,j)))
! CALCULATE FROM SIG_EFF
!            V_S(J) =
!     &          KCONSO(J) * CONC_VASE(J) * (1.D0/XMVS - 1.D0/XMVE)
!     &          + ( KCONSO(J) / (XMVE * GRAV)) *
!     &          (SIG_EFF(J+1) - SIG_EFF(J)) /
!     &          (0.5D0 * (ES(I,J+1) + ES(I,J)))
          ELSE
            v_s(j) = 1.d8
          ENDIF
        ELSE
!      PURE SEDIMENTATION :
!     ---------------
          v_s(j) = ksed(j)*conc_vase(j)*(1.d0/xmvs-1.d0/xmve)
        ENDIF
      ENDDO
!
        DO j=1,nomblay
          IF (v_s(j).GT.0.d0) v_s(j) = 0.d0
        ENDDO
!
!      FALLING VELOCITY AT THE LEVEL OF ZR (AT THE BED)
          v_s(nomblay) = 0.d0
!      SEDIMENT FLUX :
!     --------------
        DO j=nomblay-1,1,-1
          flux(j) =
     &    (v_s(j)-v_s(j+1))*conc_vase(j+1)*conc_vase(j)/
     &          (conc_vase(j+1)-conc_vase(j))
          IF (flux(j).GT.0.d0) flux(j) = 0.d0
        ENDDO
!      SEDIMENT FLUX AT THE RIGID BED
        flux(nomblay) = 0.d0
!
!      REDISTRIBUTE THE MASS :
!      ----------------------------------
!      RECALCULATE THE FLUX FROM LAYER 1 TO NCOUCH_TASS
        IF ((ms_vase(i,1)+dts*flux(1)).LT.0.d0) THEN
          flux(1) = -ms_vase(i,1)/dts
        ENDIF
        DO j=2,nomblay
          IF ((ms_vase(i,j)-dts*(flux(j-1)-flux(j))).LT.0.d0) THEN
            flux(j) = -ms_vase(i,j)/dts + flux(j-1)
          ENDIF
        ENDDO
!      MASS OF FIRST LAYER
        ms_vase(i,1)=ms_vase(i,1)+dts*flux(1)
!      MASS OF LAYER 2 TO NCOUCH_TASS
        DO j=2,nomblay
          ms_vase(i,j) = ms_vase(i,j) - dts * (flux(j-1)-flux(j))
        ENDDO
!
!      THICKNESSES
        elay%R(i)=0.d0
!
        DO j=1,nomblay
          es(i,j) = ms_vase(i,j) / conc_vase(j)
          elay%R(i)=elay%R(i) + es(i,j)
        ENDDO
!      BED EVOLUTION DUE TO CONSOLIDATION
        dzf_tass%R(i)=elay%R(i)-t2%R(i)
      ENDDO
!  END SUBROUTINE TASSEMENT_2
      RETURN
      END