remont.f

Go to the documentation of this file.

!                   *****************
                    SUBROUTINE remont
!                   *****************
!
     &(x, xa,typexa,b,ikle,nelem,nelmax,npoin,ielm,ditr,copy,lv)
!
!***********************************************************************
! BIEF   V6P1                                   21/08/2010
!***********************************************************************
!
!brief    SOLVES THE SYSTEM U X = B (ELEMENT BY ELEMENT).
!code
!+            THE MATRIX U IS HERE THE RESULT OF A DECOMPOSITION
!+            DONE IN SUBROUTINE DECLDU
!+
!+            EACH ELEMENTARY MATRIX WAS FACTORISED IN THE FORM:
!+
!+            LE X DE X UE
!+
!+            LE : LOWER TRIANGULAR WITH 1S ON THE DIAGONAL
!+            DE : DIAGONAL
!+            UE : UPPER TRIANGULAR WITH 1S ON THE DIAGONAL
!+
!+                                                T
!+            IF THE MATRIX IS SYMMETRICAL : LE =  UE
!
!code
!+-----------------------------------------------------------------------
!+  MEANING OF IELM :
!+
!+  TYPE OF ELEMENT      NUMBER OF POINTS      CODED IN THIS SUBROUTINE
!+
!+  11 : TRIANGLE P1            3                       YES
!+  12 : TRIANGLE P2            6
!+  13 : TRIANGLE P1-ISO P1     6
!+  14 : TRIANGLE P2            7
!+  21 : QUADRILATERAL Q1       4                       YES
!+  22 : QUADRILATERAL Q2       8
!+  24 : QUADRILATERAL Q2       9
!+  31 : TETRAHEDRON P1         4
!+  32 : TETRAHEDRON P2        10
!+  41 : TELEMAC-3D PRISMS      6                       YES
!+  51 : PRISMS SPLIT IN TETRAHEDRONS  4                YES
!+-----------------------------------------------------------------------
!
!history  J-M HERVOUET (LNH)    ; F  LEPEINTRE (LNH)
!+        05/02/91
!+        V5P3
!+
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        13/07/2010
!+        V6P0
!+   Translation of French comments within the FORTRAN sources into
!+   English comments
!
!history  N.DURAND (HRW), S.E.BOURBAN (HRW)
!+        21/08/2010
!+        V6P0
!+   Creation of DOXYGEN tags for automated documentation and
!+   cross-referencing of the FORTRAN sources
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| B              |<--| RIGHT-HAND SIDE OF THE LINEAR SYSTEM TO BE SOLVED
!| COPY           |-->| IF .TRUE. B IS COPIED INTO X TO START WITH
!| DITR           |-->| CHARACTER, IF  'D' : DIRECT MATRIX A CONSIDERED
!|                |   |                'T' : TRANSPOSED MATRIX A CONSIDERED
!| IELM           |-->| TYPE OF ELEMENT (SEE ABOVE)
!| IKLE           |-->| CONNECTIVITY TABLE.
!| LV             |-->| VECTOR LENGTH OF THE MACHINE
!| NELEM          |-->| NUMBER OF ELEMENTS
!| NELMAX         |-->| MAXIMUM NUMBER OF ELEMENTS
!| NPOIN          |-->| NUMBER OF POINTS
!| TYPEXA         |-->| TYPE OF OFF-DIAGONAL TERMS IN THE MATRIX
!| X              |<--| SOLUTION OF THE SYSTEM AX = B
!| XA             |<--| OFF-DIAGONAL TERMS OF THE MATRIX
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief, ex_remont => remont
!
      USE declarations_special
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER, INTENT(IN) :: IELM,NPOIN,NELEM,NELMAX,LV
      INTEGER, INTENT(IN) :: IKLE(nelmax,*)
!
      DOUBLE PRECISION, INTENT(INOUT) :: X(npoin)
      DOUBLE PRECISION, INTENT(IN)    :: B(npoin),XA(nelmax,*)
!
      CHARACTER(LEN=*), INTENT(IN) :: TYPEXA,DITR
!
      LOGICAL, INTENT(IN) :: COPY
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!
!-----------------------------------------------------------------------
!
! 1) INITIALISES : X = SECOND MEMBER
!
      IF(copy) CALL ov('X=Y     ', x=x, y=b, dim1=npoin)
!
!-----------------------------------------------------------------------
!
! 2) INVERTS THE UPPER TRIANGULAR MATRICES (TRACEBACK)
!
!     2.1) TRANSPOSE CASE
!
      IF(typexa(1:1).EQ.'S' .OR.
     &  (typexa(1:1).EQ.'Q'.AND.ditr(1:1).EQ.'D')) THEN
!
      IF(ielm.EQ.11) THEN
!
        CALL rem11(x,xa(1,1),xa(1,2),xa(1,3),
     &             ikle(1,1),ikle(1,2),ikle(1,3),nelem,nelmax,npoin,lv)
!
      ELSEIF(ielm.EQ.21.OR.ielm.EQ.12.OR.ielm.EQ.31.OR.ielm.EQ.51) THEN
!
        CALL rem21(x,xa(1,1),xa(1,2),xa(1,3),xa(1,4),xa(1,5),xa(1,6),
     &               ikle(1,1),ikle(1,2),ikle(1,3),ikle(1,4),
     &               nelem,nelmax,npoin,lv)
!
      ELSEIF(ielm.EQ.41) THEN
!
        CALL rem41(x,xa(1,1),xa(1,2),xa(1,3),xa(1,4) ,xa(1,5) ,xa(1,6),
     &             xa(1,7),xa(1,8),xa(1,9),xa(1,10),xa(1,11),xa(1,12),
     &             xa(1,13),xa(1,14),xa(1,15),
     &             ikle(1,1),ikle(1,2),ikle(1,3),
     &             ikle(1,4),ikle(1,5),ikle(1,6),nelem,nelmax,npoin,lv)
!
!  VALUE FOR IELM NOT PERMITTED : ERROR
!
      ELSE
!
        WRITE(lu,101) ielm
101   FORMAT(1x,'REMONT (BIEF) : IELM = ',1i6,' ELEMENT NOT AVAILABLE')
        CALL plante(1)
        stop
!
      ENDIF
!
!     2.2) TRANSPOSE CASE
!
      ELSEIF(typexa(1:1).EQ.'Q'.AND.ditr(1:1).EQ.'T') THEN
!
      IF(ielm.EQ.11) THEN
!
        CALL rem11(x,xa(1,4),xa(1,5),xa(1,6),
     &             ikle(1,1),ikle(1,2),ikle(1,3),nelem,nelmax,npoin,lv)
!
      ELSEIF(ielm.EQ.21.OR.ielm.EQ.12.OR.ielm.EQ.31.OR.ielm.EQ.51) THEN
!
        CALL rem21(x,xa(1,7),xa(1,8),xa(1,9),xa(1,10),xa(1,11),xa(1,12),
     &             ikle(1,1),ikle(1,2),ikle(1,3),ikle(1,4),
     &             nelem,nelmax,npoin,lv)
!
      ELSEIF(ielm.EQ.41) THEN
!
        CALL rem41(x,
     &            xa(1,16),xa(1,17),xa(1,18),xa(1,19),xa(1,20),xa(1,21),
     &            xa(1,22),xa(1,23),xa(1,24),xa(1,25),xa(1,26),xa(1,27),
     &            xa(1,28),xa(1,29),xa(1,30),
     &            ikle(1,1),ikle(1,2),ikle(1,3),
     &            ikle(1,4),ikle(1,5),ikle(1,6),nelem,nelmax,npoin,lv)
!
!  VALUE FOR IELM NOT PERMITTED : ERROR
!
      ELSE
!
        WRITE(lu,101) ielm
        CALL plante(1)
        stop
!
      ENDIF
!
!     2.3) CASE NOT IMPLEMENTED
!
      ELSE
        WRITE(lu,201) typexa(1:1)
201     FORMAT(1x,'REMONT (BIEF) : UNEXPECTED TYPE OF MATRIX :',a1)
        CALL plante(1)
        stop
      ENDIF
!
!-----------------------------------------------------------------------
!
      RETURN
      END