sd_mdm.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE sd_mdm
!                   *****************
!
     &(vk,tail,v,l,last,next,mark)
!
!***********************************************************************
! BIEF   V6P1                                   21/07/2011
!***********************************************************************
!
!brief    FORMS ELEMENT FROM UNELIMINATED NEIGHBOURS OF VK.
!
!note     IMPORTANT : INSPIRED FROM PACKAGE CMLIB3 - YALE UNIVERSITE-YSMP
!
!history  E. RAZAFINDRAKOTO (LNH)
!+        20/11/06
!+        V5P7
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| L              |---| INTEGER ONE-DIMENSIONAL WORK ARRAY;DIMENSION=MAX
!| LAST           |-->| INTEGER ONE-DIMENSIONAL ARRAY USED TO RETURN THE
!|                |   | PERMUTATION OF THE ROWS AND COLUMNS OF M
!|                |   | CORRESPONDING TO THE MINIMUM DEGREE ORDERING;
!|                |   | DIMENSION = N
!| MARK           |---| INTEGER ONE-DIMENSIONAL WORK ARRAY;DIMENSION=N
!| NEXT           |-->| INVERSE OF THE PERMUTATION RETURNED IN LAST
!|                |   | DIMENSION = N
!| TAIL           |<--| UNELIMINATED NEIGHBOURS OF VERTEX VK
!| V              |-->| INTEGER ONE-DIMENSIONAL WORK ARRAY;DIMENSION=MAX
!| VK             |-->| VERTEX NUMBER
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_sd_mdm => sd_mdm
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)    :: VK,LAST(*),NEXT(*),V(*)
      INTEGER, INTENT(INOUT) :: TAIL,L(*),MARK(*)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER TAG,S,LS,VS,ES,B,LB,VB,BLP,BLPMAX
      equivalence(vs,es)
!
!----INITIALISES TAG AND LIST OF UNELIMINATED NEIGHBOURS
!
      tag = mark(vk)
      tail = vk
!
!----FOR EACH VERTEX/ELEMENT VS/ES IN ELEMENT LIST OF VK
!
      ls = l(vk)
1     s = ls
      IF(s.EQ.0)  GO TO 5
      ls = l(s)
      vs = v(s)
      IF(next(vs).LT.0)  GO TO 2
!
!------IF VS IS UNELIMINATED VERTEX, THEN TAGS AND APPENDS TO LIST OF
!------UNELIMINATED NEIGHBOURS
!
      mark(vs) = tag
      l(tail) = s
      tail = s
      GO TO 4
!
!------IF ES IS ACTIVE ELEMENT, THEN ...
!--------FOR EACH VERTEX VB IN BOUNDARY LIST OF ELEMENT ES
!
2     lb = l(es)
      blpmax = last(es)
      DO blp=1,blpmax
        b = lb
        lb = l(b)
        vb = v(b)
!
!----------IF VB IS UNTAGGED VERTEX, THEN TAGS AND APPENDS TO LIST OF
!----------UNELIMINATED NEIGHBOURS
!
        IF(mark(vb).GE.tag) cycle
        mark(vb) = tag
        l(tail) = b
        tail = b
      ENDDO ! BLP
!
!--------MARKS ES INACTIVE
!
      mark(es) = tag
!
4     GO TO 1
!
!----TERMINATES LIST OF UNELIMINATED NEIGHBOURS
!
5     l(tail) = 0
!
!-----------------------------------------------------------------------
!
      RETURN
      END