rescue_sisyphe_notperma.f

Go to the documentation of this file.

!                   **********************************
                    SUBROUTINE rescue_sisyphe_notperma
!                   **********************************
!
     &(qu,qv,q,u,v,h,s,zf,hw,tw,thetaw,npoin,trouve,alire,icf,entet,
     & maxvar)
!
!***********************************************************************
! SISYPHE   V6P1                                   21/07/2011
!***********************************************************************
!
!brief    COMPUTES MISSING DATA/VARIABLES FOR HYDRODYNAMIC
!+                AND/OR SEDIMENTOLOGICAL CONTINUATION RUN.
!
!note     RESCUE_SISYPHE MUST BE MODIFIED FOR UNSTEADY SIMULATIONS
!+         TO TAKE THE BED EVOLUTIONS INTO ACCOUNT.
!note  THE WATER DEPTH NEEDS TO BE COMPUTED FROM THE BED ELEVATION
!+        (SISYPHE) AND THE FREE SURFACE ELEVATION (HYDRO FILE).
!
!history  C.VILLARET
!+
!+        V5P7
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ALIRE          |-->| LIST VARIABLES TO BE READ
!| H              |<->| WATER DEPTH
!| HW             |<->| WAVE DEPTH
!| ICF            |-->| BED-LOAD OR TOTAL LOAD TRANSPORT FORMULAS
!| LISTI          |-->| LOGICAL, IF YES PRINT MESSAGES
!| MAXVAR         |-->| MAXIMUM NUMBER OF OUTPUT VARIABLES
!| NPOIN          |-->| NUMBER OF MESH NODES
!| PASS           |-->| LOGICAL, IF YES BEGIN OF COMPUTATION
!| Q              |<->| LIQUID DISCHARGE
!| QU             |<->| LIQUID DISCHARGE X
!| QV             |<->| LIQUID DISCHARGE Y
!| S              |<->| WATER SURFACE ELEVATION
!| THETAW         |<->| ANGLE BETWEEN WAVE AND CURRENT
!| TROUVE         |-->| LOGIQUE INDIQUANT LES VARIABLES TROUVEES
!|                |   | DANS LE SOUS-PROGRAMME SUITE
!| TW             |<->| WAVE PERIOD
!| U              |<->| VELOCITY COMPONENT X
!| V              |<->| VELOCITY COMPONENT Y
!| ZF             |<->| BED LEVEL
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE interface_sisyphe, ex_rescue_sisyphe_notperma
     &           => rescue_sisyphe_notperma
      USE bief, ONLY: ov
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: MAXVAR
      INTEGER, INTENT(IN) :: TROUVE(maxvar),ALIRE(maxvar),NPOIN,ICF
!
      DOUBLE PRECISION, INTENT(INOUT) :: QU(npoin), QV(npoin), Q(npoin)
      DOUBLE PRECISION, INTENT(INOUT) :: U(npoin) , V(npoin)
      DOUBLE PRECISION, INTENT(INOUT) :: S(npoin) , ZF(npoin), H(npoin)
      DOUBLE PRECISION, INTENT(INOUT) :: HW(npoin), TW(npoin)
      DOUBLE PRECISION, INTENT(INOUT) :: THETAW(npoin)
      LOGICAL, INTENT(IN)             :: ENTET
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!     THE ESSENTIAL VARIABLES NOT MODIFIED BY THE BED EVOLUTIONS
!     ARE THE FREE SURFACE AND THE FLOW
!
!     COMPUTES THE FREE SURFACE(4) FROM THE NON-MODIFIED WATER DEPTH
!     AND THE NON-MODIFIED BED ELEVATION
!
      IF(trouve(4).EQ.0.AND.alire(4).EQ.1) THEN
        IF(trouve(3).EQ.1.AND.trouve(5).EQ.1) THEN
          CALL ov('X=Y+Z   ', x=s, y=h, z=zf, dim1=npoin)
        ELSE
          WRITE(lu,*) 'UNABLE TO BUILD FREE SURFACE'
          CALL plante(1)
          stop
        ENDIF
      ENDIF
!
! COMPUTES THE TELEMAC WATER DEPTH(3) FROM THE NON-MODIFIED
! BED ELEVATION AND THE FREE SURFACE
!
      IF(trouve(3).EQ.0.AND.alire(3).EQ.1) THEN
        IF(trouve(5).EQ.1) THEN
          CALL ov('X=Y-Z   ', x=h, y=s, z=zf, dim1=npoin)
        ELSE
          WRITE(lu,*) 'MISSING BOTTOM OR WATER DEPTH'
          CALL plante(1)
          stop
        ENDIF
      ENDIF
!
!  FLOWRATE ALONG X:  QU
!
      IF (alire(7).EQ.1.AND.trouve(7).EQ.0)  THEN
        IF (trouve(1).EQ.1) THEN
          IF(entet) THEN
          WRITE(lu,151)
151       FORMAT(1x,'DISCHARGE /X COMPUTED WITH DEPTH AND VELOCITY')
          ENDIF
          CALL ov('X=YZ    ', x=qu, y=u, z=h, dim1=npoin)
        ELSE
          IF(entet) THEN
          WRITE(lu,191)
191       FORMAT(1x,'PREVIOUS COMPUTATION WITHOUT VELOCITY U: U IS
     &               EQUAL TO ZERO')
          ENDIF
          CALL ov('X=C     ', x=qu, c=0.d0, dim1=npoin)
        ENDIF
      ENDIF
!
!-----------------------------------------------------------------------
!
!  FLOWRATE ALONG Y :  QV
!
      IF (alire(8).EQ.1.AND.trouve(8).EQ.0)  THEN
        IF (trouve(2).EQ.1) THEN
          IF(entet) THEN
          WRITE(lu,161)
161       FORMAT(1x,'DISCHARGE /Y COMPUTED WITH DEPTH AND VELOCITY')
          ENDIF
          CALL ov('X=YZ    ', x=qv, y=v, z=h,dim1=npoin)
        ELSE
          IF(entet) THEN
          WRITE(lu,211)
211       FORMAT(1x,'PREVIOUS COMPUTATION WITHOUT VELOCITY V:
     &               FIXED TO ZERO')
          ENDIF
          CALL ov('X=C     ', x=qv, c=0.d0, dim1=npoin)
        ENDIF
      ENDIF
!
!-----------------------------------------------------------------------
!
!  FLOWRATE (M2/S)
!
      IF ((alire(6).EQ.1).AND.(trouve(6).EQ.0))  THEN
        CALL ov('X=N(Y,Z)', x=q, y=qu, z=qv, dim1=npoin)
      ENDIF
!
!-----------------------------------------------------------------------
!  WAVE HEIGHT AND PERIOD
!
      IF ((icf==4).OR.(icf==5).OR.
     &    (icf==8).OR.(icf==9)    ) THEN
!
        IF ((alire(12).EQ.1).AND.(trouve(12).EQ.0)) THEN
          WRITE(lu,901)
          CALL ov('X=C     ', x=hw, c=0.d0, dim1=npoin)
        ENDIF
!
901     FORMAT(1x,'PREVIOUS COMPUTATION WITHOUT WAVE HEIGHT : IT IS',
     &          ' FIXED TO ZERO')
!
        IF ((alire(13).EQ.1).AND.(trouve(13).EQ.0)) THEN
          WRITE(lu,903)
          CALL ov('X=C     ', x=tw, c=0.d0, dim1=npoin)
        ENDIF
903     FORMAT(1x,'PREVIOUS COMPUTATION WITHOUT WAVE PERIOD : IT IS',
     &          ' FIXED TO ZERO')
!
        IF ((alire(14).EQ.1).AND.(trouve(14).EQ.0)) THEN
          WRITE(lu,910)
          CALL ov('X=C     ', x=thetaw , c=90.d0, dim1=npoin)
        ENDIF
      ENDIF
910     FORMAT(1x,'PREVIOUS COMPUTATION WITHOUT WAVE ANGLE : IT IS',
     &          ' FIXED TO ZERO')
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE rescue_sisyphe_notperma