suspension_fredsoe.f

Go to the documentation of this file.

!                   *****************************
                    SUBROUTINE suspension_fredsoe
!                   *****************************
!
     &(dm,taup,npoin,grav,xmve,xmvs,ac,cstaeq)
!
!***********************************************************************
! SISYPHE   V6P1                                   21/07/2011
!***********************************************************************
!
!brief    COMPUTES THE REFERENCE CONCENTRATION AT Z= 2*D50
!+                ACCORDING TO ZYSERMAN AND FREDSOE FORMULATION (1994).
!
!history  C. VILLARET
!+        14/04/2004
!+        V5P5
!+
!
!history  F. HUVELIN
!+        04/01/2005
!+        V5P6
!+
!
!history  JMH
!+        13/06/2008
!+
!+   FORMULATION OPTIMISED WITH AUX
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!+
!+
!history  C. VILLARET
!+        20/03/2011
!+        V6P1
!+   Send DM instead of array ACLADM
!
!history  C.VILLARET (EDF-LNHE), P.TASSI (EDF-LNHE)
!+        19/07/2011
!+        V6P1
!+   Name of variables
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AC             |<->| CRITICAL SHIELDS PARAMETER
!| DM             |-->| SEDIMENT GRAIN DIAMETER
!| CSTAEQ         |<->| EQUILIBRIUM CONCENTRATION
!| GRAV           |-->| ACCELERATION OF GRAVITY
!| NPOIN          |-->| NUMBER OF POINTS
!| TAUP           |-->| CRITICAL SHEAR STRESS
!| XMVE           |-->| FLUID DENSITY
!| XMVS           |-->| WATER DENSITY
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_sisyphe,ex_suspension_fredsoe => suspension_fredsoe
      USE bief
      USE declarations_special
      IMPLICIT NONE
!
!
      ! 2/ GLOBAL VARIABLES
      ! -------------------
      TYPE(bief_obj),   INTENT(IN)    ::  TAUP
      INTEGER,          INTENT(IN)    :: NPOIN
      DOUBLE PRECISION, INTENT(IN)    :: GRAV, XMVE, XMVS
      DOUBLE PRECISION, INTENT(IN)    :: AC,DM
      TYPE(bief_obj),   INTENT(INOUT) :: CSTAEQ


      ! 3/ LOCAL VARIABLES
      ! ------------------
      INTEGER            :: I
      DOUBLE PRECISION   ::  TETAP,AUX
!
!     MAXIMUM CONCENTRATION CORRESPONDING TO DENSE PACKING
!
      DOUBLE PRECISION, PARAMETER :: CMAX = 0.6d0
!!
!======================================================================!
!======================================================================!
!                               PROGRAM                                !
!======================================================================!
!======================================================================!
!
      ! ******************************** !
      !    I - CRITICAL SHIELDS PARAMETER!
      ! ******************************** !
!
      DO i=1,npoin
!
        ! ****************** !
        ! II - SKIN FRICTION !
        ! ****************** !
!
        tetap = taup%R(i) / (grav*(xmvs-xmve)*dm)
!
        ! ***************** !
        ! IV - EROSION FLUX ! (_IMP_)
        ! ***************** !
        ! CONCENTRATION INCREASED BY AVA BECAUSE IT IS COMPUTED
        ! ONLY WITH ONE CLASS OF SEDIMENT (ASSUMPTION)
!
        IF(tetap.GT.ac) THEN
          aux=(tetap-ac)**1.75d0
          cstaeq%R(i) = 0.331d0*aux/(1.d0+0.72d0*aux)
          cstaeq%R(i) = min(cstaeq%R(i),cmax)
        ELSE
          cstaeq%R(i) = 0.d0
        ENDIF
!
      ENDDO
!
!======================================================================!
!======================================================================!
!
      RETURN
      END