sd_strsg4.f

Go to the documentation of this file.

!                   ********************
                    SUBROUTINE sd_strsg4
!                   ********************
!
     &(npoin,nseg,glosegb,nsegblk,gloseg4)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    TRANSFORMS THE SEGMENTS OF A 4-MATRIX SYSTEM INTO
!          THE SEGMENTS OF A SINGLE BLOCK.
!
!history  E. RAZAFINDRAKOTO (LNH)
!+        20/11/06
!+        V5P7
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| GLOSEG4        |<--| FIRST AND SECOND POINT OF SEGMENTS IN BLOCK
!| GLOSEGB        |-->| FIRST AND SECOND POINT OF SEGMENTS
!| NPOIN          |-->| NUMBER OF POINTS
!| NSEG           |-->| NUMBER OF SEGMENTS
!| NSEGBLK        |-->| NUMBER OF SEGMENTS IN THE FINAL BLOCK
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_sd_strsg4 => sd_strsg4
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)    :: NSEGBLK,NSEG,NPOIN
      INTEGER, INTENT(IN)    :: GLOSEGB(nseg,2)
      INTEGER, INTENT(INOUT) :: GLOSEG4(2*nsegblk)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER I,ISEG,JSEG
!
!----------------------------------------------
!     INFO :     NSEGBLK=NSEG*4 +   NPOIN !!!!
!----------------------------------------------
!
!     MATRIX ASSEMBLES TOTAL BLOCKS:
!
!----------------------------------------------
!
      jseg=0
!
!     BLOCK 1 (EXTRA-DIAGONAL TERMS)
!     ------------------------------
!
      DO iseg=1,nseg
        jseg=jseg+1
        gloseg4(jseg)= glosegb(iseg,1)
        gloseg4(jseg+nsegblk)= glosegb(iseg,2)
      ENDDO
!
!     BLOCKS 2 AND 3 (PREVIOUSLY DIAGONAL TERMS)
!     ------------------------------------------
!
      DO i=1,npoin
        jseg=jseg+1
        gloseg4(jseg)= i
        gloseg4(jseg+nsegblk)= i+npoin
      ENDDO
!
!     BLOCKS 2 AND 3 (EXTRA-DIAGONAL TERMS)
!     -------------------------------------
!
      DO iseg=1,nseg
        jseg=jseg+1
        gloseg4(jseg)= glosegb(iseg,1)
        gloseg4(jseg+nsegblk)= glosegb(iseg,2)+ npoin
        jseg=jseg+1
        gloseg4(jseg)= glosegb(iseg,2)
        gloseg4(jseg+nsegblk)= glosegb(iseg,1)+ npoin
      ENDDO
!
!     BLOCK 4 (EXTRA-DIAGONAL TERMS)
!     ------------------------------
!
      DO iseg=1,nseg
        jseg=jseg+1
        gloseg4(jseg)         = glosegb(iseg,1)+npoin
        gloseg4(jseg+nsegblk) = glosegb(iseg,2)+npoin
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END