rescue_sisyphe.f

Go to the documentation of this file.

!                 *************************
                  SUBROUTINE rescue_sisyphe
!                 *************************
!
     &(h,s,zf,zr,es,hw,tw,thetaw,npoin,nomblay,nsicla,
     & trouve,alire,pass,icf,listi,maxvar)
!
!***********************************************************************
! SISYPHE   V7P2
!***********************************************************************
!
!brief    COMPUTES MISSING DATA/VARIABLES FOR HYDRODYNAMIC
!+                AND/OR SEDIMENTOLOGICAL CONTINUATION RUN.
!
!history  C. LENORMANT
!+
!+        V6P0
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!history M.SECHER (EDF-CIH)
!+       22/08/2016
!+       V7P2
!+   Add calculation of the rigid bed from bottom elevation and
!+   layers thickness of a previous sedimentology computation file
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ALIRE          |-->| LIST VARIABLES TO BE READ
!| H              |<->| WATER DEPTH
!| HW             |<->| WAVE DEPTH
!| ICF            |-->| BED-LOAD OR TOTAL LOAD TRANSPORT FORMULAS
!| LISTI          |-->| LOGICAL, IF YES PRINT MESSAGES
!| MAXVAR         |-->| MAXIMUM NUMBER OF OUTPUT VARIABLES
!| NPOIN          |-->| NUMBER OF MESH NODES
!| PASS           |-->| LOGICAL, IF YES BEGIN OF COMPUTATION
!| S              |<->| WATER SURFACE ELEVATION
!| THETAW         |<->| ANGLE BETWEEN WAVE AND CURRENT
!| TROUVE         |-->| LOGIQUE INDIQUANT LES VARIABLES TROUVEES
!|                |   | DANS LE SOUS-PROGRAMME SUITE
!| TW             |<->| WAVE PERIOD
!| ZF             |<->| BED LEVEL
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
!
      USE interface_sisyphe, ex_rescue_sisyphe
     &           => rescue_sisyphe
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: MAXVAR,NOMBLAY,NSICLA
      INTEGER, INTENT(IN) :: ALIRE(maxvar),NPOIN,ICF
      LOGICAL, INTENT(IN) :: PASS,LISTI
      DOUBLE PRECISION, INTENT(IN) :: ES(npoin,nomblay)
!
      INTEGER, INTENT(INOUT) :: TROUVE(maxvar)
      DOUBLE PRECISION, INTENT(INOUT) :: S(npoin) , ZF(npoin), H(npoin)
      DOUBLE PRECISION, INTENT(INOUT) :: ZR(npoin)
      DOUBLE PRECISION, INTENT(INOUT) :: HW(npoin), TW(npoin)
      DOUBLE PRECISION, INTENT(INOUT) :: THETAW(npoin)
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER K,I,J
      INTEGER CHECK_ES
!
!-----------------------------------------------------------------------
!
! PRINTOUTS :
! -----------
      IF(pass.AND.listi) THEN
        WRITE(lu,200)
200     FORMAT(80('-'))
        IF(alire(8).EQ.1) THEN
          WRITE(lu,301)
301       FORMAT(1x,'RESCUE : HYDRODYNAMIC FILE')
        ELSE
          WRITE(lu,311)
311       FORMAT(1x,'RESCUE : SEDIMENTOLOGICAL FILE')
        ENDIF
      ENDIF
!
! ------------------------------------------------------------------
!  WATER DEPTH :
!  -------------
      IF((alire(3).EQ.1).AND.(trouve(3).NE.1)) THEN
        IF(trouve(4).EQ.1.AND.trouve(5).EQ.1) THEN
          IF (listi) THEN
            WRITE(lu,401)
          ENDIF
          CALL ov('X=Y-Z   ', x=h, y=s, z=zf, dim1=npoin)
        ELSE
          IF (listi) THEN
            WRITE(lu,421)
          ENDIF
          CALL plante(1)
          stop
        ENDIF
      ENDIF
!
401       FORMAT(1x,'WATER DEPTH COMPUTED WITH BATHYMETRY',
     &         /,1x,' AND SURFACE ELEVATION')
421       FORMAT(1x,'WATER DEPTH UNABLE TO BE COMPUTED')
!
! ----------------------------------------------------------------------
!
! CLIPS NEGATIVE WATER DEPTHS :
! -------------------------------------
!
      DO k = 1,npoin
        h(k) = max(h(k),0.d0)
      ENDDO
!
!------------------------------------------------------------------------
!
!  WAVE HEIGHT AND PERIOD
!
      IF(icf==4.OR.icf==5.OR.icf==8.OR.icf==9) THEN
!
        IF(alire(12).EQ.1.AND.trouve(12).EQ.0) THEN
          WRITE(lu,901)
          CALL ov('X=C     ', x=hw, c=0.d0, dim1=npoin)
        ENDIF
!
901     FORMAT(1x,'PREVIOUS COMPUTATION WITHOUT WAVE HEIGHT : IT IS',
     &          ' FIXED TO ZERO')
!
        IF(alire(13).EQ.1.AND.trouve(13).EQ.0) THEN
          WRITE(lu,903)
          CALL ov('X=C     ', x=tw, c=0.d0, dim1=npoin)
        ENDIF
903     FORMAT(1x,'PREVIOUS COMPUTATION WITHOUT WAVE PERIOD : IT IS',
     &          ' FIXED TO ZERO')
!
        IF(alire(14).EQ.1.AND.trouve(14).EQ.0) THEN
          WRITE(lu,905)
          CALL ov('X=C     ', x=thetaw, c=90.d0, dim1=npoin)
        ENDIF
      ENDIF
905   FORMAT(1x,'PREVIOUS COMPUTATION WITHOUT WAVE ANGLE : IT IS',
     &          ' FIXED TO ZERO')
!
!-----------------------------------------------------------------------
!  NON-ERODABLE BED
!
      IF(alire(9).EQ.1.AND.trouve(9).EQ.0) THEN
        WRITE(lu,908)
        check_es=0
        DO i = 1,nomblay
          IF(trouve(5).EQ.1.AND.
     &       trouve(28+i+nsicla*(nomblay+4)).EQ.1) THEN
            check_es=check_es+1
          ENDIF
        ENDDO
        IF(check_es.EQ.nomblay) THEN
          WRITE(lu,910)
          DO i = 1,npoin
            zr(i)=zf(i)
            DO j = 1,nomblay
              zr(i)=zr(i)-es(i,j)
            ENDDO
          ENDDO
          trouve(9) = 1
        ENDIF
      ENDIF
908   FORMAT(1x,'PREVIOUS CALCULATION WITHOUT NON ERODABLE',
     &         /,1x,'BOTTOM')
910   FORMAT(1x,'PREVIOUS CALCULATION CONTAINS ALL LAYERS',
     &         /,1x,'RIGID BED COMPUTED FROM LAYERS THICKNESS',
     &         /,1x,'AND BOTTOM')
!
!-----------------------------------------------------------------------
!  BED ELEVATION
!
      IF(alire(5).EQ.1.AND.trouve(5).EQ.0) THEN
!
        IF(trouve(4).EQ.1.AND.trouve(3).EQ.1) THEN
          IF (listi) THEN
          WRITE(lu,411)
411       FORMAT(1x,'BATHYMETRY COMPUTED FROM WATER DEPTH',
     &         /,1x,'AND SURFACE ELEVATION')
          ENDIF
          CALL ov('X=Y-Z   ', x=zf, y=s, z=h, dim1=npoin)
        ELSE
          CALL ov('X=C     ', x=zf, c=0.d0, dim1=npoin)
          WRITE(lu,961)
        ENDIF
961     FORMAT(1x,'BOTTOM TOPOGRAPHY NOT FOUND',/,
     &            'IT IS SET TO ZERO')
!
      ENDIF
!
      IF (pass.AND.listi) THEN
        WRITE(lu,970)
970     FORMAT(80('-'))
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END SUBROUTINE rescue_sisyphe