suspension_sandflow.f

Go to the documentation of this file.

!                   ***************************************
                    SUBROUTINE suspension_sandflow
!                   ***************************************
!
     &  (fdm, fd90, npoin, grav,
     &   xmve, xmvs, zero, cstaeq,hn,u2d,v2d,csratio)
!
!***********************************************************************
! SISYPHE
!***********************************************************************
!
!brief    Attempt to ensure SISYPHE computes C_a in the same way as
!+        HRW-SANDFLOW. Uses Soulsby-van Rijn formula to give a
!+        (depth-averaged) saturated concentration.
!
!history    D.M.Kelly (HRW)
!+          19/07/2012
!+          V6P1
!+        Original implementation
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AC             |<->|
!| FDM            |-->| D50
!| GRAV           |-->| ACCELERATION DUE TO GRAVITY
!| NPOIN          |-->|
!| XMVE           |-->| WATER DENSITY
!| XMVS           |-->| SEDIMENT DENSITY
!| CSTAEQ         |<->| EQUILIBRIUM SEDIMENT CONCENTRATION
!! HN             |-->| WATER DEPTJ
!| U2D            |-->| DEPTH AVERAGED VELOCITY IN X DIRECTION
!| V2D            |-->| DEPTH AVERAGED VELOCITY IN Y DIRECTION
!| T2             |<->| WORK ARRAY
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_sisyphe,
     & ex_suspension_sandflow => suspension_sandflow
      USE bief
      USE declarations_sisyphe, ONLY : vce,uw,houle,prive
      USE declarations_special
      IMPLICIT NONE
!
      ! 2/ GLOBAL VARIABLES
      ! -------------------
      TYPE(bief_obj),   INTENT(IN)       :: HN,U2D,V2D,CSRATIO
      INTEGER,          INTENT(IN)       :: NPOIN
      DOUBLE PRECISION, INTENT(IN)       :: GRAV, XMVE, XMVS
      DOUBLE PRECISION, INTENT(IN)       :: ZERO,FDM,FD90
      TYPE(bief_obj),   INTENT(INOUT)    :: CSTAEQ
!
      ! 3/ LOCAL VARIABLES
      ! ------------------
      INTEGER            :: I
      DOUBLE PRECISION   :: DSTAR,DENS,COEFF,UCR,ASS,UB
      DOUBLE PRECISION   :: WORB,CD
      DOUBLE PRECISION, PARAMETER :: Z0=0.006d0
      INTRINSIC max
!======================================================================!
!======================================================================!
!                               PROGRAMME                              !
!======================================================================!
!======================================================================!

      dens  = (xmvs - xmve )/ xmve

      DO i=1,npoin
        ! ***************** !
        ! IV - EROSION FLUX ! (_IMP_)
        ! ***************** !
        dstar = fdm*(grav*dens/(vce*vce))**(1.d0/3.d0)
        coeff = (dens*grav*fdm)**1.2d0
        IF(dstar.LE. zero) THEN
          WRITE(lu,*)'ERROR SUSPENSION_SANDFLOW:DSTAR = ',dstar,fdm,
     &               vce,grav
          CALL plante(1)
          stop
        ENDIF
        IF ((hn%R(i).GT.zero).AND.(coeff.GT.zero)) THEN
!         CRITICAL VELOCITIES:
          IF (fdm<500.e-6) THEN
!            UCR = 0.19D0*(D50**0.1D0)*LOG10(4.0D0*(HN%R(I)/D50))    ! SANDFLOW
            ucr = 0.19d0*(fdm**0.1d0)*log10(4.0d0*hn%R(i)/fd90)  ! CORRECT
          ELSE
!               UCR = 8.5D0*(D50**0.6D0)*LOG10(4.D0*(HN%R(I)/D50))      ! SANDFLOW
            ucr = 8.5d0*(fdm**0.6d0)*log10(4.d0*hn%R(i)/fd90)    ! CORRECT
          END IF
!              WAVE ORBITAL VELOCITIES:
          IF (houle) THEN
            cd   = (0.4d0/(log(max(hn%R(i),z0)/z0)-1.d0))**2.d0
            worb = (0.018d0/cd)*(uw%R(i)**2.d0)
          ELSE
            worb = 0.d0
          ENDIF
          ass = (0.012d0*fdm*(dstar**(-0.6d0)))/coeff      ! JUST FOR SUSPENDED LOAD (A LA SANDFLOW)
          ub  = (u2d%R(i)*u2d%R(i))+(v2d%R(i)*v2d%R(i))+worb ! VEL
!             NOTE WE MULTIPLY EQ. (136A) OF SOULSBY (1997) THROUGH BY (UH)^{-1} TO GET DIMENSIONLESS
!              DEPTH-AVERAGED SATURATION CONCENTRATION CA:
          cstaeq%R(i)=ass*(max(0.d0,(sqrt(ub)-ucr))**2.4d0)/hn%R(i) !MISSING ORB VELS
!              DUMP SATURATED CONC OUTPUT TO SUPPLEMENTARY VARIABLE A (PRIVATE ARRAY WITH INDEX 1):
          prive%ADR(1)%P%R(i)=cstaeq%R(i)
          cstaeq%R(i)=cstaeq%R(i)*csratio%R(i)
        ELSE
          cstaeq%R(i) = 0.d0
        ENDIF
      ENDDO
!======================================================================!
!======================================================================!
      RETURN
      END SUBROUTINE suspension_sandflow