slop10.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE slop10
!                   *****************
!
     &(coef,xel,yel,z,ikle,nelem,nelmax)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    COMPUTES THE COEFFICIENT 1 / COS(ALFA)
!+                WHERE ALFA IS THE SLOPE OF A TRIANGULAR ELEMENT.
!+
!+            THIS COEFFICIENT IS USED IN THE BOTTOM FRICTION
!+                TERM.
!
!warning  THE JACOBIAN MUST BE POSITIVE
!
!history  J-M HERVOUET (LNH)
!+        27/01/95
!+        V5P1
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| COEF           |<--| RESULT
!| IKLE           |-->| CONNECTIVITY TABLE.
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| XEL            |-->| ABSCISSAE OF POINTS IN THE MESH, PER ELEMENT
!| YEL            |-->| ORDINATES OF POINTS IN THE MESH, PER ELEMENT
!| Z              |-->| BOTTOM ELEVATIONS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NELEM,NELMAX
      INTEGER, INTENT(IN) :: IKLE(nelmax,*)
!
      DOUBLE PRECISION, INTENT(INOUT) :: COEF(nelem)
      DOUBLE PRECISION, INTENT(IN) :: XEL(nelmax,*),YEL(nelmax,*),Z(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IELEM
      DOUBLE PRECISION X2,X3,Y2,Y3,Z2,Z3,A,B,C
!
      INTRINSIC sqrt
!
!-----------------------------------------------------------------------
!
      DO ielem = 1 , nelem
!
        x2 = xel(ielem,2)
        x3 = xel(ielem,3)
!
        y2 = yel(ielem,2)
        y3 = yel(ielem,3)
!
        z2 = z(ikle(ielem,2)) -  z(ikle(ielem,1))
        z3 = z(ikle(ielem,3)) -  z(ikle(ielem,1))
!
        a = (x2*y3-x3*y2)**2
        b = (y2*z3-z2*y3)**2
        c = (x3*z2-z3*x2)**2
!
        coef(ielem) = sqrt( (a+b+c)/a )
!
      ENDDO ! IELEM
!
!-----------------------------------------------------------------------
!
      RETURN
      END