sd_strssd.f

Go to the documentation of this file.

!                   ********************
                    SUBROUTINE sd_strssd
!                   ********************
!
     &(npblk,nsegblk,gloseg1,gloseg2,in,ip,isegip,iw)
!
!***********************************************************************
! BIEF   V6P2                                   21/08/2010
!***********************************************************************
!
!brief    BUILDS COMPACT STORAGE
!+               (IN,IP) = (XADJ, ADJNCY)OF EXTRADIAGONAL TERMS
!+                VIA SEGMENT STORAGE.
!
!warning  NSEG AND IW ARE THE SAME ARRAY IN THE MEMORY
!
!history  E.RAZAFINDRAKOTO (LNH)
!+        18/02/08
!+        V5P9
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  J-M HERVOUET (LNHE)
!+        08/06/2012
!+        V6P2
!+   Dimensions changed in declarations and allocation.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| GLOSEG1        |-->| FIRST POINT OF SEGMENTS
!| GLOSEG2        |-->| SECOND POINT OF SEGMENTS
!| IN             |<--| (IN, IP) COMPACT STORAGE OF EXTRADIAGONAL TERMS
!| IP             |<--| (IN, IP) COMPACT STORAGE OF EXTRADIAGONAL TERMS
!| ISEGIP         |<--| INVERSE TABLE OF CONNECTIVITY: POINT-->SEGMENT
!| IW             |<--| NUMBER OF NEIGHBOURS OF POINTS
!| NPBLK          |-->| NUMBER OF POINTS
!| NSEGBLK        |-->| NUMBER OF SEGMENTS
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief,ex_sd_strssd => sd_strssd
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)    :: NSEGBLK,NPBLK
      INTEGER, INTENT(IN)    :: GLOSEG1(nsegblk),GLOSEG2(nsegblk)
      INTEGER, INTENT(INOUT) :: IN(npblk+1),IP(nsegblk*2)
      INTEGER, INTENT(INOUT) :: ISEGIP(nsegblk*2)
      INTEGER, INTENT(INOUT) :: IW(npblk)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,J1,J2,ISEG
!
!  -----------------------
!
!---> DEGREE OF A POINT: NUMBER OF NEIGHBOURS
!
      DO i=1,npblk
        iw(i)=0
      ENDDO
!
!     IW : NUMBER OF NEIGHBOURS FOR EACH POINT
!
      DO iseg=1,nsegblk
        j1 = gloseg1(iseg)
        j2 = gloseg2(iseg)
        iw(j1) = iw(j1) + 1
        iw(j2) = iw(j2) + 1
      ENDDO
!
!---> COMPACT STORAGE WITHOUT THE DIAGONAL: (XADJ,ADJNCY) = (IN,IP)
!
!     COEFFICIENTS FOR POINT I: FROM IN(I) TO IN(I+1)-1
!
      in(1)=1
      DO i=1,npblk
        in(i+1)=in(i)+iw(i)
      ENDDO
!
!     IW IS NO LONGER THE NUMBER OF NEIGHBOURS
!
      DO i=1,npblk
        iw(i)=in(i)
      ENDDO
!
      DO iseg=1,nsegblk
        j1 = gloseg1(iseg)
        j2 = gloseg2(iseg)
!
!-->    TABLE OF CONNECTIVITY: SEGMENT ---> POINT
!       WILL SAY TO WHAT POINT A COEFFICIENT REFERS TO
!
        ip(iw(j1))=j2
        ip(iw(j2))=j1
!
!-->    INVERSE TABLE OF CONNECTIVITY: POINT ---> SEGMENT
!       WILL SAY TO WHAT SEGMENT A COEFFICIENT REFERS TO
!
!       NOTATION FOR TRIANGULAR SUPERIOR COEFF.
        isegip(iw(j1))=-iseg
!       NOTATION FOR TRIANGULAR INFERIOR COEFF.
        isegip(iw(j2))= iseg
!
        iw(j1) = iw(j1) + 1
        iw(j2) = iw(j2) + 1
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END