share_3d_fluxes.f

Go to the documentation of this file.

!                   **************************
                    SUBROUTINE share_3d_fluxes
!                   **************************
!
     &(flux,nplan,mesh2,mesh3,opt)
!
!***********************************************************************
! BIEF   V7P1
!***********************************************************************
!
!brief    Shares assembled fluxes between sub-domains.
!+        Only one sub-domain will receive the whole flux to be treated.
!
!warning  MUST NOT BE CALLED WHEN NCSIZE = 0
!
!history  J-M HERVOUET (LNHE)
!+        14/04/2010
!+        V6P0
!+   First version
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (EDF LAB, LNHE)
!+        12/06/2015
!+        V7P1
!+   The fluxes are no longer shared but given to a single processor.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FLUX           |<->| FLUXES TO BE SHARED
!| MESH2          |-->| 2D MESH
!| MESH3          |-->| 3D MESH
!| NPLAN          |-->| NUMBER OF PLANES
!| OPT            |-->| 1 : HORIZONTAL AND VERTICAL SEGMENTS ONLY
!|                |   | 2 : ALL SEGMENTS
!| XMUL           |-->| MULTIPLICATING FACTOR
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_share_3d_fluxes => share_3d_fluxes
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: NPLAN,OPT
!
      TYPE(bief_mesh) , INTENT(INOUT) :: MESH2,MESH3
!
      DOUBLE PRECISION, INTENT(INOUT) :: FLUX(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER IPLAN,NSEG,NSEGH,NSEGV,NPOIN2,I,I3D,I2D,IAD
!
!-----------------------------------------------------------------------
!
      nseg=mesh2%NSEG
      npoin2=mesh2%NPOIN
      nsegh=nseg*nplan
      nsegv=npoin2*(nplan-1)
!
!     HORIZONTAL FLUXES
!
      DO iplan=1,nplan
        CALL mult_interface_seg(flux(1+(iplan-1)*nseg:iplan*nseg),
     &                          mesh2%NH_COM_SEG%I,
     &                          mesh2%NH_COM_SEG%DIM1,
     &                          mesh2%NB_NEIGHB_SEG,
     &                          mesh2%NB_NEIGHB_PT_SEG%I,
     &                          mesh2%LIST_SEND_SEG%I,mesh2%NSEG)
      ENDDO
!
!     VERTICAL FLUXES (SAME NUMBERING AS POINTS, SO FAC%R(I))
!
      iad=1
      DO i=1,nptir
!       I2D=NACHB(1,I) WITH NACHB OF SIZE NACHB(NBMAXNSHARE,NPTIR)
!       IAD IS (I-1)*NBMAXNSHARE+1
        i2d=mesh2%NACHB%I(iad)
        DO iplan=1,nplan-1
          i3d=(iplan-1)*npoin2+i2d
          flux(nsegh+i3d)=flux(nsegh+i3d)*mesh3%IFAC%I(i3d)
        ENDDO
        iad=iad+nbmaxnshare
      ENDDO
!
!     CROSSED FLUXES (SEE STOSEG41 FOR STORAGE). THERE ARE 2*NESG
!     PER LAYER AND NPLAN-1 LAYER. HERE ORISEG=1 AND ORISEG=2 SEGMENTS
!     ARE MULTIPLIED BY THE SAME NUMBER, SO GIVEN HOW THE NUMBERING
!     IS BUILT IT IS AS IF WE HAVE 2*NPLAN-2 LAYERS OF HORIZONTAL SEGMENTS
!
      IF(opt.EQ.2) THEN
        DO iplan=1,2*(nplan-1)
          CALL mult_interface_seg(flux(1+nsegh+nsegv+(iplan-1)*nseg:
     &                                   nsegh+nsegv+ iplan   *nseg),
     &                            mesh2%NH_COM_SEG%I,
     &                            mesh2%NH_COM_SEG%DIM1,
     &                            mesh2%NB_NEIGHB_SEG,
     &                            mesh2%NB_NEIGHB_PT_SEG%I,
     &                            mesh2%LIST_SEND_SEG%I,mesh2%NSEG)
        ENDDO
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END