satur_o2.f

Go to the documentation of this file.

!                   *******************
                    SUBROUTINE satur_o2
!                   *******************
!
     &(sato2,formcs,wattemp,eps)
!
!***********************************************************************
! TELEMAC2D   V7P1
!***********************************************************************
!
!brief    COMPUTES THE CONCENTRATION OF O2 SATURATION OF WATER
!
!
!history  R. ATA (LNHE)
!+        02/09/2015
!+        V7P1
!+    First version.
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| EPS            |-->| TO AVOID DIVISION BY 0
!| FORMCS         |-->| WHICH FORMULAE FOR SATUR_O2
!| SATO2          |<--| CONCENTRATION OF O2 SATURATION OF WATER
!| WATTEMP        |-->| TEMPERATURE OF WATER
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_special
      USE interface_waqtel, ex_satur_o2 => satur_o2
!
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER         , INTENT(IN)    :: FORMCS
      DOUBLE PRECISION, INTENT(IN)    :: WATTEMP,EPS
      DOUBLE PRECISION, INTENT(INOUT) :: SATO2
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTRINSIC abs
!
!-----------------------------------------------------------------------
!
      IF(formcs.NE.0) THEN
        IF(formcs.EQ.1) THEN
          sato2 = 14.652d0 - 0.41022d0  * wattemp
     &                     + 0.007991d0 * wattemp**2
     &                     - 7.7774d-5  * wattemp**3
        ELSEIF(formcs.EQ.2)THEN
          IF(abs(31.6d0+wattemp).GT.eps)THEN
            sato2 = 468.d0/(31.6d0+wattemp)
          ELSE
            sato2 = 468.d0/eps
          ENDIF
        ELSE
          WRITE(lu,101) formcs
          CALL plante(1)
          stop
        ENDIF
      ENDIF
!
!     ERROR MESSAGES
!
101   FORMAT(1x,'CS FORMULA :',i3,/,1x, 'NOT AVAILABLE')
!
!-----------------------------------------------------------------------
!
      RETURN
      END