sd_mdi.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE sd_mdi
!                   *****************
!
     &(n,ia,ja,maximum,v,l,head,last,next,mark,tag,flag)
!
!***********************************************************************
! BIEF   V6P2                                   21/08/2010
!***********************************************************************
!
!brief    INITIALISES.
!
!note     IMPORTANT: INSPIRED FROM PACKAGE CMLIB3 - YALE UNIVERSITE-YSMP
!
!history  E. RAZAFINDRAKOTO (LNHE)
!+        20/11/06
!+        V5P7
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  U.H.MErkel
!+        2012
!+        V6P2
!+   Changed MAX to MAXIMUM for NAG Compiler
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| FLAG           |<--| FLAG - INTEGER ERROR FLAG;  VALUES AND THEIR
!|                |   | MEANINGS ARE : 0      NO ERRORS DETECTED
!|                |   |         9*N + VI  INSUFFICIENT STORAGE IN MDI
!| HEAD           |<--| INTEGER ONE-DIMENSIONAL WORK ARRAY;DIMENSION=N
!| IA, JA         |-->| COMPACT STORAGE STRUCTURE OF MATRIX
!| L              |---| INTEGER ONE-DIMENSIONAL WORK ARRAY;DIMENSION=MAX
!| LAST           |---| INTEGER ONE-DIMENSIONAL ARRAY USED TO RETURN THE
!|                |   | PERMUTATION OF THE ROWS AND COLUMNS OF M
!|                |   | CORRESPONDING TO THE MINIMUM DEGREE ORDERING;
!|                |   | DIMENSION = N
!| MARK           |---| INTEGER ONE-DIMENSIONAL WORK ARRAY;DIMENSION=N
!| MAXIMUM        |-->| DECLARED DIMENSION OF THE ONE-DIMENSIONAL ARRAYS
!|                |   | V AND L;
!| N              |-->| RANK OF MATRIX
!| NEXT           |<--| INVERSE OF THE PERMUTATION RETURNED IN LAST
!|                |   | DIMENSION = N
!| TAG            |-->| SEE DEFINITION IN INTERNAL PARAMATERS OF SD_MD.f
!| V              |---| INTEGER ONE-DIMENSIONAL WORK ARRAY;DIMENSION=MAX
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_sd_mdi => sd_mdi
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN)    :: N,MAXIMUM,IA(*),JA(*)
      INTEGER, INTENT(INOUT) :: V(*),L(*),HEAD(*),LAST(*)
      INTEGER, INTENT(INOUT) :: NEXT(*),MARK(*),TAG,FLAG
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER SFS,VI,DVI,VJ,JMIN,JMAX,J
!
!----INITIALISES DEGREES, ELEMENT LISTS, AND DEGREE LISTS
!
      DO vi=1,n
        mark(vi) = 1
        l(vi) = 0
        head(vi) = 0
      ENDDO ! VI
      sfs = n+1
!
!----CREATES NONZERO STRUCTURE
!----FOR EACH NONZERO ENTRY A(VI,VJ) IN STRICT UPPER TRIANGLE
!
      DO vi=1,n
        jmin = ia(vi)
        jmax = ia(vi+1) - 1
        IF(jmin.GT.jmax)  cycle
        DO j=jmin,jmax
          vj = ja(j)
          IF(vi.GE.vj) cycle
          IF(sfs.GE.maximum) GO TO 101
!
!------ENTERS VJ IN ELEMENT LIST FOR VI
!
          mark(vi) = mark(vi) + 1
          v(sfs) = vj
          l(sfs) = l(vi)
          l(vi) = sfs
          sfs = sfs+1
!
!------ENTERS VI IN ELEMENT LIST FOR VJ
!
          mark(vj) = mark(vj) + 1
          v(sfs) = vi
          l(sfs) = l(vj)
          l(vj) = sfs
          sfs = sfs+1
        ENDDO ! J
      ENDDO ! VI
!
!----CREATES DEGREE LISTS AND INITIALISES MARK VECTOR
!
      DO vi=1,n
        dvi = mark(vi)
        next(vi) = head(dvi)
        head(dvi) = vi
        last(vi) = -dvi
        IF(next(vi).GT.0)  last(next(vi)) = vi
        mark(vi) = tag
      ENDDO ! VI
!
      RETURN
!
! ** ERROR -- INSUFFICIENT STORAGE
!
101   flag = 9*n + vi
!
!-----------------------------------------------------------------------
!
      RETURN
      END