ride_vr.f

Go to the documentation of this file.

!                   ******************
                    SUBROUTINE ride_vr
!                   ******************
!
     & (ksr,ks,unorm,hn,grav,xmve,xmvs,npoin,acladm)
!
!***********************************************************************
! SISYPHE   V6P1                                   21/07/2011
!***********************************************************************
!
!brief    COMPUTES THE DIMENSIONS OF EQUILIBRIUM RIPPLES.
!+                VAN RIJN (2007) (CURRENT ONLY).
!
!history  C. VILLARET (LNHE); AG DAVIES (UCW)
!+
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C.VILLARET (EDF-LNHE), P.TASSI (EDF-LNHE)
!+        19/07/2011
!+        V6P1
!+  Name of variables
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ACLADM         |-->| MEAN DIAMETER OF SEDIMENT
!| GRAV           |-->| ACCELERATION OF GRAVITY
!| HN             |-->| WATER DEPTH
!| KS             |-->| TOTAL ROUGHNESS
!| KSP            |-->| BED SKIN ROUGHNESS
!| NPOIN          |-->| NUMBER OF POINTS
!| UNORM          |-->| INTENSITE DU COURANT
!| XMVE           |-->| FLUID DENSITY
!| XMVS           |-->| SEDIMENT DENSITY
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      IMPLICIT NONE
!
      INTEGER I,NPOIN
!
      DOUBLE PRECISION, INTENT(INOUT)  :: KSR(npoin),KS(npoin)
      DOUBLE PRECISION, INTENT(IN)     :: GRAV,XMVE,XMVS
      DOUBLE PRECISION, INTENT(IN)     :: HN(npoin)
      DOUBLE PRECISION, INTENT(IN)     :: ACLADM(npoin),UNORM(npoin)
!
! LOCAL VARIABLES
!
      DOUBLE PRECISION AI,ZERO,KSCR,KSCD,KSCMR,MOB,FES,FFS
      DOUBLE PRECISION DSAND,DGRAVEL,DSILT
!
!---------------------------------------------------------------------
!
      zero=1.d-6
      dsilt=0.000032d0
      dgravel=0.002d0
      dsand=0.000062d0
!
! COMPUTES CURRENT-DOMINATED ROUGHNESS USING VAN RIJN (2007)
!
      DO i=1,npoin
!
! MOBILITY NUMBER FOR CURRENT ONLY
!
        ai  = acladm(i)*grav*(xmvs-xmve)/xmve
        mob = unorm(i)**2/ai
!
! RIPPLE ROUGHNESS
!
        IF(acladm(i).LE.0.25d0*dgravel)THEN
          fes=1.d0
        ELSE
          fes=(0.25d0*dgravel/acladm(i))**1.5d0
        ENDIF
!
        IF(acladm(i).LT.dsilt)THEN
          kscr=20.d0*dsilt
        ELSE
          ai= tanh(0.015d0*(mob-150.d0))
          kscr=fes*acladm(i)*(85.d0-65.d0*ai)
        ENDIF
!
! MEGARIPPLE ROUGHNESS
!
        IF(acladm(i).GE.(1.5d0*dsand))THEN
          ffs=1.d0
        ELSE
          ffs=acladm(i)/1.5d0/dsand
        ENDIF
        IF(acladm(i).LE.dsilt)THEN
          kscmr=0.d0
        ELSE
          kscmr=0.00002d0*ffs*hn(i)*(1.d0-exp(-0.05d0*mob))
          IF(mob.GT.550.d0.AND.acladm(i).GE.1.5d0*dsand)THEN
            kscmr=0.02d0
          ELSEIF(mob.GT.550d0.AND.acladm(i).LT.1.5d0*dsand)THEN
            kscmr=200.d0*acladm(i)
          ENDIF
        ENDIF
!
! DUNE ROUGHNESS
!
        IF(acladm(i).LT.dsilt) THEN
          kscd=0.d0
        ELSE
          ai=(1.d0-exp(-0.02d0*mob))*(600.d0-mob)
          kscd=0.00008d0*ffs*hn(i)* ai
        ENDIF
        IF(mob.GT.600.d0) kscd=0.d0
        IF(kscd.GT.1.d0) kscd=1.d0
!
! ***RIPPLE BED ROUGHNESS FOR SEDIMENT COMPUTATIONS IN SISYPHE ***
!
        ksr(i)=kscr
!
! *** TOTAL ROUGHNESS FOR COMPUTATIONS IN TELEMAC2D **
!
        ks(i)=sqrt(kscr**2+kscmr**2+kscd**2)
!
      ENDDO
!
!AGD****************************************************
!
!---------------------------------------------------------------------
!
      RETURN
      END