sd_strtri.f

Go to the documentation of this file.

!                   ********************
                    SUBROUTINE sd_strtri
!                   ********************
!
     &(is,n,ind)
!
!***********************************************************************
! BIEF   V6P0                                   21/08/2010
!***********************************************************************
!
!brief    SORTS IN ASCENDING ORDER THE INTEGER ARRAY 'IS'.
!+                OUTPUT :  IS(IND(I+1) >= IS(IND(I).
!
!note     IMPORTANT: INSPIRED FROM N3S 3.3  22/04/92  B.THOMAS
!
!history  E. RAZAFINDRAKOTO (LNH)
!+        20/11/06
!+        V5P7
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| IND            |<--| PERMUTATION ARRAY FOR ASCENDING ORDER IS
!| IS             |-->| INTEGER ARRAY TO SORT IN ASCENDING ORDER
!| N              |-->| LENGTH OF IS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_sd_strtri => sd_strtri
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)    :: N
      INTEGER, INTENT(IN)    :: IS(n)
      INTEGER, INTENT(INOUT) :: IND(n)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,I1,K
!
!-----------------------------------------------------------------------
!
      ind(1) = 1
!
      DO i = 2 , n
!
!--->   IS(1:I-1) IS SORTED
!
        i1 = i-1
        DO k = i1 , 1 , -1
!
!--->     FOR L > K+1  IS(IND(L)) > IS(I)
!
          IF(is(ind(k)).GT.is(i)) THEN
            ind(k+1) = ind(k)
          ELSE
            EXIT
          ENDIF
!
        ENDDO ! K
!
!--->   ASSERTION : IS(IND(K))
!
        ind(k+1)=i
!
      ENDDO ! I
!
!-----------------------------------------------------------------------
!
      RETURN
      END