suspension_rouse.f

Go to the documentation of this file.

!                   ***************************
                    SUBROUTINE suspension_rouse
!                   ***************************
!
     &(ustar,hn,npoin,karman,zero,xwc,zref,t2)
!
!***********************************************************************
! SISYPHE   V6P1                                   21/07/2011
!***********************************************************************
!
!brief    COMPUTES THE DEPOSITION FLUX AND
!+                CONCENTRATION ACCORDING TO ROUSE PROFILE.
!
!history  C. VILLARET     ; J-M HERVOUET
!+        14/04/04
!+        V5P5
!+
!
!history  F. HUVELIN
!+        04/01/05
!+        V5P6
!+
!
!history  J-M HERVOUET
!+        13/07/07
!+        V5P7
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C.VILLARET (EDF-LNHE), P.TASSI (EDF-LNHE)
!+        19/07/2011
!+        V6P1
!+   Name of variables
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| HN             |-->| WATER DEPTH
!| KARMAN         |-->| VON KARMAN CONSTANT
!| NPOIN          |-->| NUMBER OF POINTS
!| T2             |<->| WORK BIEF_OBJ STRUCTURE
!| USTAR          |-->| SHEAR VELOCITY
!| XWC            |-->| SETTLING VELOCITIES
!| ZERO           |-->| ZERO
!| ZREF           |-->| REFERENCE ELEVATION
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_sisyphe,ex_suspension_rouse => suspension_rouse
      USE bief
      USE declarations_special
      IMPLICIT NONE
      ! 2/ GLOBAL VARIABLES
      ! -------------------
      TYPE(bief_obj),   INTENT(IN)    :: USTAR,HN,ZREF
      INTEGER,          INTENT(IN)    :: NPOIN
      DOUBLE PRECISION, INTENT(IN)    :: KARMAN,XWC,ZERO
      TYPE(bief_obj),   INTENT(INOUT) :: T2
      ! 3/ LOCAL VARIABLES
      ! ------------------
      INTEGER          :: I
      DOUBLE PRECISION :: B,EXP1,ROUSE
!
      INTRINSIC max,min,log
!
!======================================================================!
!======================================================================!
!                               PROGRAM                                !
!======================================================================!
!======================================================================!
!
!     ROUSE NUMBER AND MINIMUM BOUND OF THE EINSTEIN INTEGRAL
!
      DO i=1,npoin
!
!       ROUSE NUMBER
!
        rouse=  xwc / (karman*max(ustar%R(i),zero))
!
!       MINIMUM BOUND OF THE EINSTEIN INTEGRAL -->  B = KS/H
!
!       B ALWAYS LESS THAN 1.
        b = zref%R(i)/max(hn%R(i),zref%R(i))
!
!       RATIO BETWEEN REFERENCE CONC. ON BOTTOM AND MEAN CONC.
!       ASSUMING EXPONENTIAL PROFILE WITH EXPONENT ROUSE NUMBER --> T2
!
        exp1=rouse-1.d0
        IF(abs(exp1).GT.1.d-4) THEN
          exp1=min(exp1,3.d0)
          t2%R(i)=b*(1.d0-b**exp1)/exp1
        ELSE
          t2%R(i)=-b*log(b)
        ENDIF
        t2%R(i)=max(1.d0/max(t2%R(i),zero),1.d0)
      ENDDO
!
!======================================================================!
!======================================================================!
!
      RETURN
      END