sd_nnsc.f

Go to the documentation of this file.

!                   ******************
                    SUBROUTINE sd_nnsc
!                   ******************
!
     &(n,r,c,il,jl,ijl,l,d,iu,ju,iju,u,z,b,tmp)
!
!***********************************************************************
! BIEF   V6P3                                   21/08/2010
!***********************************************************************
!
!brief NUMERICAL SOLUTION OF SPARSE NONSYMMETRIC SYSTEM OF LINEAR
!+      EQUATIONS GIVEN LDU-FACTORIZATION (COMPRESSED POINTER STORAGE)
!+
!+
!+       INPUT VARIABLES..  N, R, C, IL, JL, IJL, L, D, IU, JU, IJU, U, B
!+       OUTPUT VARIABLES.. Z
!+
!+       PARAMETERS USED INTERNALLY..
!+ FIA   \ TMP   - TEMPORARY VECTOR WHICH GETS RESULT OF SOLVING  LY = B.
!+       \           SIZE = N.
!+
!note     IMPORTANT : INSPIRED FROM PACKAGE CMLIB3 - YALE UNIVERSITE-YSMP
!
!         DON'T HESITATE TO CHANGE IN/OUTPUT VARIABLES COMMENTS
!         FOR CLARITY
!
!history  C. PEYRARD (LNHE)
!+        30/06/13
!+        V6P3
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| B              |-->| RIGHT-HAND SIDE B ;
!| C              |-->| ORDERING OF THE COLUMNS OF MATRIX
!| D              |-->| DIAGONAL FACTORIZED OF MATRIX
!| IL, JL         |-->| STRUCTURE OF LOWER FACTORISED TRIANGULAR MATRIX
!| IU, JU         |-->| STRUCTURE OF UPPER FACTORISED TRIANGULAR MATRIX
!| IJU,IJL        |-->| USED TO COMPRESS STORAGE OF JU and JL
!| L              |-->| LOWER FACTORIZED TRIANGULAR MATRIX
!| N              |-->| RANK OF MATRIX
!| R              |-->| ORDERING OF THE ROWS OF MATRIX
!| TMP            |-->| REAL ONE-DIMENSIONAL WORK ARRAY
!| U              |-->| UPPER FACTORIZED TRIANGULAR MATRIX
!| Z              |<--| SOLUTION X
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER R(*), C(*), IL(*), JL(*), IJL(*), IU(*), JU(*), IJU(*),N
      DOUBLE PRECISION  L(*), D(*), U(*), B(*), Z(*), TMP(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER K,JMIN,JMAX,ML,J,MU,I
      DOUBLE PRECISION TMPK,SOMME
!
!-----------------------------------------------------------------------
!
!     SET TMP TO REORDERED B
!
      DO k=1,n
        tmp(k) = b(r(k))
      ENDDO
!
!     SOLVE  LY = B  BY FORWARD SUBSTITUTION
!
      DO k=1,n
        jmin = il(k)
        jmax = il(k+1) - 1
        tmpk = -d(k) * tmp(k)
        tmp(k) = -tmpk
        IF (jmin .GT. jmax) cycle
        ml = ijl(k) - jmin
        DO j=jmin,jmax
          tmp(jl(ml+j)) = tmp(jl(ml+j)) + tmpk * l(j)
        ENDDO
      ENDDO ! K
!
!     SOLVE  UX = Y  BY BACK SUBSTITUTION
!
      k = n
      DO i=1,n
        somme = -tmp(k)
        jmin = iu(k)
        jmax = iu(k+1) - 1
        IF (jmin .GT. jmax) GO TO 5
        mu = iju(k) - jmin
        DO j=jmin,jmax
          somme = somme + u(j) * tmp(ju(mu+j))
        ENDDO
   5    tmp(k) = -somme
        z(c(k)) = -somme
        k = k - 1
      ENDDO
!
!-----------------------------------------------------------------------
!
      RETURN
      END