stoseg41.f

Go to the documentation of this file.

!                   *******************
                    SUBROUTINE stoseg41
!                   *******************
!
     &(ifabor,nelmax,ielm,ikle,nbor,
     & gloseg,maxseg,eltseg,oriseg,nelbor,nulone,nelmax2,
     & nelem2,nptfr2,npoin2,nplan,knolg,nseg2d,iklbor,nelebx,neleb)
!
!***********************************************************************
! BIEF   V7P0                                   19/03/2014
!***********************************************************************
!
!brief    BUILDS THE DATA STRUCTURE FOR EDGE-BASED STORAGE
!+                IN PRISMS.
!code
!+       LOCAL NUMBERING OF SEGMENTS CHOSEN HERE IN A PRISM
!+
!+       HORIZONTAL
!+
!+       01 : POINT 1 TO 2 (OR THE OPPOSITE DEPENDING OF ORISEG)
!+       02 : POINT 2 TO 3 (OR THE OPPOSITE DEPENDING OF ORISEG)
!+       03 : POINT 3 TO 1 (OR THE OPPOSITE DEPENDING OF ORISEG)
!+       04 : POINT 4 TO 5 (OR THE OPPOSITE DEPENDING OF ORISEG)
!+       05 : POINT 5 TO 6 (OR THE OPPOSITE DEPENDING OF ORISEG)
!+       06 : POINT 6 TO 4 (OR THE OPPOSITE DEPENDING OF ORISEG)
!+
!+       VERTICAL
!+
!+       07 : POINT 1 TO 4
!+       08 : POINT 2 TO 5
!+       09 : POINT 3 TO 6
!+
!+       CROSSED
!+
!+       10 : POINT 1 TO 5
!+       11 : POINT 2 TO 4
!+       12 : POINT 2 TO 6
!+       13 : POINT 3 TO 5
!+       14 : POINT 3 TO 4
!+       15 : POINT 1 TO 6
!
!history  JMH
!+        11/08/09
!+
!+   CROSSED AND VERTICAL SEGMENTS INVERTED IN THE NUMBERING.
!
!history  JMH
!+        16/10/09
!+
!+   NUMBERING OF CROSSED SEGMENTS CHANGED, TO FACILITATE
!
!history  J-M HERVOUET (LNHE)
!+        19/10/2009
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (EDF LAB, LNHE)
!+        19/03/2014
!+        V7P0
!+   Boundary segments have now their own numbering, independent of
!+   boundary points numbering.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ELTSEG         |<--| SEGMENTS OF EVERY TRIANGLE.
!| GLOSEG         |<--| GLOBAL NUMBERS OF POINTS OF SEGMENTS.
!| IELM           |-->| 11: TRIANGLES.
!|                |   | 21: QUADRILATERALS.
!| IFABOR         |-->| ELEMENTS BEHIND THE EDGES OF A TRIANGLE
!|                |   | IF NEGATIVE OR ZERO, THE EDGE IS A LIQUID
!|                |   | BOUNDARY
!| IKLBOR         |-->| CONNECTIVITY OF BOUNDARY SEGMENTS IN D
!| IKLE           |-->| CONNECTIVITY TABLE.
!| KNOLG          |-->| GLOBAL NUMBER OF A LOCAL POINT IN PARALLEL
!| MAXSEG         |<--| MAXIMUM NUMBER OF SEGMENTS
!| NBOR           |-->| GLOBAL NUMBERS OF BOUNDARY POINTS.
!| NELBOR         |-->| NUMBER OF ELEMENT CONTAINING SEGMENT K OF
!|                |   | THE BOUNDARY.
!| NELEB          |-->| NUMBER OF BOUNDARY ELEMENTS
!| NELEBX         |-->| MAXIMUM NUMBER OF BOUNDARY ELEMENTS
!| NELEM2         |-->| NUMBER OF ELEMENTS IN 2D
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS IN 3D
!| NELMAX2        |-->| MAXIMUM NUMBER OF ELEMENTS IN 2D
!| NPLAN          |-->| NUMBER OF PLANES IN THE 3D MESH OF PRISMS
!| NPOIN2         |-->| NUMBER OF POINTS IN 2D
!| NPTFR2         |-->| NUMBER OF BOUNDARY POINTS IN 2D
!| NULONE         |-->| LOCAL NUMBER OF BOUNDARY POINTS IN A BOUNDARY
!|                |   | ELEMENT.
!|                |   | HERE THE 3D NULONE IS PASSED THOUGH IT IS HERE
!|                |   | USED AS THE 2D ONE. HENCE BOTH MUST BEGIN BY
!|                |   | THE SAME BOUNDARY ELEMENTS OF THE LOWER PLANE.
!| ORISEG         |<--| ORIENTATION OF SEGMENTS OF EVERY TRIANGLE.
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_stoseg41 => stoseg41
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)    :: NELMAX,NELMAX2,MAXSEG,IELM
      INTEGER, INTENT(IN)    :: NELEM2,NPTFR2,NPOIN2,NPLAN,NSEG2D
      INTEGER, INTENT(IN)    :: NELEB,NELEBX
      INTEGER, INTENT(IN)    :: NBOR(nptfr2)
      INTEGER, INTENT(IN)    :: IFABOR(nelmax2,*),IKLE(nelmax,6)
      INTEGER, INTENT(IN)    :: NELBOR(nptfr2),NULONE(nptfr2)
      INTEGER, INTENT(IN)    :: IKLBOR(nelebx,2)
      INTEGER, INTENT(INOUT) :: GLOSEG(maxseg,2)
      INTEGER, INTENT(INOUT) :: ELTSEG(nelmax,15),ORISEG(nelmax,15)
      INTEGER, INTENT(IN)    :: KNOLG(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I1,I2,I3,IELEM,I,ONE,TWO
      INTEGER IPLAN,ISEG2D,ISEG3D,IELEM3D,NSEGH,NSEGV,NELEB2D
!
!-----------------------------------------------------------------------
!
      IF(ielm.NE.41) THEN
        WRITE(lu,501) ielm
501     FORMAT(1x,'STOSEG41 (BIEF) : UNEXPECTED ELEMENT: ',1i6)
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
!     BUILDS 2D SEGMENTS (THE FIRST IN THE NUMBERING)
!
!     NOTE:
!     IN PARALLEL MODE, THE NUMBER OF SEGMENTS IN THE CONTOUR LINE IS NOT NPTFR2
!     NSEG2D=(3*NELEM2+NPTFR2)/2
      nsegh=nseg2d*nplan
      nsegv=(nplan-1)*npoin2
      neleb2d=neleb/(nplan-1)
!
      CALL stoseg(ifabor,nelem2,nelmax,nelmax2,11,ikle,nbor,nptfr2,
     &            gloseg,maxseg,eltseg,oriseg,nseg2d,
     &            nelbor,nulone,knolg,iklbor,nelebx,neleb2d)
!
!-----------------------------------------------------------------------
!
!     COMPLETES HORIZONTAL SEGMENTS (1,2,3,4,5,6)
!
      DO iplan=2,nplan
      DO iseg2d=1,nseg2d
        iseg3d=iseg2d+(iplan-1)*nseg2d
        gloseg(iseg3d,1)=gloseg(iseg2d,1)+npoin2*(iplan-1)
        gloseg(iseg3d,2)=gloseg(iseg2d,2)+npoin2*(iplan-1)
      ENDDO
      ENDDO
!
!     VERTICAL SEGMENTS (7,8,9)
!
      DO iplan=1,nplan-1
      DO i=1,npoin2
        iseg3d=nsegh+npoin2*(iplan-1)+i
        gloseg(iseg3d,1)=npoin2*(iplan-1)+i
        gloseg(iseg3d,2)=npoin2*(iplan  )+i
      ENDDO
      ENDDO
!
!-----------------------------------------------------------------------
!
!     ARRAY ELTSEG GIVES GLOBAL NUMBERS OF SEGMENTS IN A PRISM
!     ARRAY ORISEG GIVES ORIENTATION OF SEGMENT
!
!     COMPLETES SEGMENTS 1,2,3
!
      IF(nplan.GT.2) THEN
      DO iplan=2,nplan-1
        DO ielem=1,nelem2
          ielem3d=ielem+(iplan-1)*nelem2
          eltseg(ielem3d,1)=eltseg(ielem,1)+nseg2d*(iplan-1)
          eltseg(ielem3d,2)=eltseg(ielem,2)+nseg2d*(iplan-1)
          eltseg(ielem3d,3)=eltseg(ielem,3)+nseg2d*(iplan-1)
          oriseg(ielem3d,1)=oriseg(ielem,1)
          oriseg(ielem3d,2)=oriseg(ielem,2)
          oriseg(ielem3d,3)=oriseg(ielem,3)
        ENDDO
      ENDDO
      ENDIF
!
!     SEGMENTS 4,5,6 (=SEGMENTS 1,2,3 + NSEG2D)
!
      DO iplan=1,nplan-1
        DO ielem=1,nelem2
          ielem3d=ielem+(iplan-1)*nelem2
          eltseg(ielem3d,4)=eltseg(ielem3d,1)+nseg2d
          eltseg(ielem3d,5)=eltseg(ielem3d,2)+nseg2d
          eltseg(ielem3d,6)=eltseg(ielem3d,3)+nseg2d
          oriseg(ielem3d,4)=oriseg(ielem,1)
          oriseg(ielem3d,5)=oriseg(ielem,2)
          oriseg(ielem3d,6)=oriseg(ielem,3)
        ENDDO
      ENDDO
!
!     SEGMENTS 7,8,9 (VERTICAL SEGMENTS)  SEE SECTION 3)
!
      DO iplan=1,nplan-1
        DO ielem=1,nelem2
          ielem3d=ielem+(iplan-1)*nelem2
          i1=ikle(ielem,1)
          i2=ikle(ielem,2)
          i3=ikle(ielem,3)
          eltseg(ielem3d,7)=nsegh+npoin2*(iplan-1)+i1
          eltseg(ielem3d,8)=nsegh+npoin2*(iplan-1)+i2
          eltseg(ielem3d,9)=nsegh+npoin2*(iplan-1)+i3
          oriseg(ielem3d,7)=1
          oriseg(ielem3d,8)=1
          oriseg(ielem3d,9)=1
        ENDDO
      ENDDO
!
!     SEGMENTS 10 TO 15 (CROSSED SEGMENTS)
!
!     THE PROBLEM IS TO FIND A GLOBAL NUMBERING OF CROSSED SEGMENTS
!     WHICH IS INDEPENDENT OF THE PRISM CONSIDERED, SO THAT WHEN
!     ASSEMBLING THE ISEG3D IS THE CORRECT ONE
!     HERE WE TAKE AS CROSSED SEGMENT 1 THE ONE THAT STARTS
!     FROM THE ORIGIN OF THE ORIENTED HORIZONTAL SEGMENT
!
!     FOR EVERY VERTICAL RECTANGLE IN A PRISM
!     WHEN THE HORIZONTAL SEGMENT HAS ORISEG = 1, THE CROSSED
!     SEGMENT NUMBER 1 IS THUS THE 10,12 OR 14
!     WHEN THE HORIZONTAL SEGMENT HAS ORISEG = 2, THE CROSSED
!     SEGMENT NUMBER 1 IS THUS THE 11,13 OR 15
!
!     IN THE GLOBAL NUMBERING OF SEGMENTS
!     THE ORISEG=1 SEGMENTS ARE PUT FIRST (NSEG2D PER LAYER)
!     THE ORISEG=2 SEGMENTS ARE PUT AFTER (NSEG2D PER LAYER)
!
      DO iplan=1,nplan-1
        DO ielem=1,nelem2
          ielem3d=ielem+(iplan-1)*nelem2
          DO i=1,3
            iseg2d=eltseg(ielem,i)
            iseg3d=nsegh+nsegv+nseg2d*2*(iplan-1)+iseg2d
            one=iseg3d
            two=iseg3d+nseg2d
            IF(oriseg(ielem,i).EQ.1) THEN
              eltseg(ielem3d,8+2*i)  =one
              eltseg(ielem3d,8+2*i+1)=two
            ELSE
              eltseg(ielem3d,8+2*i+1)=one
              eltseg(ielem3d,8+2*i)  =two
            ENDIF
!           ONE: FOLLOWS ISEG2D
            gloseg(one,1)=gloseg(iseg2d,1)+(iplan-1)*npoin2
            gloseg(one,2)=gloseg(iseg2d,2)+(iplan  )*npoin2
!           BACKWARDS WITH RESPECT TO ISEG2D
            gloseg(two,1)=gloseg(iseg2d,2)+(iplan-1)*npoin2
            gloseg(two,2)=gloseg(iseg2d,1)+(iplan  )*npoin2
          ENDDO
          oriseg(ielem3d,10)=1
          oriseg(ielem3d,11)=1
          oriseg(ielem3d,12)=1
          oriseg(ielem3d,13)=1
          oriseg(ielem3d,14)=1
          oriseg(ielem3d,15)=1
        ENDDO
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END