set_mesh.f

Go to the documentation of this file.

!                   *******************
                    SUBROUTINE set_mesh
!                   *******************
!
     &(fformat,file_id,mesh_dim,typelm,ndp,nptfr,
     & nptir,nelem,npoin,ikle,ipobo,
     & knolg,x,y,nplan,date,time,x_orig,y_orig,ierr,z,in_place)
!
!***********************************************************************
! HERMES   V7P0                                               01/05/2014
!***********************************************************************
!
!brief    Writes the mesh geometry in the file
!
!history  Y AUDOUIN (LNHE)
!+        24/03/2014
!+        V7P0
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FFORMAT        |-->| FORMAT OF THE FILE
!| FILE_ID        |-->| FILE DESCRIPTOR
!| MESH_DIM       |-->| DIMENSION OF THE MESH
!| TYPELM         |-->| TYPE OF THE MESH ELEMENTS
!| NDP            |-->| NUMBER OF POINTS PER ELEMENT
!| NPTFR          |-->| NUMBER OF BOUNDARY POINT
!| NPTIR          |-->| NUMBER OF INTERFACE POINT
!| NELEM          |-->| NUMBER OF ELEMENT IN THE MESH
!| NPOIN          |-->| NUMBER OF POINTS IN THE MESH
!| IKLE           |<->| CONNECTIVITY ARRAY FOR THE MAIN ELEMENT
!| IPOBO          |-->| IS A BOUNDARY POINT ? ARRAY
!| KNOLG          |-->| LOCAL TO GLOBAL NUMBERING ARRAY
!| X              |-->| X COORDINATES OF THE MESH POINTS
!| Y              |-->| Y COORDINATES OF THE MESH POINTS
!| NPLAN          |-->| NUMBER OF PLANES
!| DATE           |-->| DATE OF THE CREATION OF THE MESH
!| TIME           |-->| TIME OF THE CREATION OF THE MESH
!| X_ORIG         |-->| Off set of the X coordinates
!| Y_ORIG         |-->| Off set of the Y coordinates
!| IERR           |<--| 0 IF NO ERROR DURING THE EXECUTION
!| Z  (OPTIONAL)  |-->| Z COORDINATES OF THE MESH POINTS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE utils_serafin
      USE utils_med
      USE utils_vtk
      USE utils_cgns
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      CHARACTER(LEN=8), INTENT(IN)  :: FFORMAT
      INTEGER,          INTENT(IN)  :: FILE_ID,NPLAN
      INTEGER,          INTENT(IN)  :: DATE(3)
      INTEGER,          INTENT(IN)  :: TIME(3)
      INTEGER,          INTENT(IN)  :: MESH_DIM
      INTEGER,          INTENT(IN)  :: TYPELM
      INTEGER,          INTENT(IN)  :: NDP
      INTEGER,          INTENT(IN)  :: NPTFR
      INTEGER,          INTENT(IN)  :: NPTIR
      INTEGER,          INTENT(IN)  :: NELEM
      INTEGER,          INTENT(IN)  :: NPOIN
      INTEGER,          INTENT(IN)  :: X_ORIG
      INTEGER,          INTENT(IN)  :: Y_ORIG
      INTEGER,          INTENT(INOUT)  :: IKLE(nelem*ndp)
      INTEGER,          INTENT(IN)  :: IPOBO(*)
      INTEGER,          INTENT(IN)  :: KNOLG(*)
      DOUBLE PRECISION, INTENT(IN)  :: X(npoin),Y(npoin)
      INTEGER,          INTENT(OUT) :: IERR
      DOUBLE PRECISION, INTENT(IN), OPTIONAL :: Z(*)
      LOGICAL,          INTENT(IN), OPTIONAL :: IN_PLACE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      DOUBLE PRECISION, ALLOCATABLE :: COORD(:)
      INTEGER :: I
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      SELECT CASE (fformat(1:7))
        CASE ('SERAFIN')
          CALL set_mesh_srf(fformat,file_id,mesh_dim,typelm,ndp,nptfr,
     &                      nptir,nelem,npoin,ikle,ipobo,
     &                      knolg,x,y,nplan,date,time,x_orig,y_orig,
     &                      ierr,
     &                      in_place=in_place)
        CASE ('MED    ')
!         STORE COORDINATES
          ALLOCATE(coord(npoin*mesh_dim),stat=ierr)
          IF(ierr.NE.0) THEN
            error_message = 'ERROR IN ALLOCATING SET_MESH:COORD'
            RETURN
          ENDIF
          DO i=1,npoin
            coord(i) = x(i)
            coord(i+npoin) = y(i)
          ENDDO
          IF (PRESENT(z).AND.(mesh_dim.EQ.3)) THEN
            DO i=1,npoin
              coord(i+2*npoin) = z(i)
            ENDDO
          ENDIF
!
          CALL set_mesh_med(file_id,mesh_dim,mesh_dim,typelm,ndp,
     &      nptir,nelem,npoin,ikle,knolg,coord,nplan,
     &      date,time,x_orig,y_orig,ierr)
          DEALLOCATE(coord)
        CASE ('VTK    ')
          CALL set_mesh_vtk(file_id,mesh_dim,typelm,ndp,
     &      nelem,npoin,ikle,x,y,ierr)
        CASE ('CGNS   ')
          IF (PRESENT(z).AND.(mesh_dim.EQ.3)) THEN
            CALL set_mesh_cgns(file_id,mesh_dim,typelm,ndp,nptfr,
     &        nptir,nelem,npoin,ikle,ipobo,knolg,x,y,nplan,ierr,z)
          ELSE
            CALL set_mesh_cgns(file_id,mesh_dim,typelm,ndp,nptfr,
     &        nptir,nelem,npoin,ikle,ipobo,knolg,x,y,nplan,ierr)
          ENDIF
        CASE DEFAULT
          ierr = hermes_unknown_file_format_err
          WRITE(error_message,*) 'SET_MESH: BAD FILE FORMAT: ',fformat
          RETURN
      END SELECT
!
!-----------------------------------------------------------------------
!
      RETURN
      END