spejon.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE spejon
!                   *****************
!
     &( spec  , nf    , al    , fp     , gamma , sigmaa, sigmab,
     &  fpmin )
!
!***********************************************************************
! TOMAWAC   V6P1                                   28/06/2011
!***********************************************************************
!
!brief    COMPUTES A JONSWAP FREQUENCY SPECTRUM BASED
!+                ON A SERIES OF FREQUENCIES.
!
!history  M. BENOIT (EDF/DER/LNH)
!+        15/11/95
!+        V1P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  G.MATTAROLO (EDF - LNHE)
!+        28/06/2011
!+        V6P1
!+   Translation of French names of the variables in argument
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| AL             |-->| PHILLIPS CONSTANT (ALPHA)
!| FP             |-->| JONSWAP SPECTRUM PEAK FREQUENCY
!| FPMIN          |-->| MINIMUM PEAK FREQUENCY VALUE
!| FREQ           |-->| DISCRETIZED FREQUENCIES
!| GAMMA          |-->| JONSWAP SPECTRUM PEAK FACTOR
!| GRAVIT         |-->| GRAVITY ACCELERATION
!| NF             |-->| NUMBER OF FREQUENCIES
!| SIGMAA         |-->| VALUE OF SIGMA FOR JONSWAP SPECTRUM (F<FP)
!| SIGMAB         |-->| VALUE OF SIGMA FOR JONSWAP SPECTRUM (F>FP)
!| SPEC           |<--| JONSWAP VARIANCE DENSITY FREQUENCY SPECTRUM
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_tomawac, ONLY : gravit, deupi, freq, e2fmin
      USE interface_tomawac, ex_spejon => spejon
      IMPLICIT NONE
!
!.....VARIABLES IN ARGUMENT
!     """"""""""""""""""""
      INTEGER, INTENT(IN)    :: NF
      DOUBLE PRECISION, INTENT(IN)    :: SIGMAA, SIGMAB, GAMMA, FPMIN
      DOUBLE PRECISION, INTENT(IN)    :: FP    , AL
      DOUBLE PRECISION, INTENT(INOUT) :: SPEC(nf)
!
!.....LOCAL VARIABLES
!     """""""""""""""""
      INTEGER  JF
      DOUBLE PRECISION COEF  , ARG1   , ARG2  , ARG3  , SIG   , FF
!
!
      IF(fp.GT.fpmin) THEN
        coef=al*gravit**2/deupi**4
        DO jf=1,nf
          ff=freq(jf)
          IF(ff.LT.fp) THEN
            sig=sigmaa
          ELSE
            sig=sigmab
          ENDIF
          arg1=0.5d0*((ff-fp)/(sig*fp))**2
          IF (arg1.LT.99.d0) THEN
            arg1=gamma**exp(-arg1)
          ELSE
            arg1=1.d0
          ENDIF
          arg2=1.25d0*(fp/ff)**4
          IF (arg2.LT.99.d0) THEN
            arg2=exp(-arg2)
          ELSE
            arg2=0.d0
          ENDIF
          arg3=coef/ff**5
          spec(jf)=arg1*arg2*arg3
          IF (spec(jf).LT.e2fmin) spec(jf)=0.d0
        ENDDO ! JF
      ELSE
        DO jf=1,nf
          spec(jf)=0.d0
        ENDDO ! JF
      ENDIF
!
      RETURN
      END