reaer_weir.f

Go to the documentation of this file.

!                  **********************
                    SUBROUTINE reaer_weir
!                   **********************
!
     &(formrs,h1,h2,abrs,wattemp,eps,o2satu,trup,tn,ind_o2,ir)
!
!***********************************************************************
! TELEMAC2D   V7P1
!***********************************************************************
!
!brief    COMPUTES THE REAERATION AT WEIRS
!
!warning: this is not a source term, this routine changes directly TN
!         questions:
!            1- it changes TN at time tn while it has to be done in tn+1
!            2- it affects the mass conservation !! to adapt bilant
!
!history  R. ATA (LNHE)
!+        02/09/2015
!+        V7P1
!+
!
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!| ABRS           |-->| COEFFICIENT A AND B USED IN RS FORMUL
!| EPS            |-->| TO AVOID DIVISION BY 0
!| FORMRS         |-->| WHICH FROMULA TO COMPUTE RS
!| H1,H2          |-->| WATER DEPTH UPSRTEAM AND DOWNSTREAM WEIR
!| IR             |-->| NODE NUMBER (BELONGS TO WEIR DOWNSTREAM)
!| O2SATU         |-->| O2 SATURATION DENSITY OF WATER (CS)
!| TN             |<--| TRACER AT TIME tn
!| TRUP           |-->| TRACER VALUE UPSTREAM WEIR
!| WATTEMP        |-->| TEMPERATURE OF WATER
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
!
      USE bief
      USE declarations_special
      USE interface_parallel
      USE interface_waqtel, ex_reaer_weir => reaer_weir
!
      IMPLICIT NONE
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
      INTEGER         , INTENT(IN)     :: FORMRS,IR
      DOUBLE PRECISION, INTENT(IN)     :: EPS,H1,H2,ABRS(2),WATTEMP
      DOUBLE PRECISION, INTENT(IN)     :: TRUP,O2SATU
      INTEGER,          INTENT(IN)     :: IND_O2
      TYPE(bief_obj)   , INTENT(INOUT) :: TN
      INTRINSIC abs
!
!+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
!
!     LOCAL VARIABLES
      DOUBLE PRECISION  DZ,RSW,TRDO,AB
!
!
      dz= abs(h2-h1)
      rsw = 0.d0
!     LETS'S COMPUTE RS IF IT IS NOT TAKEN CONSTANT
      IF(formrs.NE.0) THEN
        ab=abrs(1)*abrs(2)
!       GAMESON FORMULA 1
        IF(formrs.EQ.1)     THEN
          rsw=1.d0+0.5d0*ab*dz
!       GAMESON FORMULA2
        ELSEIF(formrs.EQ.2) THEN
!         BUG BEFORE V8P0, NOT RSW = 0.11*AB*...
          rsw = 1.d0+0.36d0*ab*(1.d0+0.046d0*wattemp)*dz
!       WRL FORMULA 1 (NO NEED TO AB ? )
        ELSEIF(formrs.EQ.3 )THEN
          rsw = 1.d0+0.69d0*dz*(1.d0-0.11d0*dz )
     &       *( 1.d0+0.046d0*wattemp)
!       WRL FORMULA 2
        ELSEIF (formrs.EQ.4)THEN
          rsw = 1.d0+0.38d0*ab*dz*(1.d0-0.11d0*dz)
     &       * (1.d0+0.046d0*wattemp )
        ELSE
          WRITE(lu,*)'FORMULA FOR RS (WEIR REAERATION) '
          WRITE(lu,*)' NOT VALID  :',formrs
          WRITE(lu,*)'POSSIBLE CHOICES ARE FROM 1 TO 4'
          CALL plante(1)
          stop
        ENDIF
!
!       FORCING O2 DENSITY DOWNSTREAM THE WEIR
!
        IF(abs(rsw).GT.eps)THEN
          trdo = o2satu + (trup-o2satu)/rsw
        ELSE
          WRITE(lu,*)'REAER_WEIR:RSW VERY SMALL',rsw
          CALL plante(1)
          stop
        ENDIF
        IF(ncsize.GT.1)trdo = p_min(trdo)+p_max(trdo)
!       O2 PROCESS
        tn%ADR(ind_o2)%P%R(ir)=trdo
      ENDIF
!
      RETURN
      END
!
!-----------------------------------------------------------------------
!