suspension_erosion.f

Go to the documentation of this file.

!                 *****************************
                  SUBROUTINE suspension_erosion
!                 *****************************
!
     &(taup,hn,fdm,fd90,ava,npoin,charr,xmve,xmvs,vce,grav,xwc,
     & zero,zref,ac,fluer,cstaeq,qsc,icq,u2d,v2d,csratio,debug)
!
!***********************************************************************
! SISYPHE   V6P2                                   01/07/2012
!***********************************************************************
!
!brief    COMPUTES THE FLUX OF DEPOSITION AND EROSION.
!
!history  J-M HERVOUET + C VILLARET
!+        17/09/2009
!+
!+
!
!history  CV
!+        04/05/2010
!+        V6P0
!+   MODIFICATION FOR FREDSOE: EQUILIBRIUM CONCENTRATIONS
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C.VILLARET (EDF-LNHE), P.TASSI (EDF-LNHE)
!+        19/07/2011
!+        V6P1
!+   Name of variables
!+
!history  MAK (HRW)
!+        31/05/2012
!+        V6P2
!+  Include CSRATIO
!
!history  PAT (LNHE)
!+        18/06/2012
!+        V6P2
!+  updated version with HRW's development: Soulsby-van Rijn's concentration
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AC             |<->| CRITICAL SHIELDS PARAMETER (SHOULD BE INPUT ONLY)
!| ACLADM         |-->| MEAN DIAMETER OF SEDIMENT
!| AVA            |-->| VOLUME PERCENT OF SEDIMENT CLASS IN THE TOP ACTIVE LAYER
!| CHARR          |-->| LOGICAL, IF BEDLOAD OR NOT
!| CSTAEQ         |<->| EQUILIBRIUM CONCENTRATION
!| CSRATIO        |<->| EQUILIBRIUM CONCENTRATION FOR SOULBY-VAN RIJN EQ.
!| DEBUG          |-->| FLAG FOR DEBUGGING
!| FLUER          |<->| EROSION FLUX
!| GRAV           |-->| ACCELERATION OF GRAVITY
!| HN             |-->| WATER DEPTH
!| ICQ            |-->| REFERENCE CONCENTRATION FORMULA
!| NPOIN          |-->| NUMBER OF POINTS
!| QSC            |-->| BED LOAD TRANSPORT RATE
!| TAUP           |-->| SKIN FRICTION
!| VCE            |-->| FLOW VISCOSITY
!| XMVE           |-->| FLUID DENSITY
!| XMVS           |-->| WATER DENSITY
!| XWC            |-->| SETTLING VELOCITIES
!| ZREF           |-->| REFERENCE ELEVATION
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_sisyphe, ex_suspension_erosion=>suspension_erosion
      USE bief
      USE declarations_special
      IMPLICIT NONE

      ! 2/ GLOBAL VARIABLES
      ! -------------------
      type(bief_obj),  INTENT(IN)    :: taup,hn,zref,qsc
      type(bief_obj),  INTENT(IN)    :: u2d,v2d,csratio
      INTEGER,          INTENT(IN)    :: NPOIN,DEBUG,ICQ
      LOGICAL,          INTENT(IN)    :: CHARR
      DOUBLE PRECISION, INTENT(IN)    :: XMVE,XMVS,GRAV,XWC,VCE
      DOUBLE PRECISION, INTENT(IN)    :: AVA(npoin),FDM,FD90,ZERO
      type(bief_obj),  INTENT(INOUT) :: fluer,cstaeq
      DOUBLE PRECISION, INTENT(INOUT) :: AC

      ! 3/ LOCAL VARIABLES
      ! -------------------

      INTEGER I
!
!======================================================================!
!======================================================================!
!                               PROGRAM                                !
!======================================================================!
!======================================================================!
!
!  COMPUTES THE NEAR BED EQUILIBRIUM CONCENTRATION --> CSTAEQ (MEAN DIAMETER)
!
      IF(icq.EQ.1) THEN
!
        IF(debug > 0) WRITE(lu,*) 'SUSPENSION_FREDSOE'
        CALL suspension_fredsoe(fdm,taup,npoin,
     &                          grav,xmve,xmvs,ac,cstaeq)
        IF(debug > 0) WRITE(lu,*) 'END SUSPENSION_FREDSOE'
!
        DO i=1,npoin
          cstaeq%R(i)=cstaeq%R(i)*ava(i)
        ENDDO
        CALL os('X=CY    ', x=fluer, y=cstaeq, c=xwc)
!
      ELSEIF(icq.EQ.2) THEN
!
        IF(debug > 0) WRITE(lu,*) 'SUSPENSION_BIJKER'
        CALL suspension_bijker(taup,npoin,charr,qsc,zref,
     &                         zero,cstaeq,xmve)
        IF(debug > 0) WRITE(lu,*) 'END SUSPENSION_BIJKER'
!       NO MULTIPLICATION BY AVA BECAUSE AVA HAS ALREADY BEEN TAKEN
!       INTO ACCOUNT IN THE BEDLOAD TRANSPORT RATE
        CALL os('X=CY    ', x=fluer, y=cstaeq, c=xwc)
!
      ELSEIF(icq.EQ.3) THEN
!
        IF(debug > 0) WRITE(lu,*) 'SUSPENSION_VANRIJN'
        CALL suspension_vanrijn(fdm,taup,npoin,grav,xmve,xmvs,
     &                          vce,zero,ac,cstaeq,zref)
        IF(debug > 0) WRITE(lu,*) 'END SUSPENSION_VANRIJN'
        DO i=1,npoin
          cstaeq%R(i)=cstaeq%R(i)*ava(i)
        ENDDO
        CALL os('X=CY    ', x=fluer, y=cstaeq, c=xwc)
      ELSEIF(icq.EQ.4) THEN
        IF(debug > 0) WRITE(lu,*) 'SUSPENSION_SANDFLOW'
        CALL suspension_sandflow(fdm,fd90,npoin,grav,xmve,xmvs,
     &              zero,cstaeq,hn,u2d,v2d,csratio)
        IF(debug > 0) WRITE(lu,*) 'END SUSPENSION_SANDFLOW'
        DO i=1,npoin
          cstaeq%R(i)=cstaeq%R(i)*ava(i)
        ENDDO
        CALL os('X=CY    ', x=fluer, y=cstaeq, c=xwc)
!
      ENDIF
!
!======================================================================!
!======================================================================!
!
      RETURN
      END
!
!#######################################################################
!