ride.f

Go to the documentation of this file.

!                   ***************
                    SUBROUTINE ride
!                   ***************
!
     &(ks,tw,uw,unorm,grav,xmve,xmvs,vce,npoin,kspratio,acladm)
!
!***********************************************************************
! SISYPHE   V6P1                                   21/07/2011
!***********************************************************************
!
!brief    COMPUTES THE DIMENSIONS OF EQUILIBRIUM RIPPLES.
!
!reference  "RIPPLE GEOMETRY IN WAVE-DOMINATED ENVIRONMENTS",
!+              WIBERG, P.L. & C.K. HARRIS. 1994. JOURNAL OF
!+              GEOPHYSICAL RESEARCH, 99 (C1): 775-789.
!
!history  C. VILLARET (LNHE)
!+        01/10/2003
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history  C.VILLARET (EDF-LNHE), P.TASSI (EDF-LNHE)
!+        19/07/2011
!+        V6P1
!+  Name of variables
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ACLADM         |-->| MEAN DIAMETER OF SEDIMENT
!| GRAV           |-->| ACCELERATION OF GRAVITY
!| KS             |<--| WAVE INDUCE RIPPLE ROUGHNESS
!| KSPRATIO       |-->| RATIO BETWEEN SKIN BED ROUGHESS AND GRAIN SIZE
!| NPOIN          |-->| NUMBER OF POINTS
!| TW             |-->| WAVE PERIOD
!| UNORM          |-->| NORM OF THE MEAN FLOW VELOCITY
!| UW             |-->| ORBITAL WAVE VELOCITY
!| VCE            |-->| WATER VISCOSITY
!| XMVE           |-->| FLUID DENSITY
!| XMVS           |-->| SEDIMENT DENSITY
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      IMPLICIT NONE
!
      INTEGER I,NPOIN
      DOUBLE PRECISION, INTENT (INOUT) :: KS(npoin)
!
      DOUBLE PRECISION, INTENT (IN) :: GRAV,XMVE,XMVS, VCE
      DOUBLE PRECISION, INTENT (IN) :: UNORM(npoin),UW(npoin),TW(npoin)
!
      DOUBLE PRECISION, INTENT(IN) :: KSPRATIO
      DOUBLE PRECISION, INTENT(IN) :: ACLADM(npoin)
!
!---------------------------------------------------------------------
! LOCAL VARIABLES
      DOUBLE PRECISION PI, ZERO,AI
!
      DOUBLE PRECISION ETA, LAMBDA
!
      DOUBLE PRECISION AA,BB,CC,DD
      DOUBLE PRECISION ALPHA,S,M,A0
      DOUBLE PRECISION WH1,WH2,WH3
      DOUBLE PRECISION VAR1,DHRA,LRA,HRA,LRO
      DOUBLE PRECISION UC,KSP
!---------------------------------------------------------------------
!
      pi=4.d0*atan(1.d0)
      zero=1.d-6
!
!     COEFFICIENTS
!
      wh1=0.095d0
      wh2=0.442d0
      wh3=2.28d0
      aa=(wh2+1.d0)/2.d0/wh1
      bb=aa*aa-wh3/wh1
      cc=1.d0/wh1
!
!     LOOP ON THE NODES
!
      DO i=1,npoin
!
!       SKIN FRICTION
!
        ksp = kspratio * acladm(i)
        ai  = acladm(i)*grav*(xmvs-xmve)/xmve
!
!       MOBILITY NUMBER
!
        m=uw(i)**2/ai
!
        IF(m.LT.1.69d0) THEN
!
          ks(i)=ksp
!
        ELSE
!
!         WIBERG AND HARRIS
!
          a0=uw(i)*tw(i)/(2.d0*pi)
          s=acladm(i)*sqrt(ai)/4.d0/vce
          lra=535.d0*acladm(i)
!         LINE OF CODE MOVED SO ALPHA COMPUTED BEFORE VAR1
!         TANNAKA AND DANG (1996)
          uc=unorm(i)
          IF(uw(i).GT.zero) THEN
            alpha=(tanh(0.3d0*s**(2.d0/3.d0)))**2.5d0
            alpha=1.d0+0.81d0*alpha*(uc/uw(i))**1.9d0
          ELSE
            alpha=1.d0
          ENDIF
          var1=log(alpha*2.d0*a0/lra)
          dd=max((bb-cc*var1),0.d0)
          dhra=exp(aa-sqrt(dd))
          hra=alpha*2.d0*a0/dhra
!
          IF(dhra.LE.20.d0) THEN
!           ORBITAL RIPPLES DHRA
            lro=0.62d0*2.d0*a0*alpha
            lambda=lro
            eta=0.17d0*lambda
          ELSEIF(dhra.LE.100.d0) THEN
!           SUB ORBITAL RIPPLES 20
            lro=0.62d0*2.d0*a0*alpha
            var1=(log(dhra)-log(100.d0))/(log(20.d0)-log(100.d0))
            var1=log(lra)+var1*(log(lro)-log(lra))
            lambda=exp(var1)
            var1=log(alpha*2.d0*a0/lambda)
            dd=max((bb-cc*var1),0.d0)
            eta=alpha*2.d0*a0/exp(aa-sqrt(dd))
          ELSE
!           ANORBITAL RIPPLES DHRA>100
!           LAMBDA NOT USED HERE BUT KEPT FOR OTHER FORMULATIONS
!           LAMBDA=LRA
            eta=hra
          ENDIF
!
          ks(i)=max(eta,ksp)
!
        ENDIF
!
      ENDDO
!
!---------------------------------------------------------------------
!
      RETURN
      END